citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.52)
   3 AC_INIT([Citadel], [8.03], [http://www.citadel.org/])
   4 AC_REVISION([$Revision: 5108 $])
   5 AC_CONFIG_SRCDIR([citserver.c])
   6 AC_CONFIG_HEADER(sysdep.h)
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_PREFIX_DEFAULT(/usr/local/citadel)
   9 if test "$prefix" = NONE; then
  10         AC_DEFINE_UNQUOTED(CTDLDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  11         ssl_dir="$ac_default_prefix/keys"
  12         localedir=$ac_default_prefix
  13 else
  14         AC_DEFINE_UNQUOTED(CTDLDIR, "$prefix", [define this to the Citadel home directory])
  15         ssl_dir="$prefix/keys"
  16         localedir=$prefix
  17 fi
  18
  19 dnl Make sure we see all GNU and Solaris extensions.
  20 AC_GNU_SOURCE
  21
  22
  23 dnl Checks for the Datadir
  24 AC_ARG_WITH(datadir,
  25                     [  --with-datadir          directory to store the databases under],
  26                         [ if test "x$withval" != "xno" ; then
  27                                               AC_DEFINE(HAVE_DATA_DIR,[],[use alternate database location?])
  28                                               AC_DEFINE_UNQUOTED(DATA_DIR, "$withval",[define, if the user suplied a data-directory to use.])
  29                                               MAKE_DATA_DIR=$withval
  30                                               AC_SUBST(MAKE_DATA_DIR)
  31                           fi
  32                         ]
  33 )
  34
  35
  36 dnl Checks for the helpDatadir
  37 AC_ARG_WITH(helpdir,
  38                     [  --with-helpdir          directory to store the helpfiles under],
  39                         [ if test "x$withval" != "xno" ; then
  40                                               AC_DEFINE(HAVE_HELP_DIR,[],[use alternate database location?])
  41                                               AC_DEFINE_UNQUOTED(HELP_DIR, "$withval",[define, if the user suplied a helpfile-directory to use.])
  42                                               MAKE_HELP_DIR=$withval
  43                                               AC_SUBST(MAKE_HELP_DIR)
  44                           fi
  45                         ]
  46 )
  47
  48 dnl Checks for the Static Datadir
  49 AC_ARG_WITH(staticdatadir,
  50                     [  --with-staticdatadir    directory to store citadels system messages under],
  51                         [ if test "x$withval" != "xno" ; then
  52                                                   AC_DEFINE(HAVE_STATICDATA_DIR, [], [should we activate an alternate static text location?])
  53                                                   AC_DEFINE_UNQUOTED(STATICDATA_DIR, "$withval", [where do we put our static text data?])
  54                                                   MAKE_STATICDATA_DIR=$withval
  55                                                   AC_SUBST(MAKE_STATICDATA_DIR)
  56                           fi
  57                         ]
  58 )
  59
  60
  61 dnl Checks for the SSLdir
  62 dnl this is a bit different than the rest,
  63 dnl because of the citadel used to have a keys/ subdir.
  64 AC_ARG_WITH(ssldir,
  65                     [  --with-ssldir           directory to store the ssl certificates under],
  66                         [ if test "x$withval" != "xno" ; then
  67
  68                                                   ssl_dir="$withval"
  69                           fi
  70                         AC_SUBST(MAKE_SSL_DIR)
  71                         ]
  72 )
  73 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
  74
  75
  76 dnl Checks for the spooldir
  77 AC_ARG_WITH(spooldir,
  78                         [  --with-spooldir         directory to keep queues under],
  79                         [ if test "x$withval" != "xno" ; then
  80                                                 AC_DEFINE(HAVE_SPOOL_DIR, [], [enable alternate spool dir?])
  81                                                 AC_DEFINE_UNQUOTED(SPOOL_DIR,"$withval", [where do we place our spool dirs?])
  82                                                 MAKE_SPOOL_DIR=$withval
  83                                                 AC_SUBST(MAKE_SPOOL_DIR)
  84                            fi
  85                         ]
  86 )
  87
  88
  89 dnl Checks for the Configdir
  90 AC_ARG_WITH(sysconfdir,
  91                         [  --with-sysconfdir       directory to store the configs under],
  92                         [ if test "x$withval" != "xno" ; then
  93                                             AC_DEFINE(HAVE_ETC_DIR, [], [should we search our system config in an alternate place?])
  94                                                 AC_DEFINE_UNQUOTED(ETC_DIR, "$withval", [where to search our config files])
  95                                                 MAKE_ETC_DIR=$withval
  96                                                 AC_SUBST(MAKE_ETC_DIR)
  97                           fi
  98                         ]
  99 )
 100
 101 dnl Checks for the Configdir
 102 AC_ARG_WITH(autosysconfdir,
 103                         [  --with-autosysconfdir         directory to store the automaticaly maintained configs under],
 104                         [ if test "x$withval" != "xno" ; then
 105                                             AC_DEFINE(HAVE_AUTO_ETC_DIR, [], [should we search our automatic config in an alternate place?])
 106                                                 AC_DEFINE_UNQUOTED(AUTO_ETC_DIR, "$withval", [where to search our automatic config files])
 107                                                 MAKE_AUTO_ETC_DIR=$withval
 108                                                 AC_SUBST(MAKE_AUTO_ETC_DIR)
 109                           fi
 110                         ]
 111 )
 112
 113 dnl Checks for where to put our utilities
 114 AC_ARG_WITH(utility-bindir,
 115                         [  --with-utility-bindir   directory where to find helper binaries],
 116                         [ if test "x$withval" != "xno" ; then
 117                                             AC_DEFINE(HAVE_UTILBIN_DIR,[],[should we put our helper binaries to another location?])
 118                                                 AC_DEFINE_UNQUOTED(UTILBIN_DIR, "$withval", [were to put our helper programs])
 119                                                 MAKE_UTILBIN_DIR=$withval
 120                                                 AC_SUBST(MAKE_UTILBIN_DIR)
 121                           fi
 122                         ]
 123 )
 124
 125
 126 dnl Checks for the run-dir for the sockets
 127 AC_ARG_WITH(rundir,
 128                         [  --with-rundir           directory to place runtime files (UDS) to?],
 129                         [ if test "x$withval" != "xno" ; then
 130                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 131                                                 AC_DEFINE_UNQUOTED(RUN_DIR, "$withval", [define, where the config should go in unix style])
 132                                                 MAKE_RUN_DIR=$withval
 133                                                 AC_SUBST(MAKE_RUN_DIR)
 134                           fi
 135                         ]
 136 )
 137
 138
 139 dnl Checks for the Pseudo Random Generator sockets TODO: this keeps being default.
 140 AC_DEFINE_UNQUOTED(EGD_POOL, "/var/run/egd-pool", [place to keep our pseudo random generator file])
 141 AC_ARG_WITH(egdpool,
 142                         [  --with-egdpool          the socket from Pseudo Random Generator, defaults to /var/run/egd-pool],
 143                         [ if test "x$withval" != "xno" ; then
 144                                                 AC_DEFINE_UNQUOTED(EGD_POOL, "$withval", [the socket from Pseudo Random Generator])
 145                           fi
 146                         ]
 147 )
 148
 149
 150 AC_ARG_WITH(docdir,
 151                         [  --with-docdir           where to install the documentation. default: /usr/local/citadel/],
 152                         [ if test "x$withval" != "xno" ; then
 153                                         MAKE_DOC_DIR=$withval
 154                                         AC_SUBST(MAKE_DOC_DIR)
 155                           fi
 156                         ]
 157 )
 158
 159 dnl where to put the locale files
 160 AC_ARG_WITH(localedir,
 161                     [  --with-localedir          directory to put the locale files to],
 162                         [ if test "x$withval" != "xno" ; then
 163                             localedir=$withval
 164                           fi
 165                         ]
 166 )
 167 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 168 LOCALEDIR=$localedir
 169 AC_SUBST(LOCALEDIR)
 170
 171
 172
 173 dnl Checks for the zlib compression library.
 174 saved_CFLAGS="$CFLAGS"
 175 CFLAGS="$CFLAGS $SERVER_LIBS"
 176 AC_CHECK_HEADER(zlib.h,
 177         [AC_CHECK_LIB(z, zlibVersion,
 178                 [
 179                         LIBS="-lz $LIBS $SERVER_LIBS"
 180                 ],
 181                 [
 182                         AC_MSG_ERROR(zlib was not found or is not usable.  Please install zlib.)
 183                 ]
 184         ,
 185         )],
 186         [
 187                 AC_MSG_ERROR(zlib.h was not found or is not usable.  Please install zlib.)
 188         ]
 189 )
 190 CFLAGS="$saved_CFLAGS"
 191
 192 dnl Here is the check for a libc integrated iconv
 193 AC_ARG_ENABLE(iconv,
 194         [  --disable-iconv         do not use iconv charset conversion],
 195         ok_iconv=no, ok_iconv=yes)
 196
 197 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 198 AC_TRY_RUN([
 199         #include <iconv.h>
 200         main() {
 201                 iconv_t ic = (iconv_t)(-1) ;
 202                 ic = iconv_open("UTF-8", "us-ascii");
 203                 iconv_close(ic);
 204                 exit(0);
 205         }
 206  ],
 207                 [
 208                   ok_iconv=yes
 209                   AC_MSG_RESULT([yes])
 210                 ],
 211                 [
 212                   ok_iconv=no
 213                   AC_MSG_RESULT([no])
 214                 ]
 215 )
 216
 217 dnl Check for iconv in external libiconv
 218 if test "$ok_iconv" = no; then
 219         AC_MSG_CHECKING(Checking for an external libiconv)
 220         OLD_LDFLAGS="$LDFLAGS"
 221         LDFLAGS="$LDFLAGS -liconv"
 222         AC_TRY_RUN([
 223                         #include <iconv.h>
 224                         main() {
 225                                 iconv_t ic = (iconv_t)(-1) ;
 226                                 ic = iconv_open("UTF-8", "us-ascii");
 227                                 iconv_close(ic);
 228                         }
 229                 ],
 230                         [
 231                           ok_iconv=yes
 232                           AC_MSG_RESULT([yes])
 233                         ],
 234                         [
 235                           ok_iconv=no
 236                           LDFLAGS="$OLD_LDFLAGS"
 237                           AC_MSG_RESULT([no])
 238                         ]
 239                 )
 240 fi
 241 if test "$ok_iconv" != "no"; then
 242         AC_MSG_RESULT(Citadel will be built with character set conversion.)
 243         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 244 else
 245         AC_MSG_RESULT(Citadel will be built without character set conversion.)
 246 fi
 247
 248 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 249
 250
 251
 252 AC_ARG_ENABLE(threaded-client, [  --disable-threaded-client
 253                           disable multithreaded client])
 254
 255 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
 256
 257 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
 258 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
 259 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Berkeley DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
 260 AC_ARG_WITH(ssl,
 261         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
 262         [
 263                 if test "x$withval" != "xno" ; then
 264                         tryssldir=$withval
 265                 fi
 266         ]
 267 )
 268 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
 269 dnl AC_ARG_WITH(with_libdspam, [  --with-libdspam         use libdspam mail spam scanning library])
 270 AC_ARG_WITH(with_gc, [  --with-gc             use the Boehm-Demers-Weiser garbage collection library])
 271
 272 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
 273         db_dir="$with_db"
 274         with_db=yes
 275 else
 276         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
 277           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
 278           && db_dir=/usr/local
 279
 280         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
 281         test -d /usr/local/BerkeleyDB.4.2 && db_dir=/usr/local/BerkeleyDB.4.2
 282         test -d /usr/local/BerkeleyDB.4.3 && db_dir=/usr/local/BerkeleyDB.4.3
 283         test -d /usr/local/BerkeleyDB.4.4 && db_dir=/usr/local/BerkeleyDB.4.4
 284         test -d /usr/local/BerkeleyDB.4.5 && db_dir=/usr/local/BerkeleyDB.4.5
 285 fi
 286
 287 dnl By default, we only build the client (citadel and whobbs) unless we can
 288 dnl figure out how to build with POSIX threads.
 289 TARGETS=client
 290
 291 AC_CANONICAL_HOST
 292 PTHREAD_DEFS=-D_REENTRANT
 293 AC_MSG_CHECKING([how to compile with POSIX threads])
 294 case "$host" in
 295         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
 296         dnl for dlopen(), and has a wrapper script to link with shared libs.
 297         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
 298         *-*-bsdi[123]*)
 299                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
 300                 AC_DEFINE(HAVE_NONREENTRANT_NETDB,[], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 301                 AC_MSG_RESULT([Old BSDI])
 302         ;;
 303         *-*-bsdi*)
 304                 AC_DEFINE(HAVE_NONREENTRANT_NETDB, [], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 305                 AC_MSG_RESULT([BSD/OS])
 306         ;;
 307         dnl Curses support on Mac OS X is kind of screwed at the moment.
 308         dnl TCP buffering isn't ideal under OS X. This define should also be
 309         dnl checked in other cases of OS X-Linux differences.
 310         *-*-darwin*)
 311                 AC_DEFINE(HAVE_DARWIN, [], [define if using OS X/Darwin])
 312                 AC_MSG_RESULT([Mac OS X])
 313         ;;
 314         dnl Digital Unix has an odd way to build for pthreads, and we can't
 315         dnl build pthreads programs with gcc due to header problems.
 316         alpha*-dec-osf*)
 317                 test -z "$CC" && CC=cc
 318                 LIBS="-lpthread -lexc $LIBS"
 319                 check_pthread=no
 320                 AC_MSG_RESULT([Tru64 or Digital UNIX])
 321         ;;
 322         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
 323         *-*-freebsd*)
 324                 if test "$with_kthread" = yes; then
 325                         LIBS="-kthread $LIBS"
 326                 else
 327                         LIBS="-pthread $LIBS"
 328                 fi
 329                 check_pthread=no
 330                 PTHREAD_DEFS=-D_THREAD_SAFE
 331                 AC_MSG_RESULT([FreeBSD])
 332         ;;
 333         *-*-openbsd*)
 334                 LIBS="-pthread $LIBS"
 335                 check_pthread=no
 336                 PTHREAD_DEFS=-pthread
 337                 AC_MSG_RESULT([OpenBSD])
 338         ;;
 339         *-*-linux*)
 340                 PTHREAD_DEFS="-D_REENTRANT -pthread"
 341                 AC_MSG_RESULT([Linux])
 342         ;;
 343         *-*-solaris*)
 344                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
 345                 AC_MSG_RESULT([Solaris])
 346         ;;
 347         *-*-cygwin*)
 348                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
 349                 AC_MSG_RESULT([Cygwin])
 350         ;;
 351         *)
 352                 AC_MSG_RESULT([default])
 353         ;;
 354 esac
 355 dnl DEFS="$DEFS $PTHREAD_DEFS"
 356
 357
 358 dnl Checks for programs.
 359 AC_PROG_CC
 360
 361
 362
 363 dnl Set up system-dependent compiler flags.
 364 if test "$GCC" = yes; then
 365         if test "$CC" = icc; then
 366                 CFLAGS="$CFLAGS -w1"
 367         else
 368                 case "$host" in
 369                         *-*-solaris*|alpha*-dec-osf*)
 370                                 CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts $PTHREAD_DEFS"
 371                         ;;
 372                         *)
 373                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes -Wno-strict-aliasing $PTHREAD_DEFS"
 374                         ;;
 375                 esac
 376         fi
 377 fi
 378
 379 if test "x$enable_pie" = xyes; then
 380         save_CFLAGS="$CFLAGS"
 381         save_LDFLAGS="$LDFLAGS"
 382         CFLAGS="$CFLAGS -fpie"
 383         LDFLAGS="$LDFLAGS -pie -fpie"
 384         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 385         [AC_TRY_LINK([], [],
 386         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 387         if test $ac_cv_pie_fpie = no; then
 388                 CFLAGS="$save_CFLAGS"
 389                 LDFLAGS="$save_LDFLAGS"
 390         fi
 391 fi
 392
 393 AC_MSG_CHECKING([how to create dependancy checks])
 394                  if test -n "`$CC -V 2>&1 |grep Sun`"; then
 395                         DEPEND_FLAG=-xM;
 396                  else
 397                         DEPEND_FLAG=-M
 398                  fi
 399 AC_SUBST(DEPEND_FLAG)
 400
 401
 402 AC_PROG_INSTALL
 403 AC_PROG_YACC
 404 AC_PATH_PROG(DIFF,diff)
 405 AC_PATH_PROG(PATCH,patch)
 406 missing_dir=`cd $ac_aux_dir && pwd`
 407 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 408 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 409
 410 dnl Checks for system services.
 411
 412 dnl Check the size of various builtin types; see typesize.h (error)
 413 AC_CHECK_SIZEOF(char, 0)
 414 AC_CHECK_SIZEOF(short, 0)
 415 AC_CHECK_SIZEOF(int, 0)
 416 AC_CHECK_SIZEOF(long, 0)
 417 AC_CHECK_SIZEOF(size_t, 0)
 418 dnl AC_CHECK_SIZEOF(long long, 0)
 419
 420 dnl Checks for libraries.
 421
 422 dnl We want to test for the following in libc before checking for their
 423 dnl respective libraries, because some systems (like Irix) have both, and the
 424 dnl non-libc versions may be broken.
 425 AC_CHECK_FUNCS(crypt gethostbyname connect flock getpwnam_r getpwuid_r getloadavg)
 426
 427 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 428
 429 if test "$ok_nls" != "no"; then
 430         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 431         ok_nls=$ok_xgettext
 432 fi
 433
 434 if test "$ok_nls" != "no"; then
 435         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 436         ok_nls=$ok_msgmerge
 437 fi
 438
 439 if test "$ok_nls" != "no"; then
 440         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 441         ok_nls=$ok_msgfmt
 442 fi
 443
 444 if test "$ok_nls" != "no"; then
 445         AC_MSG_RESULT(citadel will be built with national language support.)
 446         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 447         PROG_SUBDIRS="$PROG_SUBDIRS po/citadel-setup"
 448 else
 449         AC_MSG_RESULT(citadel will be built without national language support.)
 450 fi
 451
 452 dnl disable backtrace if we don't want it.
 453 AC_ARG_WITH(backtrace,
 454                     [  --with-backtrace        enable backtrace dumps in the syslog],
 455                         [ if test "x$withval" != "xno" ; then
 456                              CFLAGS="$CFLAGS  -rdynamic "
 457                              LDFLAGS="$LDFLAGS  -rdynamic "
 458                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -rdynamic "
 459                              AC_CHECK_FUNCS(backtrace)
 460                           fi
 461                         ]
 462 )
 463
 464 dnl disable backtrace if we don't want it.
 465 AC_ARG_WITH(gprof,
 466                     [  --with-gprof            enable profiling],
 467                         [ if test "x$withval" != "xno" ; then
 468                              CFLAGS="$CFLAGS  -pg "
 469                              LDFLAGS="$LDFLAGS  -pg "
 470                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -pg "
 471                           fi
 472                         ]
 473 )
 474
 475 if test "$ac_cv_func_gethostbyname" = no; then
 476         AC_CHECK_LIB(nsl, gethostbyname)
 477 fi
 478
 479 if test "$ac_cv_func_connect" = no; then
 480         AC_CHECK_LIB(socket, connect)
 481 fi
 482
 483 dnl Check for Solaris realtime support
 484 AC_CHECK_LIB(rt, sched_yield)
 485
 486 dnl Determine the system's authentication capabilities.
 487 dnl We currently support PAM, standard getpwnam(), and getspnam()
 488 dnl (Linux shadow passwords)
 489
 490 save_LIBS=$LIBS
 491 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 492         LIBS="-lpam $LIBS"])
 493 AC_CHECK_FUNCS(pam_start)
 494 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 495         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 496                 save_LIBS=$LIBS
 497                 AC_SEARCH_LIBS(getspnam, shadow, [
 498                         if test "$ac_cv_search_getspnam" = -lshadow; then
 499                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 500                         fi])
 501                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 502                 if test "$ac_cv_func_crypt" = no; then
 503                         AC_CHECK_LIB(crypt, crypt, [
 504                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 505                                 test "$enable_chkpwd" = no && \
 506                                         LIBS="-lcrypt $LIBS"])
 507                 fi
 508         fi
 509
 510 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 511
 512 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 513 dnl which the -pthread flag takes care of this.)
 514 if test "$check_pthread" != no; then
 515         AC_CHECK_LIB(pthread, pthread_create)
 516         AC_CHECK_LIB(pthreads, pthread_create)
 517 fi
 518
 519 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 520
 521 dnl Checks for the libical iCalendar library.
 522 AC_CHECK_HEADER(libical/ical.h,
 523         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 524                 [
 525                         SERVER_LIBS="-lical $SERVER_LIBS"
 526                 ],
 527                 [
 528                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 529                 ]
 530         ,
 531         )],
 532         [
 533                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 534         ]
 535 )
 536
 537
 538 dnl Checks for the libsieve mailbox sorting library.
 539 AC_CHECK_HEADER(sieve2.h,
 540         [AC_CHECK_LIB(sieve, sieve2_license,
 541                 [
 542                         SERVER_LIBS="-lsieve $SERVER_LIBS"
 543                 ],
 544                 [
 545                         AC_MSG_ERROR(libsieve was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 546                 ]
 547         ,
 548         )],
 549         [
 550                 AC_MSG_ERROR(sieve2.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 551         ]
 552 )
 553
 554 saved_CFLAGS="$CFLAGS"
 555 CFLAGS="$CFLAGS $SERVER_LIBS"
 556 dnl Check for libcitadel
 557 AC_CHECK_HEADER(libcitadel.h,
 558         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 559                 [
 560                         LIBS="-lcitadel $LIBS $SERVER_LIBS"
 561                         chkpwd_LIBS="-lcitadel $chkpwd_LIBS"
 562                 ],
 563                 [
 564                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 565                 ]
 566         ,
 567         )],
 568         [
 569                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 570         ]
 571 )
 572
 573 CFLAGS="$saved_CFLAGS"
 574
 575
 576 AC_CHECK_LIB(cares, ares_parse_mx_reply,
 577             [
 578                     C_ARES_LIBS=-lcares
 579                     AC_DEFINE(HAVE_C_ARES, 1, [Define to use c-ares library])
 580                     have_good_c_ares=yes
 581             ],, $SOCKET_LIBS $NSL_LIBS
 582 )
 583
 584
 585
 586 saved_CFLAGS="$CFLAGS"
 587 CFLAGS="$CFLAGS $SERVER_LIBS"
 588 dnl Check for c-ares
 589 AC_CHECK_HEADER(ares.h,
 590         [AC_CHECK_LIB(cares, ares_parse_mx_reply,
 591                 [
 592                         LIBS="-lcares $LIBS $SERVER_LIBS"
 593                 ],
 594                 [
 595                         AC_MSG_ERROR(libc-ares was not found or is not usable.  Please install libc-ares.)
 596                 ]
 597         )],
 598         [
 599                 AC_MSG_ERROR(ares.h was not found or is not usable.  Please install libc-ares.)
 600         ]
 601 )
 602 CFLAGS="$saved_CFLAGS"
 603
 604 saved_CFLAGS="$CFLAGS"
 605 CFLAGS="$CFLAGS $SERVER_LIBS"
 606 dnl Check for libev
 607 AC_CHECK_HEADER(ev.h,
 608         [AC_TRY_COMPILE([#include <math.h>
 609 #include <ev.h>],
 610                          [
 611                          ev_cleanup abort_by_shutdown;
 612                          struct ev_loop *event_base;
 613                          ev_cleanup_start(event_base, &abort_by_shutdown);
 614                         ],[],
 615                 [
 616                         AC_MSG_ERROR(libev was not found or is not usable.  Please install libev.)
 617                 ])
 618         ],
 619         [
 620                 AC_MSG_ERROR(ev.h was not found or is not usable.  Please install libev.)
 621         ]
 622 )
 623 CFLAGS="$saved_CFLAGS"
 624
 625
 626
 627
 628
 629
 630
 631
 632
 633
 634
 635
 636
 637
 638
 639
 640
 641
 642
 643 # The big search for OpenSSL
 644 if test "$with_ssl" != "no"; then
 645         saved_LIBS="$LIBS"
 646         saved_LDFLAGS="$LDFLAGS"
 647         saved_CFLAGS="$CFLAGS"
 648         if test "x$prefix" != "xNONE"; then
 649                 tryssldir="$tryssldir $prefix"
 650         fi
 651         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 652                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 653                         CFLAGS="$saved_CFLAGS"
 654                         LDFLAGS="$saved_LDFLAGS"
 655                         LIBS="$saved_LIBS -lssl -lcrypto"
 656
 657                         # Skip directories if they don't exist
 658                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 659                                 continue;
 660                         fi
 661                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 662                                 # Try to use $ssldir/lib if it exists, otherwise
 663                                 # $ssldir
 664                                 if test -d "$ssldir/lib" ; then
 665                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 666                                         if test ! -z "$need_dash_r" ; then
 667                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 668                                         fi
 669                                 else
 670                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 671                                         if test ! -z "$need_dash_r" ; then
 672                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 673                                         fi
 674                                 fi
 675                                 # Try to use $ssldir/include if it exists, otherwise
 676                                 # $ssldir
 677                                 if test -d "$ssldir/include" ; then
 678                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 679                                 else
 680                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 681                                 fi
 682                         fi
 683
 684                         # Basic test to check for compatible version and correct linking
 685                         # *does not* test for RSA - that comes later.
 686                         AC_TRY_RUN(
 687                                 [
 688         #include <string.h>
 689         #include <openssl/rand.h>
 690         int main(void)
 691         {
 692                 char a[2048];
 693                 memset(a, 0, sizeof(a));
 694                 RAND_add(a, sizeof(a), sizeof(a));
 695                 return(RAND_status() <= 0);
 696         }
 697                                 ],
 698                                 [
 699                                         found_crypto=1
 700                                         break;
 701                                 ], []
 702                         )
 703
 704                         if test ! -z "$found_crypto" ; then
 705                                 break;
 706                         fi
 707                 done
 708
 709                 if test -z "$ssldir" ; then
 710                         ssldir="(system)"
 711                 fi
 712
 713                 if test ! -z "$found_crypto" ; then
 714                         ac_cv_openssldir=$ssldir
 715                 else
 716                         ac_cv_openssldir="no"
 717                 fi
 718         ])
 719         LIBS="$saved_LIBS"
 720         LDFLAGS="$saved_LDFLAGS"
 721         CFLAGS="$saved_CFLAGS"
 722
 723         if test "x$ac_cv_openssldir" != "xno" ; then
 724                 AC_DEFINE(HAVE_OPENSSL, [], [Define if you have OpenSSL.])
 725                 LIBS="-lssl -lcrypto $LIBS"
 726                 dnl Need to recover ssldir - test above runs in subshell
 727                 ssldir=$ac_cv_openssldir
 728                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 729                         # Try to use $ssldir/lib if it exists, otherwise
 730                         # $ssldir
 731                         if test -d "$ssldir/lib" ; then
 732                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 733                                 if test ! -z "$need_dash_r" ; then
 734                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 735                                 fi
 736                         else
 737                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 738                                 if test ! -z "$need_dash_r" ; then
 739                                         LDFLAGS="-R$ssldir $LDFLAGS"
 740                                 fi
 741                         fi
 742                         # Try to use $ssldir/include if it exists, otherwise
 743                         # $ssldir
 744                         if test -d "$ssldir/include" ; then
 745                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 746                         else
 747                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 748                         fi
 749                 fi
 750         fi
 751 fi
 752
 753 if test "x$with_db" != xno; then
 754         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 755
 756         dblib=""
 757
 758         if test -d "$db_dir/include/db4"; then
 759                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 760                 dblib="db4"
 761         elif test "$db_dir"; then
 762                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 763         elif test -d /usr/include/db4; then
 764                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 765                 dblib="db4"
 766         fi
 767
 768
 769         AC_CHECK_DB([db db-4.1 db-4 db4],
 770                     [
 771                      DATABASE=database.c
 772                     ],
 773                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 774                                   library.  Use --with-db=PATH to specify
 775                                   the path]]))
 776
 777 fi
 778
 779
 780
 781
 782 dnl Checks for the OpenLDAP client library.
 783 if test "x$with_ldap" != xno ; then
 784         AC_CHECK_HEADERS(ldap.h,
 785                 [AC_CHECK_LIB(ldap, ldap_init,
 786                         [ok_ldap=yes],,
 787         )])
 788 fi
 789
 790 if test "x$ok_ldap" = xyes ; then
 791         SERVER_LIBS="-lldap $SERVER_LIBS"
 792         AC_DEFINE(HAVE_LDAP, [], [define this if you have OpenLDAP client available])
 793 fi
 794
 795
 796
 797
 798
 799
 800 dnl Checks for the libdspam mail spam scanning library.
 801 dnl if test "x$with_libdspam" != xno ; then
 802 dnl     AC_CHECK_HEADERS(dspam/libdspam.h,
 803 dnl             [AC_CHECK_LIB(dspam, dspam_init,
 804 dnl                     [ok_libdspam=yes],,
 805 dnl     )])
 806 dnl fi
 807 dnl
 808 dnl if test "x$ok_libdspam" = xyes ; then
 809 dnl     SERVER_LIBS="-ldspam $SERVER_LIBS"
 810 dnl     AC_DEFINE(HAVE_LIBDSPAM, [], [(unfinished) define this if you have the libdspam mail spam scanning library available])
 811 dnl fi
 812
 813
 814
 815 dnl Checks for the Expat XML parser.
 816 AC_CHECK_HEADER(expat.h,
 817         [AC_CHECK_LIB(expat, XML_ParserCreateNS,
 818                 [
 819                         SERVER_LIBS="-lexpat $SERVER_LIBS"
 820                 ],
 821                 [
 822                         AC_MSG_ERROR(The Expat XML parser was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 823                 ]
 824         ,
 825         )],
 826         [
 827                 AC_MSG_ERROR(expat.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 828         ]
 829 )
 830
 831
 832
 833
 834
 835
 836
 837 dnl Checks for libcurl.
 838 AC_CHECK_HEADER(curl/curl.h,
 839         [AC_CHECK_LIB(curl, curl_version,
 840                 [
 841                         SERVER_LIBS="-lcurl $SERVER_LIBS"
 842                 ],
 843                 [
 844                         AC_MSG_ERROR(libcurl was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 845                 ]
 846         ,
 847         )],
 848         [
 849                 AC_MSG_ERROR(curl/curl.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 850         ]
 851 )
 852
 853
 854
 855
 856
 857
 858
 859
 860
 861
 862 dnl Checks for header files.
 863 AC_HEADER_DIRENT
 864 AC_HEADER_STDC
 865 AC_HEADER_SYS_WAIT
 866
 867 dnl
 868 dnl TODO: for the DB header checks, we should check whether the headers
 869 dnl define db_env_create, somehow
 870 dnl
 871 AC_CHECK_HEADERS(dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/stat.h sys/time.h sys/prctl.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h syscall.h sys/syscall.h)
 872
 873 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H, [], [define this if you have the resolv.h header file.]),,
 874 [#ifdef HAVE_SYS_TYPES_H
 875 #include <sys/types.h>
 876 #endif
 877 #ifdef HAVE_NETINET_IN_H
 878 #include <netinet/in.h>
 879 #endif
 880 #ifdef HAVE_ARPA_NAMESER_H
 881 #include <arpa/nameser.h>
 882 #endif])
 883
 884
 885 dnl Checks for typedefs, structures, and compiler characteristics.
 886 AC_C_CONST
 887 AC_TYPE_PID_T
 888 AC_TYPE_SIZE_T
 889 AC_HEADER_TIME
 890
 891 dnl defined in acinclude.m4:
 892 CIT_STRUCT_TM
 893
 894 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 895 [AC_TRY_COMPILE([#include <sys/types.h>
 896 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 897 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 898 if test $ac_cv_struct_ut_type = yes; then
 899         AC_DEFINE(HAVE_UT_TYPE, [], [define this if struct utmp has an ut_type member])
 900 fi
 901
 902 AC_CACHE_CHECK(
 903         [for call semantics from getpwuid_r],
 904         ac_cv_call_getpwuid_r,
 905         [AC_TRY_COMPILE([#include <sys/types.h>
 906 #include <pwd.h>],
 907                          [
 908                                 struct passwd pw, *pwp;
 909                                 char pwbuf[64];
 910                                 uid_t uid;
 911
 912                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 913                         ],
 914                         ac_cv_call_getpwuid_r=yes,
 915                         ac_cv_call_getpwuid_r=no)
 916         ])
 917
 918 if test $ac_cv_call_getpwuid_r = no; then
 919         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 920         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 921         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 922         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 923 else
 924         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 925         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 926         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 927 fi
 928
 929
 930 dnl Our own happy little check for the resolver library.
 931
 932 case "`uname -a`" in
 933  OpenBSD*)
 934         echo "we don't need to check for resolv on openbsd"
 935         ;;
 936  FreeBSD*)
 937         echo "we don't need to check for resolv on freeBSD"
 938         ;;
 939  *)
 940         test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 941         AC_CHECK_LIB(resolv, res_query,
 942                 RESOLV="$RESOLV -lresolv",
 943                 [dnl Have to include resolv.h as res_query is sometimes defined as a macro
 944                         AC_MSG_CHECKING([for res_query in -lresolv (with resolv.h if present)])
 945                         saved_libs="$LIBS"
 946                         LIBS="-lresolv $LIBS"
 947                         AC_TRY_LINK([
 948                                 #ifdef HAVE_RESOLV_H
 949                                 #include <resolv.h>
 950                                 #endif],
 951                                 [res_query(0,0,0,0,0)],
 952                                 [AC_MSG_RESULT(yes)
 953                                                 have_res_query=yes],
 954                                 [AC_MSG_RESULT(no)
 955                                         AC_MSG_ERROR(libresolv was not found.  Citadel requires the resolver library.)
 956                                 ])
 957          ]
 958         )
 959         ;;
 960 esac
 961
 962
 963
 964 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 965 [AC_TRY_COMPILE([#include <sys/types.h>
 966 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 967 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 968 if test $ac_cv_struct_ut_host = yes; then
 969         AC_DEFINE(HAVE_UT_HOST, [], [define this if struct utmp has an ut_host member])
 970 fi
 971
 972 dnl Checks for library functions.
 973 AC_FUNC_GETPGRP
 974 AC_PROG_GCC_TRADITIONAL
 975 AC_TYPE_SIGNAL
 976 AC_FUNC_VPRINTF
 977 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 978
 979 dnl Now check for pthreads
 980
 981 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 982 dnl we need to include pthread.h
 983
 984 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 985 [AC_TRY_LINK([#include <pthread.h>],
 986 [       pthread_t thread;
 987
 988         /* The GNU C library defines this for functions which it implements
 989            to always fail with ENOSYS.  Some functions are actually named
 990            something starting with __ and the normal name is an alias.  */
 991 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 992         choke me
 993 #else
 994         pthread_cancel(thread);
 995 #endif],
 996 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 997 if test "$ac_cv_func_pthread_cancel" = yes; then
 998         AC_DEFINE(HAVE_PTHREAD_CANCEL, [], [define this if you have the pthread_cancel() function])
 999 fi
1000
1001 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
1002 [AC_TRY_LINK([#include <pthread.h>],
1003 [       /* The GNU C library defines this for functions which it implements
1004            to always fail with ENOSYS.  Some functions are actually named
1005            something starting with __ and the normal name is an alias.  */
1006 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
1007         choke me
1008 #else
1009         pthread_create(NULL, NULL, NULL, NULL);
1010 #endif],
1011 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
1012 if test "$ac_cv_func_pthread_create" = yes; then
1013         test "$DATABASE" && TARGETS="client server utils"
1014         if test "x$enable_threaded_client" != xno; then
1015                 AC_DEFINE(THREADED_CLIENT, [], [define this if you want to enable the multithreaded client])
1016         fi
1017 fi
1018
1019 AC_REPLACE_FUNCS(snprintf getutline)
1020
1021 AC_CACHE_CHECK([the weather], ac_cv_weather, [
1022         sleep 1
1023         echo $ECHO_N "opening your window... $ECHO_C" >&6
1024         sleep 2
1025         month=`date | cut -f 2 -d ' '`
1026         case $month in
1027         Dec | Jan | Feb)
1028                 ac_cv_weather="it's cold!"
1029                 ;;
1030         Mar | Apr)
1031                 ac_cv_weather="it's wet!"
1032                 ;;
1033         Jul | Aug)
1034                 ac_cv_weather="it's hot!"
1035                 ;;
1036         Oct | Nov)
1037                 ac_cv_weather="it's cool"
1038                 ;;
1039         May | Jun | Sep | *)
1040                 ac_cv_weather="it's fine"
1041                 ;;
1042         esac
1043         ])
1044
1045
1046
1047
1048 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
1049         number=`date | cut -c 19`
1050         case $number in
1051         7)
1052                 ac_cv_under_the_bed="lunatics and monsters found"
1053                 ;;
1054         *)
1055                 ac_cv_under_the_bed="dust bunnies found"
1056                 ;;
1057         esac
1058         ])
1059
1060
1061 STRUCT_UCRED
1062
1063 dnl Done! Now write the Makefile and sysdep.h
1064 AC_SUBST(RESOLV)
1065 AC_SUBST(chkpwd_LIBS)
1066 AC_SUBST(TARGETS)
1067 AC_SUBST(DATABASE)
1068 AC_SUBST(SERVER_LDFLAGS)
1069 AC_SUBST(SERVER_LIBS)
1070 AC_SUBST(SETUP_LIBS)
1071 AC_SUBST(DIFF)
1072 AC_SUBST(PATCH)
1073 AC_CONFIG_FILES([Makefile])
1074 AC_OUTPUT(database_cleanup.sh po/citadel-setup/Makefile)
1075
1076 if test -z "$DATABASE"; then
1077         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
1078 fi
1079
1080 abs_srcdir="`cd $srcdir && pwd`"
1081 abs_builddir="`pwd`"
1082 if test "$abs_srcdir" != "$abs_builddir"; then
1083    ln -sf $abs_srcdir/include $abs_builddir
1084    ln -sf $abs_srcdir/Make_sources $abs_builddir
1085    ln -sf $abs_srcdir/Make_modules $abs_builddir
1086    for i in $abs_srcdir/*.h ; do
1087       if test "$abs_srcdir/sysdep.h" != "$i"; then
1088          ln -sf $i $abs_builddir
1089       fi
1090    done
1091    for d in `/bin/ls $abs_srcdir/modules/`; do
1092         (mkdir -p $abs_builddir/modules/$d)
1093    done
1094    if test -d "$abs_srcdir/user_modules/"; then
1095       for d in `/bin/ls $abs_srcdir/user_modules/`; do
1096         (mkdir -p $abs_builddir/user_modules/$d)
1097         done
1098    fi
1099    mkdir -p $abs_builddir/utils
1100    mkdir -p $abs_builddir/utillib
1101    mkdir -p $abs_builddir/textclient
1102 fi
1103
1104 if test -n "$srcdir"; then
1105    export srcdir=.
1106 fi
1107
1108
1109 echo ------------------------------------------------------------------------
1110 echo 'LDAP support:                    ' $ok_ldap
1111 echo 'Character set conversion support:' $ok_iconv
1112 echo 'Boehm-Demers-Weiser support:     ' $ok_gc
1113 dnl echo 'DSpam Scanning support:          ' $ok_libdspam
1114 echo
1115 echo 'Note: if you are not using Linux, make sure you are using GNU make'
1116 echo '(gmake) to compile Citadel.'
1117 echo