citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.52)
   3 AC_INIT([Citadel], [912], [http://www.citadel.org/])
   4 AC_REVISION([$Revision: 5108 $])
   5 AC_CONFIG_SRCDIR([citserver.c])
   6 AC_CONFIG_HEADER(sysdep.h)
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_PREFIX_DEFAULT(/usr/local/citadel)
   9 if test "$prefix" = NONE; then
  10         AC_DEFINE_UNQUOTED(CTDLDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  11         ssl_dir="$ac_default_prefix/keys"
  12         localedir=$ac_default_prefix
  13 else
  14         AC_DEFINE_UNQUOTED(CTDLDIR, "$prefix", [define this to the Citadel home directory])
  15         ssl_dir="$prefix/keys"
  16         localedir=$prefix
  17 fi
  18
  19 dnl Make sure we see all GNU and Solaris extensions.
  20 AC_GNU_SOURCE
  21
  22
  23 dnl Checks for the Datadir
  24 AC_ARG_WITH(datadir,
  25                     [  --with-datadir          directory to store the databases under],
  26                         [ if test "x$withval" != "xno" ; then
  27                                               AC_DEFINE(HAVE_DATA_DIR,[],[use alternate database location?])
  28                                               AC_DEFINE_UNQUOTED(DATA_DIR, "$withval",[define, if the user suplied a data-directory to use.])
  29                                               MAKE_DATA_DIR=$withval
  30                                               AC_SUBST(MAKE_DATA_DIR)
  31                           fi
  32                         ]
  33 )
  34
  35
  36 dnl Checks for the helpDatadir
  37 AC_ARG_WITH(helpdir,
  38                     [  --with-helpdir          directory to store the helpfiles under],
  39                         [ if test "x$withval" != "xno" ; then
  40                                               AC_DEFINE(HAVE_HELP_DIR,[],[use alternate database location?])
  41                                               AC_DEFINE_UNQUOTED(HELP_DIR, "$withval",[define, if the user suplied a helpfile-directory to use.])
  42                                               MAKE_HELP_DIR=$withval
  43                                               AC_SUBST(MAKE_HELP_DIR)
  44                           fi
  45                         ]
  46 )
  47
  48 dnl Checks for the Static Datadir
  49 AC_ARG_WITH(staticdatadir,
  50                     [  --with-staticdatadir    directory to store citadels system messages under],
  51                         [ if test "x$withval" != "xno" ; then
  52                                                   AC_DEFINE(HAVE_STATICDATA_DIR, [], [should we activate an alternate static text location?])
  53                                                   AC_DEFINE_UNQUOTED(STATICDATA_DIR, "$withval", [where do we put our static text data?])
  54                                                   MAKE_STATICDATA_DIR=$withval
  55                                                   AC_SUBST(MAKE_STATICDATA_DIR)
  56                           fi
  57                         ]
  58 )
  59
  60
  61 dnl Checks for the SSLdir
  62 dnl this is a bit different than the rest,
  63 dnl because of the citadel used to have a keys/ subdir.
  64 AC_ARG_WITH(ssldir,
  65                     [  --with-ssldir           directory to store the ssl certificates under],
  66                         [ if test "x$withval" != "xno" ; then
  67
  68                                                   ssl_dir="$withval"
  69                           fi
  70                         AC_SUBST(MAKE_SSL_DIR)
  71                         ]
  72 )
  73 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
  74
  75
  76 dnl Checks for the spooldir
  77 AC_ARG_WITH(spooldir,
  78                         [  --with-spooldir         directory to keep queues under],
  79                         [ if test "x$withval" != "xno" ; then
  80                                                 AC_DEFINE(HAVE_SPOOL_DIR, [], [enable alternate spool dir?])
  81                                                 AC_DEFINE_UNQUOTED(SPOOL_DIR,"$withval", [where do we place our spool dirs?])
  82                                                 MAKE_SPOOL_DIR=$withval
  83                                                 AC_SUBST(MAKE_SPOOL_DIR)
  84                            fi
  85                         ]
  86 )
  87
  88
  89 dnl Checks for the Configdir
  90 AC_ARG_WITH(sysconfdir,
  91                         [  --with-sysconfdir       directory to store the configs under],
  92                         [ if test "x$withval" != "xno" ; then
  93                                             AC_DEFINE(HAVE_ETC_DIR, [], [should we search our system config in an alternate place?])
  94                                                 AC_DEFINE_UNQUOTED(ETC_DIR, "$withval", [where to search our config files])
  95                                                 MAKE_ETC_DIR=$withval
  96                                                 AC_SUBST(MAKE_ETC_DIR)
  97                           fi
  98                         ]
  99 )
 100
 101 dnl Checks for the Configdir
 102 AC_ARG_WITH(autosysconfdir,
 103                         [  --with-autosysconfdir         directory to store the automaticaly maintained configs under],
 104                         [ if test "x$withval" != "xno" ; then
 105                                             AC_DEFINE(HAVE_AUTO_ETC_DIR, [], [should we search our automatic config in an alternate place?])
 106                                                 AC_DEFINE_UNQUOTED(AUTO_ETC_DIR, "$withval", [where to search our automatic config files])
 107                                                 MAKE_AUTO_ETC_DIR=$withval
 108                                                 AC_SUBST(MAKE_AUTO_ETC_DIR)
 109                           fi
 110                         ]
 111 )
 112
 113 dnl Checks for where to put our utilities
 114 AC_ARG_WITH(utility-bindir,
 115                         [  --with-utility-bindir   directory where to find helper binaries],
 116                         [ if test "x$withval" != "xno" ; then
 117                                             AC_DEFINE(HAVE_UTILBIN_DIR,[],[should we put our helper binaries to another location?])
 118                                                 AC_DEFINE_UNQUOTED(UTILBIN_DIR, "$withval", [were to put our helper programs])
 119                                                 MAKE_UTILBIN_DIR=$withval
 120                                                 AC_SUBST(MAKE_UTILBIN_DIR)
 121                           fi
 122                         ]
 123 )
 124
 125
 126 dnl Checks for the run-dir for the sockets
 127 AC_ARG_WITH(rundir,
 128                         [  --with-rundir           directory to place runtime files (UDS) to?],
 129                         [ if test "x$withval" != "xno" ; then
 130                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 131                                                 AC_DEFINE_UNQUOTED(RUN_DIR, "$withval", [define, where the config should go in unix style])
 132                                                 MAKE_RUN_DIR=$withval
 133                                                 AC_SUBST(MAKE_RUN_DIR)
 134                           fi
 135                         ]
 136 )
 137
 138
 139 dnl Checks for the Pseudo Random Generator sockets TODO: this keeps being default.
 140 AC_DEFINE_UNQUOTED(EGD_POOL, "/var/run/egd-pool", [place to keep our pseudo random generator file])
 141 AC_ARG_WITH(egdpool,
 142                         [  --with-egdpool          the socket from Pseudo Random Generator, defaults to /var/run/egd-pool],
 143                         [ if test "x$withval" != "xno" ; then
 144                                                 AC_DEFINE_UNQUOTED(EGD_POOL, "$withval", [the socket from Pseudo Random Generator])
 145                           fi
 146                         ]
 147 )
 148
 149
 150 AC_ARG_WITH(docdir,
 151                         [  --with-docdir           where to install the documentation. default: /usr/local/citadel/],
 152                         [ if test "x$withval" != "xno" ; then
 153                                         MAKE_DOC_DIR=$withval
 154                                         AC_SUBST(MAKE_DOC_DIR)
 155                           fi
 156                         ]
 157 )
 158
 159 dnl where to put the locale files
 160 AC_ARG_WITH(localedir,
 161                     [  --with-localedir          directory to put the locale files to],
 162                         [ if test "x$withval" != "xno" ; then
 163                             localedir=$withval
 164                           fi
 165                         ]
 166 )
 167 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 168 LOCALEDIR=$localedir
 169 AC_SUBST(LOCALEDIR)
 170
 171
 172
 173 dnl Checks for the zlib compression library.
 174 saved_CFLAGS="$CFLAGS"
 175 CFLAGS="$CFLAGS $SERVER_LIBS"
 176 AC_CHECK_HEADER(zlib.h,
 177         [AC_CHECK_LIB(z, zlibVersion,
 178                 [
 179                         LIBS="-lz $LIBS $SERVER_LIBS"
 180                 ],
 181                 [
 182                         AC_MSG_ERROR(zlib was not found or is not usable.  Please install zlib.)
 183                 ]
 184         ,
 185         )],
 186         [
 187                 AC_MSG_ERROR(zlib.h was not found or is not usable.  Please install zlib.)
 188         ]
 189 )
 190 CFLAGS="$saved_CFLAGS"
 191
 192 dnl Here is the check for a libc integrated iconv
 193 AC_ARG_ENABLE(iconv,
 194         [  --disable-iconv         do not use iconv charset conversion],
 195         ok_iconv=no, ok_iconv=yes)
 196
 197 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 198 AC_TRY_RUN([
 199         #include <iconv.h>
 200         main() {
 201                 iconv_t ic = (iconv_t)(-1) ;
 202                 ic = iconv_open("UTF-8", "us-ascii");
 203                 iconv_close(ic);
 204                 exit(0);
 205         }
 206  ],
 207                 [
 208                   ok_iconv=yes
 209                   AC_MSG_RESULT([yes])
 210                 ],
 211                 [
 212                   ok_iconv=no
 213                   AC_MSG_RESULT([no])
 214                 ]
 215 )
 216
 217 dnl Check for iconv in external libiconv
 218 if test "$ok_iconv" = no; then
 219         AC_MSG_CHECKING(Checking for an external libiconv)
 220         OLD_LDFLAGS="$LDFLAGS"
 221         LDFLAGS="$LDFLAGS -liconv"
 222         AC_TRY_RUN([
 223                         #include <iconv.h>
 224                         main() {
 225                                 iconv_t ic = (iconv_t)(-1) ;
 226                                 ic = iconv_open("UTF-8", "us-ascii");
 227                                 iconv_close(ic);
 228                         }
 229                 ],
 230                         [
 231                           ok_iconv=yes
 232                           AC_MSG_RESULT([yes])
 233                         ],
 234                         [
 235                           ok_iconv=no
 236                           LDFLAGS="$OLD_LDFLAGS"
 237                           AC_MSG_RESULT([no])
 238                         ]
 239                 )
 240 fi
 241 if test "$ok_iconv" != "no"; then
 242         AC_MSG_RESULT(Citadel will be built with character set conversion.)
 243         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 244 else
 245         AC_MSG_RESULT(Citadel will be built without character set conversion.)
 246 fi
 247
 248 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 249
 250 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
 251
 252 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
 253 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
 254 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Berkeley DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
 255 AC_ARG_WITH(ssl,
 256         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
 257         [
 258                 if test "x$withval" != "xno" ; then
 259                         tryssldir=$withval
 260                 fi
 261         ]
 262 )
 263 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
 264 AC_ARG_WITH(with_gc, [  --with-gc             use the Boehm-Demers-Weiser garbage collection library])
 265
 266 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
 267         db_dir="$with_db"
 268         with_db=yes
 269 else
 270         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
 271           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
 272           && db_dir=/usr/local
 273
 274         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
 275         test -d /usr/local/BerkeleyDB.4.2 && db_dir=/usr/local/BerkeleyDB.4.2
 276         test -d /usr/local/BerkeleyDB.4.3 && db_dir=/usr/local/BerkeleyDB.4.3
 277         test -d /usr/local/BerkeleyDB.4.4 && db_dir=/usr/local/BerkeleyDB.4.4
 278         test -d /usr/local/BerkeleyDB.4.5 && db_dir=/usr/local/BerkeleyDB.4.5
 279 fi
 280
 281 AC_CANONICAL_HOST
 282 PTHREAD_DEFS=-D_REENTRANT
 283 AC_MSG_CHECKING([how to compile with POSIX threads])
 284 case "$host" in
 285         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
 286         dnl for dlopen(), and has a wrapper script to link with shared libs.
 287         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
 288         *-*-bsdi[123]*)
 289                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
 290                 AC_DEFINE(HAVE_NONREENTRANT_NETDB,[], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 291                 AC_MSG_RESULT([Old BSDI])
 292         ;;
 293         *-*-bsdi*)
 294                 AC_DEFINE(HAVE_NONREENTRANT_NETDB, [], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 295                 AC_MSG_RESULT([BSD/OS])
 296         ;;
 297         dnl Curses support on Mac OS X is kind of screwed at the moment.
 298         dnl TCP buffering isn't ideal under OS X. This define should also be
 299         dnl checked in other cases of OS X-Linux differences.
 300         *-*-darwin*)
 301                 AC_DEFINE(HAVE_DARWIN, [], [define if using OS X/Darwin])
 302                 AC_MSG_RESULT([Mac OS X])
 303         ;;
 304         dnl Digital Unix has an odd way to build for pthreads, and we can't
 305         dnl build pthreads programs with gcc due to header problems.
 306         alpha*-dec-osf*)
 307                 test -z "$CC" && CC=cc
 308                 LIBS="-lpthread -lexc $LIBS"
 309                 check_pthread=no
 310                 AC_MSG_RESULT([Tru64 or Digital UNIX])
 311         ;;
 312         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
 313         *-*-freebsd*)
 314                 if test "$with_kthread" = yes; then
 315                         LIBS="-kthread $LIBS"
 316                 else
 317                         LIBS="-pthread $LIBS"
 318                 fi
 319                 check_pthread=no
 320                 PTHREAD_DEFS=-D_THREAD_SAFE
 321                 AC_MSG_RESULT([FreeBSD])
 322         ;;
 323         *-*-openbsd*)
 324                 LIBS="-pthread $LIBS"
 325                 check_pthread=no
 326                 PTHREAD_DEFS=-pthread
 327                 AC_MSG_RESULT([OpenBSD])
 328         ;;
 329         *-*-linux*)
 330                 PTHREAD_DEFS="-D_REENTRANT -pthread"
 331                 AC_MSG_RESULT([Linux])
 332         ;;
 333         *-*-solaris*)
 334                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
 335                 AC_MSG_RESULT([Solaris])
 336         ;;
 337         *-*-cygwin*)
 338                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
 339                 AC_MSG_RESULT([Cygwin])
 340         ;;
 341         *)
 342                 AC_MSG_RESULT([default])
 343         ;;
 344 esac
 345 dnl DEFS="$DEFS $PTHREAD_DEFS"
 346
 347
 348 dnl Checks for programs.
 349 AC_PROG_CC
 350
 351
 352
 353 dnl Set up system-dependent compiler flags.
 354 if test "$GCC" = yes; then
 355         if test "$CC" = icc; then
 356                 CFLAGS="$CFLAGS -w1"
 357         else
 358                 case "$host" in
 359                         *-*-solaris*|alpha*-dec-osf*)
 360                                 CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts $PTHREAD_DEFS"
 361                         ;;
 362                         *)
 363                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes -Wno-strict-aliasing $PTHREAD_DEFS"
 364                         ;;
 365                 esac
 366         fi
 367 fi
 368
 369 if test "x$enable_pie" = xyes; then
 370         save_CFLAGS="$CFLAGS"
 371         save_LDFLAGS="$LDFLAGS"
 372         CFLAGS="$CFLAGS -fpie"
 373         LDFLAGS="$LDFLAGS -pie -fpie"
 374         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 375         [AC_TRY_LINK([], [],
 376         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 377         if test $ac_cv_pie_fpie = no; then
 378                 CFLAGS="$save_CFLAGS"
 379                 LDFLAGS="$save_LDFLAGS"
 380         fi
 381 fi
 382
 383 AC_MSG_CHECKING([how to create dependancy checks])
 384                  if test -n "`$CC -V 2>&1 |grep Sun`"; then
 385                         DEPEND_FLAG=-xM;
 386                  else
 387                         DEPEND_FLAG=-M
 388                  fi
 389 AC_SUBST(DEPEND_FLAG)
 390
 391
 392 AC_PROG_INSTALL
 393 AC_PROG_YACC
 394 AC_PATH_PROG(DIFF,diff)
 395 AC_PATH_PROG(PATCH,patch)
 396 missing_dir=`cd $ac_aux_dir && pwd`
 397 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 398 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 399
 400 dnl Checks for system services.
 401
 402 dnl Check the size of various builtin types; see typesize.h (error)
 403 AC_CHECK_SIZEOF(char, 0)
 404 AC_CHECK_SIZEOF(short, 0)
 405 AC_CHECK_SIZEOF(int, 0)
 406 AC_CHECK_SIZEOF(long, 0)
 407 AC_CHECK_SIZEOF(size_t, 0)
 408 AC_CHECK_SIZEOF(loff_t, 0)
 409 dnl AC_CHECK_SIZEOF(long long, 0)
 410
 411 dnl Checks for libraries.
 412
 413 dnl We want to test for the following in libc before checking for their
 414 dnl respective libraries, because some systems (like Irix) have both, and the
 415 dnl non-libc versions may be broken.
 416 AC_CHECK_FUNCS(crypt gethostbyname connect getpwnam_r getpwuid_r getloadavg)
 417
 418 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 419
 420 if test "$ok_nls" != "no"; then
 421         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 422         ok_nls=$ok_xgettext
 423 fi
 424
 425 if test "$ok_nls" != "no"; then
 426         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 427         ok_nls=$ok_msgmerge
 428 fi
 429
 430 if test "$ok_nls" != "no"; then
 431         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 432         ok_nls=$ok_msgfmt
 433 fi
 434
 435 if test "$ok_nls" != "no"; then
 436         AC_MSG_RESULT(citadel will be built with national language support.)
 437         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 438         PROG_SUBDIRS="$PROG_SUBDIRS po/citadel-setup"
 439 else
 440         AC_MSG_RESULT(citadel will be built without national language support.)
 441 fi
 442
 443 dnl disable backtrace if we don't want it.
 444 AC_ARG_WITH(backtrace,
 445                     [  --with-backtrace        enable backtrace dumps in the syslog],
 446                         [ if test "x$withval" != "xno" ; then
 447                              CFLAGS="$CFLAGS  -rdynamic "
 448                              LDFLAGS="$LDFLAGS  -rdynamic "
 449                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -rdynamic "
 450                              AC_CHECK_FUNCS(backtrace)
 451                           fi
 452                         ]
 453 )
 454
 455 dnl disable backtrace if we don't want it.
 456 AC_ARG_WITH(gprof,
 457                     [  --with-gprof            enable profiling],
 458                         [ if test "x$withval" != "xno" ; then
 459                              CFLAGS="$CFLAGS  -pg "
 460                              LDFLAGS="$LDFLAGS  -pg "
 461                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -pg "
 462                           fi
 463                         ]
 464 )
 465
 466 if test "$ac_cv_func_gethostbyname" = no; then
 467         AC_CHECK_LIB(nsl, gethostbyname)
 468 fi
 469
 470 if test "$ac_cv_func_connect" = no; then
 471         AC_CHECK_LIB(socket, connect)
 472 fi
 473
 474 dnl Check for Solaris realtime support
 475 AC_CHECK_LIB(rt, sched_yield)
 476
 477 dnl Determine the system's authentication capabilities.
 478 dnl We currently support PAM, standard getpwnam(), and getspnam()
 479 dnl (Linux shadow passwords)
 480
 481 save_LIBS=$LIBS
 482 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 483         LIBS="-lpam $LIBS"])
 484 AC_CHECK_FUNCS(pam_start)
 485 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 486         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 487                 save_LIBS=$LIBS
 488                 AC_SEARCH_LIBS(getspnam, shadow, [
 489                         if test "$ac_cv_search_getspnam" = -lshadow; then
 490                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 491                         fi])
 492                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 493                 if test "$ac_cv_func_crypt" = no; then
 494                         AC_CHECK_LIB(crypt, crypt, [
 495                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 496                                 test "$enable_chkpwd" = no && \
 497                                         LIBS="-lcrypt $LIBS"])
 498                 fi
 499         fi
 500
 501 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 502
 503 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 504 dnl which the -pthread flag takes care of this.)
 505 if test "$check_pthread" != no; then
 506         AC_CHECK_LIB(pthread, pthread_create)
 507         AC_CHECK_LIB(pthreads, pthread_create)
 508 fi
 509
 510 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 511
 512 dnl Checks for the libical iCalendar library.
 513 AC_CHECK_HEADER(libical/ical.h,
 514         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 515                 [
 516                         SERVER_LIBS="-lical $SERVER_LIBS"
 517                 ],
 518                 [
 519                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 520                 ]
 521         ,
 522         )],
 523         [
 524                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 525         ]
 526 )
 527
 528
 529 dnl Checks for the libsieve mailbox sorting library.
 530 AC_CHECK_HEADER(sieve2.h,
 531         [AC_CHECK_LIB(sieve, sieve2_license,
 532                 [
 533                         SERVER_LIBS="-lsieve $SERVER_LIBS"
 534                 ],
 535                 [
 536                         AC_MSG_ERROR(libsieve was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 537                 ]
 538         ,
 539         )],
 540         [
 541                 AC_MSG_ERROR(sieve2.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 542         ]
 543 )
 544
 545 saved_CFLAGS="$CFLAGS"
 546 CFLAGS="$CFLAGS $SERVER_LIBS"
 547 dnl Check for libcitadel
 548 AC_CHECK_HEADER(libcitadel.h,
 549         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 550                 [
 551                         LIBS="-lcitadel $LIBS $SERVER_LIBS"
 552                         chkpwd_LIBS="-lcitadel $chkpwd_LIBS"
 553                 ],
 554                 [
 555                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 556                 ]
 557         ,
 558         )],
 559         [
 560                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 561         ]
 562 )
 563
 564 CFLAGS="$saved_CFLAGS"
 565
 566
 567 # The big search for OpenSSL
 568 if test "$with_ssl" != "no"; then
 569         saved_LIBS="$LIBS"
 570         saved_LDFLAGS="$LDFLAGS"
 571         saved_CFLAGS="$CFLAGS"
 572         if test "x$prefix" != "xNONE"; then
 573                 tryssldir="$tryssldir $prefix"
 574         fi
 575         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 576                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 577                         CFLAGS="$saved_CFLAGS"
 578                         LDFLAGS="$saved_LDFLAGS"
 579                         LIBS="$saved_LIBS -lssl -lcrypto"
 580
 581                         # Skip directories if they don't exist
 582                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 583                                 continue;
 584                         fi
 585                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 586                                 # Try to use $ssldir/lib if it exists, otherwise
 587                                 # $ssldir
 588                                 if test -d "$ssldir/lib" ; then
 589                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 590                                         if test ! -z "$need_dash_r" ; then
 591                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 592                                         fi
 593                                 else
 594                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 595                                         if test ! -z "$need_dash_r" ; then
 596                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 597                                         fi
 598                                 fi
 599                                 # Try to use $ssldir/include if it exists, otherwise
 600                                 # $ssldir
 601                                 if test -d "$ssldir/include" ; then
 602                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 603                                 else
 604                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 605                                 fi
 606                         fi
 607
 608                         # Basic test to check for compatible version and correct linking
 609                         # *does not* test for RSA - that comes later.
 610                         AC_TRY_RUN(
 611                                 [
 612         #include <string.h>
 613         #include <openssl/rand.h>
 614         int main(void)
 615         {
 616                 char a[2048];
 617                 memset(a, 0, sizeof(a));
 618                 RAND_add(a, sizeof(a), sizeof(a));
 619                 return(RAND_status() <= 0);
 620         }
 621                                 ],
 622                                 [
 623                                         found_crypto=1
 624                                         break;
 625                                 ], []
 626                         )
 627
 628                         if test ! -z "$found_crypto" ; then
 629                                 break;
 630                         fi
 631                 done
 632
 633                 if test -z "$ssldir" ; then
 634                         ssldir="(system)"
 635                 fi
 636
 637                 if test ! -z "$found_crypto" ; then
 638                         ac_cv_openssldir=$ssldir
 639                 else
 640                         ac_cv_openssldir="no"
 641                 fi
 642         ])
 643         LIBS="$saved_LIBS"
 644         LDFLAGS="$saved_LDFLAGS"
 645         CFLAGS="$saved_CFLAGS"
 646
 647         if test "x$ac_cv_openssldir" != "xno" ; then
 648                 AC_DEFINE(HAVE_OPENSSL, [], [Define if you have OpenSSL.])
 649                 LIBS="-lssl -lcrypto $LIBS"
 650                 dnl Need to recover ssldir - test above runs in subshell
 651                 ssldir=$ac_cv_openssldir
 652                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 653                         # Try to use $ssldir/lib if it exists, otherwise
 654                         # $ssldir
 655                         if test -d "$ssldir/lib" ; then
 656                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 657                                 if test ! -z "$need_dash_r" ; then
 658                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 659                                 fi
 660                         else
 661                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 662                                 if test ! -z "$need_dash_r" ; then
 663                                         LDFLAGS="-R$ssldir $LDFLAGS"
 664                                 fi
 665                         fi
 666                         # Try to use $ssldir/include if it exists, otherwise
 667                         # $ssldir
 668                         if test -d "$ssldir/include" ; then
 669                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 670                         else
 671                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 672                         fi
 673                 fi
 674         fi
 675 fi
 676
 677 if test "x$with_db" != xno; then
 678         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 679
 680         dblib=""
 681
 682         if test -d "$db_dir/include/db4"; then
 683                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 684                 dblib="db4"
 685         elif test "$db_dir"; then
 686                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 687         elif test -d /usr/include/db4; then
 688                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 689                 dblib="db4"
 690         fi
 691
 692
 693         AC_CHECK_DB([db db-4.1 db-4 db4],
 694                     [
 695                      DATABASE=database.c
 696                     ],
 697                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 698                                   library.  Use --with-db=PATH to specify
 699                                   the path]]))
 700
 701 fi
 702
 703
 704
 705
 706 dnl Checks for the OpenLDAP client library.
 707 if test "x$with_ldap" != xno ; then
 708         AC_CHECK_HEADERS(ldap.h,
 709                 [AC_CHECK_LIB(ldap, ldap_initialize,
 710                         [ok_ldap=yes],,
 711         )])
 712 fi
 713
 714 if test "x$ok_ldap" = xyes ; then
 715         SERVER_LIBS="-lldap $SERVER_LIBS"
 716         AC_DEFINE(HAVE_LDAP, [], [define this if you have OpenLDAP client available])
 717 fi
 718
 719
 720
 721
 722
 723
 724 dnl Checks for the Expat XML parser.
 725 AC_CHECK_HEADER(expat.h,
 726         [AC_CHECK_LIB(expat, XML_ParserCreateNS,
 727                 [
 728                         SERVER_LIBS="-lexpat $SERVER_LIBS"
 729                 ],
 730                 [
 731                         AC_MSG_ERROR(The Expat XML parser was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 732                 ]
 733         ,
 734         )],
 735         [
 736                 AC_MSG_ERROR(expat.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 737         ]
 738 )
 739
 740
 741
 742
 743
 744
 745
 746 dnl Checks for libcurl.
 747 AC_CHECK_HEADER(curl/curl.h,
 748         [AC_CHECK_LIB(curl, curl_version,
 749                 [
 750                         SERVER_LIBS="-lcurl $SERVER_LIBS"
 751                 ],
 752                 [
 753                         AC_MSG_ERROR(libcurl was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 754                 ]
 755         ,
 756         )],
 757         [
 758                 AC_MSG_ERROR(curl/curl.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 759         ]
 760 )
 761
 762
 763
 764
 765
 766
 767
 768
 769
 770
 771 dnl Checks for header files.
 772 AC_HEADER_DIRENT
 773 AC_HEADER_STDC
 774 AC_HEADER_SYS_WAIT
 775
 776 dnl
 777 dnl TODO: for the DB header checks, we should check whether the headers
 778 dnl define db_env_create, somehow
 779 dnl
 780 AC_CHECK_HEADERS(dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/stat.h sys/time.h sys/prctl.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h syscall.h sys/syscall.h)
 781
 782 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H, [], [define this if you have the resolv.h header file.]),,
 783 [#ifdef HAVE_SYS_TYPES_H
 784 #include <sys/types.h>
 785 #endif
 786 #ifdef HAVE_NETINET_IN_H
 787 #include <netinet/in.h>
 788 #endif
 789 #ifdef HAVE_ARPA_NAMESER_H
 790 #include <arpa/nameser.h>
 791 #endif])
 792
 793
 794 dnl Checks for typedefs, structures, and compiler characteristics.
 795 AC_C_CONST
 796 AC_TYPE_PID_T
 797 AC_TYPE_SIZE_T
 798 AC_HEADER_TIME
 799
 800 dnl defined in acinclude.m4:
 801 CIT_STRUCT_TM
 802
 803 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 804 [AC_TRY_COMPILE([#include <sys/types.h>
 805 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 806 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 807 if test $ac_cv_struct_ut_type = yes; then
 808         AC_DEFINE(HAVE_UT_TYPE, [], [define this if struct utmp has an ut_type member])
 809 fi
 810
 811 AC_CACHE_CHECK(
 812         [for call semantics from getpwuid_r],
 813         ac_cv_call_getpwuid_r,
 814         [AC_TRY_COMPILE([#include <sys/types.h>
 815 #include <pwd.h>],
 816                          [
 817                                 struct passwd pw, *pwp;
 818                                 char pwbuf[64];
 819                                 uid_t uid;
 820
 821                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 822                         ],
 823                         ac_cv_call_getpwuid_r=yes,
 824                         ac_cv_call_getpwuid_r=no)
 825         ])
 826
 827 if test $ac_cv_call_getpwuid_r = no; then
 828         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 829         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 830         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 831         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 832 else
 833         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 834         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 835         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 836 fi
 837
 838
 839 dnl Our own happy little check for the resolver library.
 840
 841 case "`uname -a`" in
 842  OpenBSD*)
 843         echo "we don't need to check for resolv on openbsd"
 844         ;;
 845  FreeBSD*)
 846         echo "we don't need to check for resolv on freeBSD"
 847         ;;
 848  *)
 849         test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 850         AC_CHECK_LIB(resolv, res_query,
 851                 RESOLV="$RESOLV -lresolv",
 852                 [dnl Have to include resolv.h as res_query is sometimes defined as a macro
 853                         AC_MSG_CHECKING([for res_query in -lresolv (with resolv.h if present)])
 854                         saved_libs="$LIBS"
 855                         LIBS="-lresolv $LIBS"
 856                         AC_TRY_LINK([
 857                                 #ifdef HAVE_RESOLV_H
 858                                 #include <resolv.h>
 859                                 #endif],
 860                                 [res_query(0,0,0,0,0)],
 861                                 [AC_MSG_RESULT(yes)
 862                                                 have_res_query=yes],
 863                                 [AC_MSG_RESULT(no)
 864                                         AC_MSG_ERROR(libresolv was not found.  Citadel requires the resolver library.)
 865                                 ])
 866          ]
 867         )
 868         ;;
 869 esac
 870
 871
 872
 873 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 874 [AC_TRY_COMPILE([#include <sys/types.h>
 875 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 876 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 877 if test $ac_cv_struct_ut_host = yes; then
 878         AC_DEFINE(HAVE_UT_HOST, [], [define this if struct utmp has an ut_host member])
 879 fi
 880
 881 dnl Checks for library functions.
 882 AC_FUNC_GETPGRP
 883 AC_PROG_GCC_TRADITIONAL
 884 AC_TYPE_SIGNAL
 885 AC_FUNC_VPRINTF
 886 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 887
 888 dnl Now check for pthreads
 889
 890 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 891 dnl we need to include pthread.h
 892
 893 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 894 [AC_TRY_LINK([#include <pthread.h>],
 895 [       pthread_t thread;
 896
 897         /* The GNU C library defines this for functions which it implements
 898            to always fail with ENOSYS.  Some functions are actually named
 899            something starting with __ and the normal name is an alias.  */
 900 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 901         choke me
 902 #else
 903         pthread_cancel(thread);
 904 #endif],
 905 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 906 if test "$ac_cv_func_pthread_cancel" = yes; then
 907         AC_DEFINE(HAVE_PTHREAD_CANCEL, [], [define this if you have the pthread_cancel() function])
 908 fi
 909
 910 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
 911 [AC_TRY_LINK([#include <pthread.h>],
 912 [       /* The GNU C library defines this for functions which it implements
 913            to always fail with ENOSYS.  Some functions are actually named
 914            something starting with __ and the normal name is an alias.  */
 915 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 916         choke me
 917 #else
 918         pthread_create(NULL, NULL, NULL, NULL);
 919 #endif],
 920 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
 921 if test "$ac_cv_func_pthread_create" = yes; then
 922         test "$DATABASE" && TARGETS="server utils"
 923 fi
 924
 925 AC_CACHE_CHECK([the weather], ac_cv_weather, [
 926         sleep 1
 927         echo $ECHO_N "opening your window... $ECHO_C" >&6
 928         sleep 2
 929         month=`date | cut -f 2 -d ' '`
 930         case $month in
 931         Dec | Jan | Feb)
 932                 ac_cv_weather="it's cold!"
 933                 ;;
 934         Mar | Apr)
 935                 ac_cv_weather="it's wet!"
 936                 ;;
 937         Jul | Aug)
 938                 ac_cv_weather="it's hot!"
 939                 ;;
 940         Oct | Nov)
 941                 ac_cv_weather="it's cool"
 942                 ;;
 943         May | Jun | Sep | *)
 944                 ac_cv_weather="it's fine"
 945                 ;;
 946         esac
 947         ])
 948
 949
 950
 951
 952 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
 953         number=`date | cut -c 19`
 954         case $number in
 955         7)
 956                 ac_cv_under_the_bed="lunatics and monsters found"
 957                 ;;
 958         *)
 959                 ac_cv_under_the_bed="dust bunnies found"
 960                 ;;
 961         esac
 962         ])
 963
 964
 965 STRUCT_UCRED
 966
 967 dnl Done! Now write the Makefile and sysdep.h
 968 AC_SUBST(RESOLV)
 969 AC_SUBST(chkpwd_LIBS)
 970 AC_SUBST(TARGETS)
 971 AC_SUBST(DATABASE)
 972 AC_SUBST(SERVER_LDFLAGS)
 973 AC_SUBST(SERVER_LIBS)
 974 AC_SUBST(SETUP_LIBS)
 975 AC_SUBST(DIFF)
 976 AC_SUBST(PATCH)
 977 AC_CONFIG_FILES([Makefile])
 978 AC_OUTPUT(database_cleanup.sh po/citadel-setup/Makefile)
 979
 980 if test -z "$DATABASE"; then
 981         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
 982 fi
 983
 984 abs_srcdir="`cd $srcdir && pwd`"
 985 abs_builddir="`pwd`"
 986 if test "$abs_srcdir" != "$abs_builddir"; then
 987    ln -sf $abs_srcdir/include $abs_builddir
 988    ln -sf $abs_srcdir/Make_sources $abs_builddir
 989    ln -sf $abs_srcdir/Make_modules $abs_builddir
 990    for i in $abs_srcdir/*.h ; do
 991       if test "$abs_srcdir/sysdep.h" != "$i"; then
 992          ln -sf $i $abs_builddir
 993       fi
 994    done
 995    for d in `/bin/ls $abs_srcdir/modules/`; do
 996         (mkdir -p $abs_builddir/modules/$d)
 997    done
 998    if test -d "$abs_srcdir/user_modules/"; then
 999       for d in `/bin/ls $abs_srcdir/user_modules/`; do
1000         (mkdir -p $abs_builddir/user_modules/$d)
1001         done
1002    fi
1003    mkdir -p $abs_builddir/utils
1004    mkdir -p $abs_builddir/utillib
1005 fi
1006
1007 if test -n "$srcdir"; then
1008    export srcdir=.
1009 fi
1010
1011
1012 echo ------------------------------------------------------------------------
1013 echo 'LDAP support:                    ' $ok_ldap
1014 echo 'Character set conversion support:' $ok_iconv
1015 echo 'Boehm-Demers-Weiser support:     ' $ok_gc
1016 echo
1017 echo 'Note: if you are not using Linux, make sure you are using GNU make'
1018 echo '(gmake) to compile Citadel.'
1019 echo