citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_PREREQ(2.52)
   4 AC_INIT([Citadel], [7.24], [http://www.citadel.org/])
   5 AC_REVISION([$Revision: 5108 $])
   6 AC_CONFIG_SRCDIR([citserver.c])
   7 AC_PREFIX_DEFAULT(/usr/local/citadel)
   8 if test "$prefix" = NONE; then
   9         AC_DEFINE_UNQUOTED(CTDLDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  10         ssl_dir="$ac_default_prefix/keys"
  11 else
  12         AC_DEFINE_UNQUOTED(CTDLDIR, "$prefix", [define this to the Citadel home directory])
  13         ssl_dir="$prefix/keys"
  14 fi
  15
  16
  17 dnl Make sure we see all GNU and Solaris extensions.
  18 AC_GNU_SOURCE
  19
  20
  21 dnl Checks for the Datadir
  22 AC_ARG_WITH(datadir,
  23                     [  --with-datadir          directory to store the databases under],
  24                         [ if test "x$withval" != "xno" ; then
  25                                               AC_DEFINE(HAVE_DATA_DIR,[],[use alternate database location?])
  26                                               AC_DEFINE_UNQUOTED(DATA_DIR, "$withval",[define, if the user suplied a data-directory to use.])
  27                                               MAKE_DATA_DIR=$withval
  28                                               AC_SUBST(MAKE_DATA_DIR)
  29                           fi
  30                         ]
  31 )
  32
  33 dnl Checks for the Datadir
  34 AC_ARG_WITH(staticdatadir,
  35                     [  --with-staticdatadir    directory to store citadels system messages under],
  36                         [ if test "x$withval" != "xno" ; then
  37                                                   AC_DEFINE(HAVE_STATICDATA_DIR, [], [should we activate an alternate static text location?])
  38                                                   AC_DEFINE_UNQUOTED(STATICDATA_DIR, "$withval", [where do we put our static text data?])
  39                                                   MAKE_STATICDATA_DIR=$withval
  40                                                   AC_SUBST(MAKE_STATICDATA_DIR)
  41                           fi
  42                         ]
  43 )
  44
  45
  46 dnl Checks for the SSLdir
  47 dnl this is a bit different than the rest,
  48 dnl because of the citadel used to have a keys/ subdir.
  49 AC_ARG_WITH(ssldir,
  50                     [  --with-ssldir          directory to store the ssl certificates under],
  51                         [ if test "x$withval" != "xno" ; then
  52
  53                                                   ssl_dir="$withval"
  54                           fi
  55                         AC_SUBST(MAKE_SSL_DIR)
  56                         ]
  57 )
  58 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
  59
  60
  61 dnl Checks for the spooldir
  62 AC_ARG_WITH(spooldir,
  63                         [  --with-spooldir         directory to keep queues under],
  64                         [ if test "x$withval" != "xno" ; then
  65                                                 AC_DEFINE(HAVE_SPOOL_DIR, [], [enable alternate spool dir?])
  66                                                 AC_DEFINE_UNQUOTED(SPOOL_DIR,"$withval", [where do we place our spool dirs?])
  67                                                 MAKE_SPOOL_DIR=$withval
  68                                                 AC_SUBST(MAKE_SPOOL_DIR)
  69                            fi
  70                         ]
  71 )
  72
  73
  74 dnl Checks for the Configdir
  75 AC_ARG_WITH(sysconfdir,
  76                         [  --with-sysconfdir       directory to store the configs under],
  77                         [ if test "x$withval" != "xno" ; then
  78                                             AC_DEFINE(HAVE_ETC_DIR, [], [should we search our system config in an alternate place?])
  79                                                 AC_DEFINE_UNQUOTED(ETC_DIR, "$withval", [where to search our config files])
  80                                                 MAKE_ETC_DIR=$withval
  81                                                 AC_SUBST(MAKE_ETC_DIR)
  82                           fi
  83                         ]
  84 )
  85
  86 dnl Checks for where to put our utilities
  87 AC_ARG_WITH(utility-bindir,
  88                         [  --with-utility-bindir       directory where to find helper binaries],
  89                         [ if test "x$withval" != "xno" ; then
  90                                             AC_DEFINE(HAVE_UTILBIN_DIR,[],[should we put our helper binaries to another location?])
  91                                                 AC_DEFINE_UNQUOTED(UTILBIN_DIR, "$withval", [were to put our helper programs])
  92                                                 MAKE_UTILBIN_DIR=$withval
  93                                                 AC_SUBST(MAKE_UTILBIN_DIR)
  94                           fi
  95                         ]
  96 )
  97
  98
  99 dnl Checks for the run-dir for the sockets
 100 AC_ARG_WITH(rundir,
 101                         [  --with-rundir           directory to place runtime files (UDS) to?],
 102                         [ if test "x$withval" != "xno" ; then
 103                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 104                                                 AC_DEFINE_UNQUOTED(RUN_DIR, "$withval", [define, where the config should go in unix style])
 105                                                 MAKE_RUN_DIR=$withval
 106                                                 AC_SUBST(MAKE_RUN_DIR)
 107                           fi
 108                         ]
 109 )
 110
 111
 112 dnl Checks for the Pseudo Random Generator sockets TODO: this keeps being default.
 113 AC_DEFINE_UNQUOTED(EGD_POOL, "/var/run/egd-pool", [place to keep our pseudo random generator file])
 114 AC_ARG_WITH(egdpool,
 115                         [  --with-egdpool          the socket from Pseudo Random Generator, defaults to /var/run/egd-pool],
 116                         [ if test "x$withval" != "xno" ; then
 117                                                 AC_DEFINE_UNQUOTED(EGD_POOL, "$withval", [the socket from Pseudo Random Generator])
 118                           fi
 119                         ]
 120 )
 121
 122
 123 AC_ARG_WITH(docdir,
 124                         [  --with-docdir           where to install the documentation. default: /usr/local/citadel/],
 125                         [ if test "x$withval" != "xno" ; then
 126                                         MAKE_DOC_DIR=$withval
 127                                         AC_SUBST(MAKE_DOC_DIR)
 128                           fi
 129                         ]
 130 )
 131
 132
 133
 134 AC_ARG_ENABLE(threaded-client, [  --disable-threaded-client
 135                           disable multithreaded client])
 136
 137 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
 138
 139 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
 140 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
 141 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Sleepycat DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
 142 AC_ARG_WITH(ssl,
 143         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
 144         [
 145                 if test "x$withval" != "xno" ; then
 146                         tryssldir=$withval
 147                 fi
 148         ]
 149 )
 150 AC_ARG_WITH(ncurses, [  --without-ncurses       don't use ncurses])
 151
 152 AC_ARG_WITH(with_zlib, [  --with-zlib             use zlib compression if present])
 153 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
 154 AC_ARG_WITH(with_libical, [  --with-libical          use libical calendaring library])
 155 AC_ARG_WITH(with_libsieve, [  --with-libsieve         use libsieve mail sorting library])
 156 AC_ARG_WITH(with_libdspam, [  --with-libdspam         use libdspam mail spam scanning library])
 157 AC_ARG_WITH(with_expat, [  --with-expat            use Expat XML parser])
 158
 159 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
 160         db_dir="$with_db"
 161         with_db=yes
 162 else
 163         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
 164           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
 165           && db_dir=/usr/local
 166
 167         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
 168         test -d /usr/local/BerkeleyDB.4.2 && db_dir=/usr/local/BerkeleyDB.4.2
 169         test -d /usr/local/BerkeleyDB.4.3 && db_dir=/usr/local/BerkeleyDB.4.3
 170         test -d /usr/local/BerkeleyDB.4.4 && db_dir=/usr/local/BerkeleyDB.4.4
 171         test -d /usr/local/BerkeleyDB.4.5 && db_dir=/usr/local/BerkeleyDB.4.5
 172 fi
 173
 174 dnl By default, we only build the client (citadel and whobbs) unless we can
 175 dnl figure out how to build with POSIX threads.
 176 TARGETS=client
 177
 178 AC_CANONICAL_HOST
 179 PTHREAD_DEFS=-D_REENTRANT
 180 AC_MSG_CHECKING([how to compile with POSIX threads])
 181 case "$host" in
 182         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
 183         dnl for dlopen(), and has a wrapper script to link with shared libs.
 184         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
 185         *-*-bsdi[123]*)
 186                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
 187                 AC_DEFINE(HAVE_NONREENTRANT_NETDB,[], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 188                 AC_MSG_RESULT([Old BSDI])
 189         ;;
 190         *-*-bsdi*)
 191                 AC_DEFINE(HAVE_NONREENTRANT_NETDB, [], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 192                 AC_MSG_RESULT([BSD/OS])
 193         ;;
 194         dnl Curses support on Mac OS X is kind of screwed at the moment.
 195         dnl TCP buffering isn't ideal under OS X. This define should also be
 196         dnl checked in other cases of OS X-Linux differences.
 197         *-*-darwin*)
 198                 AC_DEFINE(DISABLE_CURSES,[],[define this to disable use of curses])
 199                 AC_DEFINE(HAVE_DARWIN, [], [define if using OS X/Darwin])
 200                 AC_MSG_RESULT([Mac OS X])
 201         ;;
 202         dnl Digital Unix has an odd way to build for pthreads, and we can't
 203         dnl build pthreads programs with gcc due to header problems.
 204         alpha*-dec-osf*)
 205                 test -z "$CC" && CC=cc
 206                 LIBS="-lpthread -lexc $LIBS"
 207                 check_pthread=no
 208                 AC_MSG_RESULT([Tru64 or Digital UNIX])
 209         ;;
 210         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
 211         *-*-freebsd*)
 212                 if test "$with_kthread" = yes; then
 213                         LIBS="-kthread $LIBS"
 214                 else
 215                         LIBS="-pthread $LIBS"
 216                 fi
 217                 check_pthread=no
 218                 PTHREAD_DEFS=-D_THREAD_SAFE
 219                 AC_MSG_RESULT([FreeBSD])
 220         ;;
 221         *-*-openbsd*)
 222                 LIBS="-pthread $LIBS"
 223                 check_pthread=no
 224                 PTHREAD_DEFS=-pthread
 225                 AC_MSG_RESULT([OpenBSD])
 226         ;;
 227         *-*-linux*)
 228                 PTHREAD_DEFS="-D_REENTRANT -pthread"
 229                 AC_MSG_RESULT([Linux])
 230         ;;
 231         *-*-solaris*)
 232                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
 233                 AC_MSG_RESULT([Solaris])
 234         ;;
 235         *-*-cygwin*)
 236                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
 237                 AC_MSG_RESULT([Cygwin])
 238         ;;
 239         *)
 240                 AC_MSG_RESULT([default])
 241         ;;
 242 esac
 243 dnl DEFS="$DEFS $PTHREAD_DEFS"
 244
 245
 246 dnl Checks for programs.
 247 AC_PROG_CC
 248
 249
 250
 251 dnl Set up system-dependent compiler flags.
 252 if test "$GCC" = yes; then
 253         if test "$CC" = icc; then
 254                 CFLAGS="$CFLAGS -w1"
 255         else
 256                 case "$host" in
 257                         *-*-solaris*|alpha*-dec-osf*)
 258                                 CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts $PTHREAD_DEFS"
 259                         ;;
 260                         *)
 261                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes $PTHREAD_DEFS"
 262                         ;;
 263                 esac
 264         fi
 265 fi
 266
 267 if test "x$enable_pie" = xyes; then
 268         save_CFLAGS="$CFLAGS"
 269         save_LDFLAGS="$LDFLAGS"
 270         CFLAGS="$CFLAGS -fpie"
 271         LDFLAGS="$LDFLAGS -pie -fpie"
 272         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 273         [AC_TRY_LINK([], [],
 274         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 275         if test $ac_cv_pie_fpie = no; then
 276                 CFLAGS="$save_CFLAGS"
 277                 LDFLAGS="$save_LDFLAGS"
 278         fi
 279 fi
 280
 281 AC_MSG_CHECKING([how to create dependancy checks])
 282                  if test -n "`$CC -V 2>&1 |grep Sun`"; then
 283                         DEPEND_FLAG=-xM;
 284                  else
 285                         DEPEND_FLAG=-M
 286                  fi
 287 AC_SUBST(DEPEND_FLAG)
 288
 289
 290 AC_PROG_INSTALL
 291 AC_PROG_YACC
 292 missing_dir=`cd $ac_aux_dir && pwd`
 293 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 294 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 295
 296 dnl Checks for system services.
 297
 298 dnl Check the size of various builtin types; see typesize.h (error)
 299 AC_CHECK_SIZEOF(char, 0)
 300 AC_CHECK_SIZEOF(short, 0)
 301 AC_CHECK_SIZEOF(int, 0)
 302 AC_CHECK_SIZEOF(long, 0)
 303 AC_CHECK_SIZEOF(size_t, 0)
 304 dnl AC_CHECK_SIZEOF(long long, 0)
 305
 306 dnl Checks for libraries.
 307
 308 dnl We want to test for the following in libc before checking for their
 309 dnl respective libraries, because some systems (like Irix) have both, and the
 310 dnl non-libc versions may be broken.
 311 AC_CHECK_FUNCS(crypt gethostbyname connect flock getpwnam_r getpwuid_r)
 312
 313
 314 dnl disable backtrace if we don't want it.
 315 AC_ARG_WITH(backtrace,
 316                     [  --with-backtrace          enable backtrace dumps in the syslog],
 317                         [ if test "x$withval" != "xno" ; then
 318                              CFLAGS="$CFLAGS  -rdynamic "
 319                              LDFLAGS="$LDFLAGS  -rdynamic "
 320                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -rdynamic "
 321                              AC_CHECK_FUNCS(backtrace)
 322                           fi
 323                         ]
 324 )
 325
 326 dnl disable backtrace if we don't want it.
 327 AC_ARG_WITH(gprof,
 328                     [  --with-gprof          enable profiling],
 329                         [ if test "x$withval" != "xno" ; then
 330                              CFLAGS="$CFLAGS  -pg "
 331                              LDFLAGS="$LDFLAGS  -pg "
 332                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -pg "
 333                           fi
 334                         ]
 335 )
 336
 337 dnl disable thread table reporting
 338 AC_ARG_WITH(threadlog,
 339                 [ --with-threadlog      enable logging of thread table],
 340                         [ if test "x$withval" != "xno" ; then
 341                                 AC_DEFINE(WITH_THREADLOG, [], [Define if you want logging of the thread tables.])
 342                           fi
 343                         ]
 344 )
 345
 346
 347 if test "$ac_cv_func_gethostbyname" = no; then
 348         AC_CHECK_LIB(nsl, gethostbyname)
 349 fi
 350
 351 if test "$ac_cv_func_connect" = no; then
 352         AC_CHECK_LIB(socket, connect)
 353 fi
 354
 355 dnl Check for Solaris realtime support
 356 AC_CHECK_LIB(rt, sched_yield)
 357
 358 dnl Determine the system's authentication capabilities.
 359 dnl We currently support PAM, standard getpwnam(), and getspnam()
 360 dnl (Linux shadow passwords)
 361
 362         if test "$with_pam" = yes; then
 363                 save_LIBS=$LIBS
 364                 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 365                         LIBS="-lpam $LIBS"])
 366                 AC_CHECK_FUNCS(pam_start)
 367                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 368         fi
 369         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 370                 save_LIBS=$LIBS
 371                 AC_SEARCH_LIBS(getspnam, shadow, [
 372                         if test "$ac_cv_search_getspnam" = -lshadow; then
 373                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 374                         fi])
 375                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 376                 if test "$ac_cv_func_crypt" = no; then
 377                         AC_CHECK_LIB(crypt, crypt, [
 378                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 379                                 test "$enable_chkpwd" = no && \
 380                                         LIBS="-lcrypt $LIBS"])
 381                 fi
 382         fi
 383
 384 test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 385 AC_CHECK_LIB(resolv, res_query,
 386         RESOLV="$RESOLV -lresolv",
 387         [
 388                 AC_MSG_ERROR(libresolv was not found.  Citadel requires the resolver library.)
 389         ]
 390 )
 391
 392 if test "x$with_ncurses" != "xno"; then
 393         AC_SEARCH_LIBS(tgetent, [ncurses curses termcap])
 394         AC_SEARCH_LIBS(scrollok, [ncurses curses])
 395         AC_SEARCH_LIBS(initscr, [ncurses curses])
 396 else
 397         AC_SEARCH_LIBS(tgetent, [curses termcap])
 398         AC_SEARCH_LIBS(initscr, [curses])
 399 fi
 400 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 401
 402 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 403 dnl which the -pthread flag takes care of this.)
 404 if test "$check_pthread" != no; then
 405         AC_CHECK_LIB(pthread, pthread_create)
 406         AC_CHECK_LIB(pthreads, pthread_create)
 407 fi
 408
 409 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 410
 411
 412 dnl Check for libcitadel
 413 AC_CHECK_HEADER(libcitadel.h,
 414         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 415                 [
 416                         AC_MSG_RESULT(OK)
 417                         LIBS="-lcitadel $LIBS"
 418                 ],
 419                 [
 420                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 421                 ]
 422         ,
 423         )],
 424         [
 425                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 426         ]
 427 )
 428
 429
 430
 431 # The big search for OpenSSL
 432 if test "$with_ssl" != "no"; then
 433         saved_LIBS="$LIBS"
 434         saved_LDFLAGS="$LDFLAGS"
 435         saved_CFLAGS="$CFLAGS"
 436         if test "x$prefix" != "xNONE"; then
 437                 tryssldir="$tryssldir $prefix"
 438         fi
 439         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 440                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 441                         CFLAGS="$saved_CFLAGS"
 442                         LDFLAGS="$saved_LDFLAGS"
 443                         LIBS="$saved_LIBS -lssl -lcrypto"
 444
 445                         # Skip directories if they don't exist
 446                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 447                                 continue;
 448                         fi
 449                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 450                                 # Try to use $ssldir/lib if it exists, otherwise
 451                                 # $ssldir
 452                                 if test -d "$ssldir/lib" ; then
 453                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 454                                         if test ! -z "$need_dash_r" ; then
 455                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 456                                         fi
 457                                 else
 458                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 459                                         if test ! -z "$need_dash_r" ; then
 460                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 461                                         fi
 462                                 fi
 463                                 # Try to use $ssldir/include if it exists, otherwise
 464                                 # $ssldir
 465                                 if test -d "$ssldir/include" ; then
 466                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 467                                 else
 468                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 469                                 fi
 470                         fi
 471
 472                         # Basic test to check for compatible version and correct linking
 473                         # *does not* test for RSA - that comes later.
 474                         AC_TRY_RUN(
 475                                 [
 476         #include <string.h>
 477         #include <openssl/rand.h>
 478         int main(void)
 479         {
 480                 char a[2048];
 481                 memset(a, 0, sizeof(a));
 482                 RAND_add(a, sizeof(a), sizeof(a));
 483                 return(RAND_status() <= 0);
 484         }
 485                                 ],
 486                                 [
 487                                         found_crypto=1
 488                                         break;
 489                                 ], []
 490                         )
 491
 492                         if test ! -z "$found_crypto" ; then
 493                                 break;
 494                         fi
 495                 done
 496
 497                 if test -z "$ssldir" ; then
 498                         ssldir="(system)"
 499                 fi
 500
 501                 if test ! -z "$found_crypto" ; then
 502                         ac_cv_openssldir=$ssldir
 503                 else
 504                         ac_cv_openssldir="no"
 505                 fi
 506         ])
 507         LIBS="$saved_LIBS"
 508         LDFLAGS="$saved_LDFLAGS"
 509         CFLAGS="$saved_CFLAGS"
 510
 511         if test "x$ac_cv_openssldir" != "xno" ; then
 512                 AC_DEFINE(HAVE_OPENSSL, [], [Define if you have OpenSSL.])
 513                 LIBS="-lssl -lcrypto $LIBS"
 514                 dnl Need to recover ssldir - test above runs in subshell
 515                 ssldir=$ac_cv_openssldir
 516                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 517                         # Try to use $ssldir/lib if it exists, otherwise
 518                         # $ssldir
 519                         if test -d "$ssldir/lib" ; then
 520                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 521                                 if test ! -z "$need_dash_r" ; then
 522                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 523                                 fi
 524                         else
 525                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 526                                 if test ! -z "$need_dash_r" ; then
 527                                         LDFLAGS="-R$ssldir $LDFLAGS"
 528                                 fi
 529                         fi
 530                         # Try to use $ssldir/include if it exists, otherwise
 531                         # $ssldir
 532                         if test -d "$ssldir/include" ; then
 533                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 534                         else
 535                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 536                         fi
 537                 fi
 538         fi
 539 fi
 540
 541 if test "x$with_db" != xno; then
 542         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 543
 544         dblib=""
 545
 546         if test -d "$db_dir/include/db4"; then
 547                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 548                 dblib="db4"
 549         elif test "$db_dir"; then
 550                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 551         elif test -d /usr/include/db4; then
 552                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 553                 dblib="db4"
 554         fi
 555
 556
 557         AC_CHECK_DB([db db-4.1 db-4 db4],
 558                     [
 559                      DATABASE=database_sleepycat.c
 560                     ],
 561                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 562                                   library.  Use --with-db=PATH to specify
 563                                   the path]]))
 564
 565 fi
 566
 567 dnl Checks for the zlib compression library.
 568 if test "x$with_zlib" != xno ; then
 569         AC_CHECK_HEADERS(zlib.h,
 570                 [AC_CHECK_LIB(z, zlibVersion,
 571                         [ok_zlib=yes],,
 572         )])
 573 fi
 574
 575 if test "x$ok_zlib" = xyes ; then
 576         SERVER_LIBS="-lz $SERVER_LIBS"
 577         AC_DEFINE(HAVE_ZLIB, [], [define this if you have zlib compression available])
 578 fi
 579
 580
 581
 582
 583 dnl Checks for the OpenLDAP client library.
 584 if test "x$with_ldap" != xno ; then
 585         AC_CHECK_HEADERS(ldap.h,
 586                 [AC_CHECK_LIB(ldap, ldap_init,
 587                         [ok_ldap=yes],,
 588         )])
 589 fi
 590
 591 if test "x$ok_ldap" = xyes ; then
 592         SERVER_LIBS="-lldap $SERVER_LIBS"
 593         AC_DEFINE(HAVE_LDAP, [], [define this if you have OpenLDAP client available])
 594 fi
 595
 596
 597
 598
 599
 600 dnl Checks for the libsieve mailbox sorting library.
 601 if test "x$with_libsieve" != xno ; then
 602         AC_CHECK_HEADERS(sieve2.h,
 603                 [AC_CHECK_LIB(sieve, sieve2_license,
 604                         [ok_libsieve=yes],,
 605         )])
 606 fi
 607
 608 if test "x$ok_libsieve" = xyes ; then
 609         SERVER_LIBS="-lsieve $SERVER_LIBS"
 610         AC_DEFINE(HAVE_LIBSIEVE, [], [define this if you have the libsieve mailbox filtering library available])
 611 fi
 612
 613
 614 dnl Checks for the libdspam mail spam scanning library.
 615 if test "x$with_libdspam" != xno ; then
 616         AC_CHECK_HEADERS(dspam/libdspam.h,
 617                 [AC_CHECK_LIB(dspam, dspam_init,
 618                         [ok_libdspam=yes],,
 619         )])
 620 fi
 621
 622 if test "x$ok_libdspam" = xyes ; then
 623         SERVER_LIBS="-ldspam $SERVER_LIBS"
 624         AC_DEFINE(HAVE_LIBDSPAM, [], [define this if you have the libdspam mail spam scanning library available])
 625 fi
 626
 627
 628
 629
 630 dnl Checks for the Expat XML parser.
 631 if test "x$with_expat" != xno ; then
 632         AC_CHECK_HEADERS(expat.h,
 633                 [AC_CHECK_LIB(expat, XML_ParserCreateNS,
 634                         [ok_expat=yes],,
 635         )])
 636 fi
 637
 638 if test "x$ok_expat" = xyes ; then
 639         SERVER_LIBS="-lexpat $SERVER_LIBS"
 640         AC_DEFINE(HAVE_EXPAT, [], [define this if you have the Expat XML parser available])
 641 fi
 642
 643
 644
 645
 646 dnl Checks for the libical calendaring library.
 647 if test "x$with_libical" != xno ; then
 648         AC_CHECK_HEADERS(ical.h,
 649                 [AC_CHECK_LIB(ical, icalcomponent_new,
 650                         [ok_libical=yes],,
 651         )])
 652 fi
 653
 654 if test "x$ok_libical" = xyes ; then
 655
 656         AC_TRY_RUN(
 657                 [
 658 #include <ical.h>
 659 main() {
 660         int major, minor, v;
 661         sscanf(ICAL_VERSION, "%d.%d", &major, &minor);
 662         v = 100*major + minor;
 663         printf("libical version: %i\n", v);
 664         if (v >= 24) {
 665                 printf("This version is ok.\n");
 666                 return(0);
 667         }
 668         printf("libical 0.24 or newer required.\n");
 669         printf("Citadel will be built without calendar support.\n");
 670         return(1);
 671 }
 672                 ],
 673                 [
 674                         SERVER_LIBS="-lical $SERVER_LIBS"
 675                         AC_DEFINE(HAVE_LIBICAL, [], [define this if you have the libical calendaring library available])
 676                 ]
 677         )
 678 fi
 679
 680
 681
 682
 683 dnl Checks for header files.
 684 AC_HEADER_DIRENT
 685 AC_HEADER_STDC
 686 AC_HEADER_SYS_WAIT
 687
 688 dnl
 689 dnl TODO: for the DB header checks, we should check whether the headers
 690 dnl define db_env_create, somehow
 691 dnl
 692 AC_CHECK_HEADERS(curses.h dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/stat.h sys/time.h sys/prctl.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h)
 693
 694 dnl
 695 dnl need to check if this is actually compilable, sometimes there are
 696 dnl conflicts with the system's headers (eg solaris xpg4 style headers)
 697 dnl
 698 if test "x$with_ncurses" != xno; then
 699         AC_CHECK_HEADERS(ncurses.h,,,[ ])
 700 fi
 701
 702 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H, [], [define this if you have the resolv.h header file.]),,
 703 [#ifdef HAVE_SYS_TYPES_H
 704 #include <sys/types.h>
 705 #endif
 706 #ifdef HAVE_NETINET_IN_H
 707 #include <netinet/in.h>
 708 #endif
 709 #ifdef HAVE_ARPA_NAMESER_H
 710 #include <arpa/nameser.h>
 711 #endif])
 712
 713
 714 dnl Checks for typedefs, structures, and compiler characteristics.
 715 AC_C_CONST
 716 AC_TYPE_PID_T
 717 AC_TYPE_SIZE_T
 718 AC_HEADER_TIME
 719
 720 dnl defined in acinclude.m4:
 721 CIT_STRUCT_TM
 722
 723 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 724 [AC_TRY_COMPILE([#include <sys/types.h>
 725 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 726 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 727 if test $ac_cv_struct_ut_type = yes; then
 728         AC_DEFINE(HAVE_UT_TYPE, [], [define this if struct utmp has an ut_type member])
 729 fi
 730
 731 AC_CACHE_CHECK(
 732         [for call semantics from getpwuid_r],
 733         ac_cv_call_getpwuid_r,
 734         [AC_TRY_COMPILE([#include <sys/types.h>
 735 #include <pwd.h>],
 736                          [
 737                                 struct passwd pw, *pwp;
 738                                 char pwbuf[64];
 739                                 uid_t uid;
 740
 741                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 742                         ],
 743                         ac_cv_call_getpwuid_r=yes,
 744                         ac_cv_call_getpwuid_r=no)
 745         ])
 746
 747 if test $ac_cv_call_getpwuid_r = no; then
 748         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 749         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 750         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 751         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 752 else
 753         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 754         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 755         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 756 fi
 757
 758 dnl AC_CHECK_FUNCS(res_query)
 759 AC_CACHE_CHECK([for the resolver calls],
 760                ac_cv_resquery_ok,
 761 [AC_TRY_COMPILE([#include <netinet/in.h>
 762 #include <arpa/nameser.h>
 763 #include <resolv.h>],
 764                 [
 765                         char *domain="www.google.com";
 766                         u_char *answer;
 767                         int len;
 768                         len = res_query( domain, C_IN, T_A, answer, PACKETSZ );
 769                 ],
 770                 ac_cv_resquery_ok=yes,
 771                 ac_cv_resquery_ok=no)
 772 ])
 773 echo "resquery: $ac_cv_resquery_ok"
 774
 775 dnl if test "$ac_cv_resquery_ok" = "no" ; then
 776 dnl    AC_DEFINE(RES_QUERY_GONE, "#error resquery not here. can't continue.")
 777 dnl fi
 778
 779
 780
 781 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 782 [AC_TRY_COMPILE([#include <sys/types.h>
 783 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 784 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 785 if test $ac_cv_struct_ut_host = yes; then
 786         AC_DEFINE(HAVE_UT_HOST, [], [define this if struct utmp has an ut_host member])
 787 fi
 788
 789 dnl Checks for library functions.
 790 AC_FUNC_GETPGRP
 791 AC_PROG_GCC_TRADITIONAL
 792 AC_TYPE_SIGNAL
 793 AC_FUNC_VPRINTF
 794 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 795
 796 dnl Now check for pthreads
 797
 798 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 799 dnl we need to include pthread.h
 800
 801 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 802 [AC_TRY_LINK([#include <pthread.h>],
 803 [       pthread_t thread;
 804
 805         /* The GNU C library defines this for functions which it implements
 806            to always fail with ENOSYS.  Some functions are actually named
 807            something starting with __ and the normal name is an alias.  */
 808 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 809         choke me
 810 #else
 811         pthread_cancel(thread);
 812 #endif],
 813 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 814 if test "$ac_cv_func_pthread_cancel" = yes; then
 815         AC_DEFINE(HAVE_PTHREAD_CANCEL, [], [define this if you have the pthread_cancel() function])
 816 fi
 817
 818 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
 819 [AC_TRY_LINK([#include <pthread.h>],
 820 [       /* The GNU C library defines this for functions which it implements
 821            to always fail with ENOSYS.  Some functions are actually named
 822            something starting with __ and the normal name is an alias.  */
 823 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 824         choke me
 825 #else
 826         pthread_create(NULL, NULL, NULL, NULL);
 827 #endif],
 828 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
 829 if test "$ac_cv_func_pthread_create" = yes; then
 830         test "$DATABASE" && TARGETS="client server utils"
 831         if test "x$enable_threaded_client" != xno; then
 832                 AC_DEFINE(THREADED_CLIENT, [], [define this if you want to enable the multithreaded client])
 833         fi
 834 fi
 835
 836 AC_REPLACE_FUNCS(snprintf getutline)
 837
 838 AC_CACHE_CHECK([the weather], ac_cv_weather, [
 839         sleep 1
 840         echo $ECHO_N "opening your window... $ECHO_C" >&6
 841         sleep 2
 842         month=`date | cut -f 2 -d ' '`
 843         case $month in
 844         Dec | Jan | Feb)
 845                 ac_cv_weather="it's cold!"
 846                 ;;
 847         Mar | Apr)
 848                 ac_cv_weather="it's wet!"
 849                 ;;
 850         Jul | Aug)
 851                 ac_cv_weather="it's hot!"
 852                 ;;
 853         Oct | Nov)
 854                 ac_cv_weather="it's cool"
 855                 ;;
 856         May | Jun | Sep | *)
 857                 ac_cv_weather="it's fine"
 858                 ;;
 859         esac
 860         ])
 861
 862
 863
 864
 865 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
 866         number=`date | cut -c 19`
 867         case $number in
 868         7)
 869                 ac_cv_under_the_bed="lunatics and monsters found"
 870                 ;;
 871         *)
 872                 ac_cv_under_the_bed="dust bunnies found"
 873                 ;;
 874         esac
 875         ])
 876
 877 dnl Done! Now write the Makefile and sysdep.h
 878 AC_SUBST(AUTH)
 879 AC_SUBST(RESOLV)
 880 AC_SUBST(chkpwd_LIBS)
 881 AC_SUBST(TARGETS)
 882 AC_SUBST(DATABASE)
 883 AC_SUBST(SERVER_LDFLAGS)
 884 AC_SUBST(SERVER_LIBS)
 885 AC_SUBST(SETUP_LIBS)
 886 AC_CONFIG_HEADER(sysdep.h)
 887 AC_CONFIG_FILES([Makefile])
 888 AC_OUTPUT(database_cleanup.sh)
 889
 890 if test -z "$DATABASE"; then
 891         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
 892 fi
 893
 894 echo ------------------------------------------------------------------------
 895 echo 'zlib compression:                ' $ok_zlib
 896 echo 'Calendar support:                ' $ok_libical
 897 echo 'LDAP support:                    ' $ok_ldap
 898 echo 'Sieve mailbox filtering support: ' $ok_libsieve
 899 echo 'DSpam Scanning support:          ' $ok_libdspam
 900 echo 'Expat XML parser present:        ' $ok_expat
 901 echo
 902 echo 'Note: if you are not using Linux, make sure you are using GNU make'
 903 echo '(gmake) to compile Citadel.'
 904 echo