webcit/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_INIT([WebCit], [7.86], [http://www.citadel.org/])
   4
   5
   6 AC_SUBST(PROG_SUBDIRS)
   7 AC_DEFINE(PROG_SUBDIRS, [], [Program dirs])
   8 AC_CANONICAL_HOST
   9 AC_PROG_INSTALL
  10 missing_dir=`cd $ac_aux_dir && pwd`
  11 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  12 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
  13
  14 dnl Make sure we see all GNU and Solaris extensions.
  15 AC_GNU_SOURCE
  16
  17 AC_CHECK_PROG(SED, sed, sed, no)
  18 AC_PREFIX_DEFAULT(/usr/local/webcit)
  19 if test "$prefix" = NONE; then
  20         AC_DEFINE_UNQUOTED(WEBCITDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  21         ssl_dir="$ac_default_prefix/keys"
  22 else
  23         AC_DEFINE_UNQUOTED(WEBCITDIR, "$prefix", [define this to the Citadel home directory])
  24         ssl_dir="$prefix/keys"
  25 fi
  26
  27 AC_ARG_WITH(ssl,
  28         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
  29         [
  30                 if test "x$withval" != "xno" ; then
  31                         tryssldir=$withval
  32                 fi
  33         ]
  34 )
  35 dnl Set some system-specific variables which are OK to set before compiler
  36 dnl checks:
  37 PTHREAD_DEFS=-D_REENTRANT
  38 case "$host" in
  39         dnl Tru64 Unix requires we use -pthread instead of linking the threads
  40         dnl libraries directly, and we can't build threaded programs with gcc
  41         dnl due to header file problems.
  42         alpha*-dec-osf*)
  43                 test -z "$CC" && CC=cc
  44                 LIBS=-pthread
  45         ;;
  46         dnl FreeBSD is similar:
  47         *-*-freebsd*)
  48                 LIBS=-pthread
  49                 PTHREAD_DEFS=-D_THREAD_SAFE
  50         ;;
  51         *-*-solaris*)
  52                 PTHREAD_DEFS='-D_REENTRANT -D_PTHREADS'
  53         ;;
  54         *-*-darwin*)
  55                 LIBS=-lintl
  56 esac
  57 AC_SUBST(PTHREAD_DEFS)
  58
  59 dnl Checks for programs.
  60 AC_PROG_CC
  61
  62 dnl Configure compiler flags for GCC
  63 if test "$GCC" = yes; then
  64         case "$host" in
  65                 *-*-solaris*)
  66 dnl                     CFLAGS="$CFLAGS -Wall -Wno-char-subscripts --pedantic"
  67                         CFLAGS="$CFLAGS -Wall -Wno-char-subscripts"
  68                 ;;
  69                 *)
  70 dnl                     CFLAGS="$CFLAGS -Wall --pedantic"
  71                         CFLAGS="$CFLAGS -Wall"
  72                 ;;
  73         esac
  74 fi
  75
  76 # missing_dir=`cd $ac_aux_dir && pwd`
  77 # AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  78
  79 dnl Checks for libraries.
  80 if test "$LIBS" != -pthread; then
  81         AC_CHECK_LIB(pthread, pthread_create)
  82         AC_CHECK_LIB(pthreads, pthread_create)
  83 fi
  84 AC_SEARCH_LIBS(gethostbyname, nsl)
  85 AC_SEARCH_LIBS(connect, socket)
  86
  87 dnl Checks for header files.
  88 AC_HEADER_STDC
  89 dnl AC_HEADER_SYS_WAIT
  90
  91 AC_CACHE_CHECK(
  92         [for call semantics from getpwuid_r],
  93         ac_cv_call_getpwuid_r,
  94         [AC_TRY_COMPILE([#include <sys/types.h>
  95 #include <pwd.h>],
  96                          [
  97                                 struct passwd pw, *pwp;
  98                                 char pwbuf[64];
  99                                 uid_t uid;
 100
 101                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 102                         ],
 103                         ac_cv_call_getpwuid_r=yes,
 104                         ac_cv_call_getpwuid_r=no)
 105         ])
 106
 107 if test $ac_cv_call_getpwuid_r = no; then
 108         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 109         AC_DEFINE(SOLARIS_LOCALTIME_R,[], [do we need to use soralis call syntax?])
 110         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 111         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 112         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 113 else
 114         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 115         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 116         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 117 fi
 118
 119
 120
 121 dnl Checks for typedefs, structures, and compiler characteristics.
 122 AC_C_CONST
 123 AC_TYPE_OFF_T
 124 AC_TYPE_SIZE_T
 125 dnl Check the size of various builtin types; see typesize.h (error)
 126 AC_CHECK_SIZEOF(char, 0)
 127 AC_CHECK_SIZEOF(short, 0)
 128 AC_CHECK_SIZEOF(int, 0)
 129 AC_CHECK_SIZEOF(long, 0)
 130 AC_CHECK_SIZEOF(long unsigned int, 0)
 131 AC_CHECK_SIZEOF(size_t, 0)
 132 dnl AC_HEADER_TIME
 133
 134 dnl Checks for library functions.
 135 AC_TYPE_SIGNAL
 136 dnl AC_FUNC_VPRINTF
 137 AC_REPLACE_FUNCS(snprintf)
 138 AC_CHECK_HEADER(CUnit/CUnit.h, [AC_DEFINE(ENABLE_TESTS, [], [whether we should compile the test-suite])])
 139
 140 AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h iconv.h xlocale.h)
 141
 142 dnl Checks for the zlib compression library.
 143 if test "x$with_zlib" != xno ; then
 144        AC_CHECK_HEADERS(zlib.h,
 145                [AC_CHECK_LIB(z, zlibVersion,
 146                        [ok_zlib=yes],,
 147        )])
 148 fi
 149
 150 if test "x$ok_zlib" = xyes ; then
 151 dnl  libcitadel will bring libz, so we don't need it here.     LDFLAGS="-lz $LDFLAGS"
 152        AC_DEFINE(HAVE_ZLIB, [], [define this if you have zlib compression available])
 153 fi
 154
 155
 156 dnl Here is the check for a libc integrated iconv
 157 AC_ARG_ENABLE(iconv,
 158         [  --disable-iconv         do not use iconv charset conversion],
 159         ok_iconv=no, ok_iconv=yes)
 160
 161 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 162 AC_TRY_RUN([
 163         #include <iconv.h>
 164         main() {
 165                 iconv_t ic = (iconv_t)(-1) ;
 166                 ic = iconv_open("UTF-8", "us-ascii");
 167                 iconv_close(ic);
 168                 exit(0);
 169         }
 170  ],
 171                 [
 172                   ok_iconv=yes
 173                   AC_MSG_RESULT([yes])
 174                 ],
 175                 [
 176                   ok_iconv=no
 177                   AC_MSG_RESULT([no])
 178                 ]
 179 )
 180
 181 dnl Check for iconv in external libiconv
 182 if test "$ok_iconv" = no; then
 183         AC_MSG_CHECKING(Checking for an external libiconv)
 184         OLD_LDFLAGS="$LDFLAGS"
 185         LDFLAGS="$LDFLAGS -liconv"
 186         AC_TRY_RUN([
 187                         #include <iconv.h>
 188                         main() {
 189                                 iconv_t ic = (iconv_t)(-1) ;
 190                                 ic = iconv_open("UTF-8", "us-ascii");
 191                                 iconv_close(ic);
 192                         }
 193                 ],
 194                         [
 195                           ok_iconv=yes
 196                           AC_MSG_RESULT([yes])
 197                         ],
 198                         [
 199                           ok_iconv=no
 200                           LDFLAGS="$OLD_LDFLAGS"
 201                           AC_MSG_RESULT([no])
 202                         ]
 203                 )
 204 fi
 205 if test "$ok_iconv" != "no"; then
 206         AC_MSG_RESULT(webcit will be built with character set conversion.)
 207         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 208 else
 209         AC_MSG_RESULT(webcit will be built without character set conversion.)
 210 fi
 211
 212
 213 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 214
 215
 216 dnl Checks for the libical iCalendar library.
 217 AC_CHECK_HEADER(libical/ical.h,
 218         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 219                 [
 220                         LIBS="-lical $LIBS"
 221                 ],
 222                 [
 223                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 224                 ]
 225         ,
 226         )],
 227         [
 228                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 229         ]
 230 )
 231
 232
 233 dnl Check for libcitadel
 234 AC_CHECK_HEADER(libcitadel.h,
 235         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 236                 [
 237                         LIBS="-lcitadel $LIBS"
 238                         SETUP_LIBS="-lcitadel $SETUP_LIBS"
 239                 ],
 240                 [
 241                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 242                 ]
 243         ,
 244         )],
 245         [
 246                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 247         ]
 248 )
 249
 250
 251
 252 found_ssl=no
 253 # The big search for OpenSSL
 254 if test "$with_ssl" != "no"; then
 255         saved_LIBS="$LIBS"
 256         saved_LDFLAGS="$LDFLAGS"
 257         saved_CFLAGS="$CFLAGS"
 258         if test "x$prefix" != "xNONE"; then
 259                 tryssldir="$tryssldir $prefix"
 260         fi
 261         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 262                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 263                         CFLAGS="$saved_CFLAGS"
 264                         LDFLAGS="$saved_LDFLAGS"
 265                         LIBS="$saved_LIBS -lssl -lcrypto"
 266
 267                         # Skip directories if they don't exist
 268                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 269                                 continue;
 270                         fi
 271                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 272                                 # Try to use $ssldir/lib if it exists, otherwise
 273                                 # $ssldir
 274                                 if test -d "$ssldir/lib" ; then
 275                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 276                                         if test ! -z "$need_dash_r" ; then
 277                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 278                                         fi
 279                                 else
 280                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 281                                         if test ! -z "$need_dash_r" ; then
 282                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 283                                         fi
 284                                 fi
 285                                 # Try to use $ssldir/include if it exists, otherwise
 286                                 # $ssldir
 287                                 if test -d "$ssldir/include" ; then
 288                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 289                                 else
 290                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 291                                 fi
 292                         fi
 293
 294                         # Basic test to check for compatible version and correct linking
 295                         # *does not* test for RSA - that comes later.
 296                         AC_TRY_RUN(
 297                                 [
 298         #include <string.h>
 299         #include <openssl/rand.h>
 300         int main(void)
 301         {
 302                 char a[2048];
 303                 memset(a, 0, sizeof(a));
 304                 RAND_add(a, sizeof(a), sizeof(a));
 305                 return(RAND_status() <= 0);
 306         }
 307                                 ],
 308                                 [
 309                                         found_crypto=1
 310                                         break;
 311                                 ], []
 312                         )
 313
 314                         if test ! -z "$found_crypto" ; then
 315                                 break;
 316                         fi
 317                 done
 318
 319                 if test -z "$ssldir" ; then
 320                         ssldir="(system)"
 321                 fi
 322
 323                 if test ! -z "$found_crypto" ; then
 324                         ac_cv_openssldir=$ssldir
 325                 else
 326                         ac_cv_openssldir="no"
 327                 fi
 328         ])
 329         LIBS="$saved_LIBS"
 330         LDFLAGS="$saved_LDFLAGS"
 331         CFLAGS="$saved_CFLAGS"
 332
 333         if test "x$ac_cv_openssldir" != "xno" ; then
 334                 AC_DEFINE(HAVE_OPENSSL,[],[whethe we have openssl])
 335                 found_ssl=yes
 336                 LIBS="-lssl -lcrypto $LIBS"
 337                 dnl Need to recover ssldir - test above runs in subshell
 338                 ssldir=$ac_cv_openssldir
 339                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 340                         # Try to use $ssldir/lib if it exists, otherwise
 341                         # $ssldir
 342                         if test -d "$ssldir/lib" ; then
 343                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 344                                 if test ! -z "$need_dash_r" ; then
 345                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 346                                 fi
 347                         else
 348                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 349                                 if test ! -z "$need_dash_r" ; then
 350                                         LDFLAGS="-R$ssldir $LDFLAGS"
 351                                 fi
 352                         fi
 353                         # Try to use $ssldir/include if it exists, otherwise
 354                         # $ssldir
 355                         if test -d "$ssldir/include" ; then
 356                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 357                         else
 358                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 359                         fi
 360                 fi
 361         fi
 362 fi
 363 dnl Checks for the SSLdir
 364 dnl this is a bit different than the rest,
 365 dnl because of the citadel used to have a keys/ subdir.
 366 AC_ARG_WITH(ssldir,
 367                     [  --with-ssldir          directory to store the ssl certificates under],
 368                         [ if test "x$withval" != "xno" ; then
 369
 370                                                   ssl_dir="$withval"
 371                                                   if test "$found_ssl" = "no"; then
 372                                                      echo "Your setup was incomplete; ssldir doesn't make sense without openssl"
 373                                                      exit
 374                                                   fi
 375                           fi
 376                         AC_SUBST(MAKE_SSL_DIR)
 377                         ]
 378 )
 379 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
 380
 381
 382
 383
 384 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 385
 386 if test "$ok_nls" != "no"; then
 387         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 388         ok_nls=$ok_xgettext
 389 fi
 390
 391 if test "$ok_nls" != "no"; then
 392         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 393         ok_nls=$ok_msgmerge
 394 fi
 395
 396 if test "$ok_nls" != "no"; then
 397         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 398         ok_nls=$ok_msgfmt
 399 fi
 400
 401 if test "$ok_nls" != "no"; then
 402         AC_MSG_RESULT(WebCit will be built with national language support.)
 403         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 404         PROG_SUBDIRS="$PROG_SUBDIRS po"
 405 else
 406         AC_MSG_RESULT(WebCit will be built without national language support.)
 407 fi
 408
 409 AC_SUBST(SETUP_LIBS)
 410
 411 dnl disable backtrace if we don't want it.
 412 AC_ARG_WITH(gprof,
 413                     [  --with-gprof          enable profiling],
 414                         [ if test "x$withval" != "xno" ; then
 415                              CFLAGS="$CFLAGS  -pg "
 416                              LDFLAGS="$LDFLAGS  -pg "
 417                           fi
 418                         ]
 419 )
 420
 421 dnl disable backtrace if we don't want it.
 422 AC_ARG_WITH(backtrace,
 423                     [  --with-backtrace          enable backtrace dumps in the syslog],
 424                         [ if test "x$withval" != "xno" ; then
 425                              CFLAGS="$CFLAGS  -rdynamic "
 426                              LDFLAGS="$LDFLAGS  -rdynamic "
 427                              AC_CHECK_FUNCS(backtrace)
 428                           fi
 429                         ]
 430 )
 431
 432 if test "$prefix" = NONE; then
 433         datadir=$ac_default_prefix
 434         localedir=$ac_default_prefix
 435         wwwdir=$ac_default_prefix
 436         rundir=$ac_default_prefix
 437         editordir=$ac_default_prefix/tiny_mce
 438 else
 439         localedir=$prefix
 440         wwwdir=$prefix
 441         datadir=$prefix
 442         rundir=$prefix
 443         editordir=$prefix/tiny_mce
 444 fi
 445
 446 dnl where to put the locale files
 447 AC_ARG_WITH(localedir,
 448                     [  --with-localedir          directory to put the locale files to],
 449                         [ if test "x$withval" != "xno" ; then
 450                             localedir=$withval
 451                           fi
 452                         ]
 453 )
 454 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 455 LOCALEDIR=$localedir
 456 AC_SUBST(LOCALEDIR)
 457
 458 dnl Checks where to put our templates
 459 AC_ARG_WITH(wwwdir,
 460                     [  --with-wwwdir             directory to put our templates],
 461                         [ if test "x$withval" != "xno" ; then
 462                                 wwwdir=$withval
 463                           fi
 464                         ]
 465 )
 466 AC_DEFINE_UNQUOTED(WWWDIR, "$wwwdir", [where to find our templates and pics])
 467 WWWDIR=$wwwdir
 468 AC_SUBST(WWWDIR)
 469
 470
 471 dnl Checks for the run-dir for the sockets
 472 AC_ARG_WITH(rundir,
 473                         [  --with-rundir           directory to place runtime files (UDS) to?],
 474                         [ if test "x$withval" != "xno" ; then
 475                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 476
 477                                                 rundir=$withval
 478                                                 AC_SUBST(MAKE_RUN_DIR)
 479                           fi
 480                         ]
 481 )
 482 AC_DEFINE_UNQUOTED(RUNDIR, "$rundir", [define, where the config should go in unix style])
 483
 484 dnl Checks for the Datadir
 485 AC_ARG_WITH(datadir,
 486                     [  --with-datadir          directory to store the databases under],
 487                         [ if test "x$withval" != "xno" ; then
 488                                               datadir=$withval
 489                           fi
 490                         ]
 491 )
 492 AC_DEFINE_UNQUOTED(DATADIR, "$datadir",[define, if the user suplied a data-directory to use.])
 493
 494 dnl Checks where to put our editor
 495 AC_ARG_WITH(editordir,
 496                     [  --with-editordir             directory to put our editor],
 497                         [ if test "x$withval" != "xno" ; then
 498                                 editordir=$withval
 499                           fi
 500                         ]
 501 )
 502 AC_DEFINE_UNQUOTED(EDITORDIR, "$editordir", [where to find our mail editor])
 503
 504 abs_srcdir="`cd $srcdir && pwd`"
 505 abs_builddir="`pwd`"
 506 if test "$abs_srcdir" != "$abs_builddir"; then
 507    CFLAGS="$CFLAGS -I $abs_builddir"
 508 fi
 509 AC_CONFIG_HEADER(sysdep.h)
 510 AC_OUTPUT(Makefile po/Makefile tests/Makefile)
 511
 512 if test "$abs_srcdir" != "$abs_builddir"; then
 513    ln -s $abs_srcdir/static $abs_builddir
 514    ln -s $abs_srcdir/tiny_mce $abs_builddir
 515    ln -s $abs_srcdir/*.h $abs_builddir
 516    make mkdir-init
 517
 518 else
 519 dnl just run it on devel systems and if non vdir build.
 520    if test -d .svn; then
 521       ./mk_module_init.sh
 522    fi
 523 fi
 524
 525 if test -n "$srcdir"; then
 526    export srcdir=.
 527 fi
 528
 529
 530 echo ------------------------------------------------------------------------
 531 echo 'Character set conversion support:' $ok_iconv
 532 echo 'National language support:       ' $ok_nls
 533 echo 'Compression support:             ' $ok_zlib
 534 echo