webcit/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_INIT([WebCit], [7.37], [http://www.citadel.org/])
   4
   5
   6 AC_SUBST(PROG_SUBDIRS)
   7 AC_DEFINE(PROG_SUBDIRS, [], [Program dirs])
   8 AC_CANONICAL_HOST
   9 AC_PROG_INSTALL
  10 missing_dir=`cd $ac_aux_dir && pwd`
  11 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  12 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
  13
  14 dnl Make sure we see all GNU and Solaris extensions.
  15 AC_GNU_SOURCE
  16
  17 AC_CHECK_PROG(SED, sed, sed, no)
  18 AC_PREFIX_DEFAULT(/usr/local/webcit)
  19 if test "$prefix" = NONE; then
  20         AC_DEFINE_UNQUOTED(WEBCITDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  21         ssl_dir="$ac_default_prefix/keys"
  22 else
  23         AC_DEFINE_UNQUOTED(WEBCITDIR, "$prefix", [define this to the Citadel home directory])
  24         ssl_dir="$prefix/keys"
  25 fi
  26
  27 AC_ARG_WITH(ssl,
  28         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
  29         [
  30                 if test "x$withval" != "xno" ; then
  31                         tryssldir=$withval
  32                 fi
  33         ]
  34 )
  35 dnl Set some system-specific variables which are OK to set before compiler
  36 dnl checks:
  37 PTHREAD_DEFS=-D_REENTRANT
  38 case "$host" in
  39         dnl Tru64 Unix requires we use -pthread instead of linking the threads
  40         dnl libraries directly, and we can't build threaded programs with gcc
  41         dnl due to header file problems.
  42         alpha*-dec-osf*)
  43                 test -z "$CC" && CC=cc
  44                 LIBS=-pthread
  45         ;;
  46         dnl FreeBSD is similar:
  47         *-*-freebsd*)
  48                 LIBS=-pthread
  49                 PTHREAD_DEFS=-D_THREAD_SAFE
  50         ;;
  51         *-*-solaris*)
  52                 PTHREAD_DEFS='-D_REENTRANT -D_PTHREADS'
  53         ;;
  54         *-*-darwin*)
  55                 LIBS=-lintl
  56 esac
  57 AC_SUBST(PTHREAD_DEFS)
  58
  59 dnl Checks for programs.
  60 AC_PROG_CC
  61
  62 dnl Configure compiler flags for GCC
  63 if test "$GCC" = yes; then
  64         case "$host" in
  65                 *-*-solaris*)
  66                         CFLAGS="$CFLAGS -Wall -Wno-char-subscripts"
  67                 ;;
  68                 *)
  69                         CFLAGS="$CFLAGS -Wall"
  70                 ;;
  71         esac
  72 fi
  73
  74 # missing_dir=`cd $ac_aux_dir && pwd`
  75 # AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  76
  77 dnl Checks for libraries.
  78 if test "$LIBS" != -pthread; then
  79         AC_CHECK_LIB(pthread, pthread_create)
  80         AC_CHECK_LIB(pthreads, pthread_create)
  81 fi
  82 AC_SEARCH_LIBS(gethostbyname, nsl)
  83 AC_SEARCH_LIBS(connect, socket)
  84
  85 dnl Checks for header files.
  86 AC_HEADER_STDC
  87 dnl AC_HEADER_SYS_WAIT
  88
  89
  90
  91
  92 dnl Checks for typedefs, structures, and compiler characteristics.
  93 AC_C_CONST
  94 AC_TYPE_OFF_T
  95 AC_TYPE_SIZE_T
  96 dnl AC_HEADER_TIME
  97
  98 dnl Checks for library functions.
  99 AC_TYPE_SIGNAL
 100 dnl AC_FUNC_VPRINTF
 101 AC_REPLACE_FUNCS(snprintf)
 102 AC_CHECK_HEADERS(fcntl.h limits.h sys/time.h unistd.h iconv.h xlocale.h)
 103
 104
 105 dnl Here is the check for a libc integrated iconv
 106 AC_ARG_ENABLE(iconv,
 107         [  --disable-iconv         do not use iconv charset conversion],
 108         ok_iconv=no, ok_iconv=yes)
 109
 110 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 111 AC_TRY_RUN([
 112         #include <iconv.h>
 113         main() {
 114                 iconv_t ic = (iconv_t)(-1) ;
 115                 ic = iconv_open("UTF-8", "us-ascii");
 116                 iconv_close(ic);
 117                 exit(0);
 118         }
 119  ],
 120                 [
 121                   ok_iconv=yes
 122                   AC_MSG_RESULT([yes])
 123                 ],
 124                 [
 125                   ok_iconv=no
 126                   AC_MSG_RESULT([no])
 127                 ]
 128 )
 129
 130 dnl Check for iconv in external libiconv
 131 if test "$ok_iconv" = no; then
 132         AC_MSG_CHECKING(Checking for an external libiconv)
 133         OLD_LDFLAGS="$LDFLAGS"
 134         LDFLAGS="$LDFLAGS -liconv"
 135         AC_TRY_RUN([
 136                         #include <iconv.h>
 137                         main() {
 138                                 iconv_t ic = (iconv_t)(-1) ;
 139                                 ic = iconv_open("UTF-8", "us-ascii");
 140                                 iconv_close(ic);
 141                         }
 142                 ],
 143                         [
 144                           ok_iconv=yes
 145                           AC_MSG_RESULT([yes])
 146                         ],
 147                         [
 148                           ok_iconv=no
 149                           LDFLAGS="$OLD_LDFLAGS"
 150                           AC_MSG_RESULT([no])
 151                         ]
 152                 )
 153 fi
 154 if test "$ok_iconv" != "no"; then
 155         AC_MSG_RESULT(WebCit will be built with character set conversion.)
 156         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 157 else
 158         AC_MSG_RESULT(WebCit will be built without character set conversion.)
 159 fi
 160
 161 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 162
 163
 164 dnl Checks for the libical iCalendar library.
 165 AC_CHECK_HEADER(libical/ical.h,
 166         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 167                 [
 168                         LIBS="-lical $LIBS"
 169                 ],
 170                 [
 171                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 172                 ]
 173         ,
 174         )],
 175         [
 176                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 177         ]
 178 )
 179
 180
 181 dnl Check for libcitadel
 182 AC_CHECK_HEADER(libcitadel.h,
 183         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 184                 [
 185                         LIBS="-lcitadel $LIBS"
 186                 ],
 187                 [
 188                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 189                 ]
 190         ,
 191         )],
 192         [
 193                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 194         ]
 195 )
 196
 197
 198
 199
 200 # The big search for OpenSSL
 201 if test "$with_ssl" != "no"; then
 202         saved_LIBS="$LIBS"
 203         saved_LDFLAGS="$LDFLAGS"
 204         saved_CFLAGS="$CFLAGS"
 205         if test "x$prefix" != "xNONE"; then
 206                 tryssldir="$tryssldir $prefix"
 207         fi
 208         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 209                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 210                         CFLAGS="$saved_CFLAGS"
 211                         LDFLAGS="$saved_LDFLAGS"
 212                         LIBS="$saved_LIBS -lssl -lcrypto"
 213
 214                         # Skip directories if they don't exist
 215                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 216                                 continue;
 217                         fi
 218                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 219                                 # Try to use $ssldir/lib if it exists, otherwise
 220                                 # $ssldir
 221                                 if test -d "$ssldir/lib" ; then
 222                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 223                                         if test ! -z "$need_dash_r" ; then
 224                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 225                                         fi
 226                                 else
 227                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 228                                         if test ! -z "$need_dash_r" ; then
 229                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 230                                         fi
 231                                 fi
 232                                 # Try to use $ssldir/include if it exists, otherwise
 233                                 # $ssldir
 234                                 if test -d "$ssldir/include" ; then
 235                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 236                                 else
 237                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 238                                 fi
 239                         fi
 240
 241                         # Basic test to check for compatible version and correct linking
 242                         # *does not* test for RSA - that comes later.
 243                         AC_TRY_RUN(
 244                                 [
 245         #include <string.h>
 246         #include <openssl/rand.h>
 247         int main(void)
 248         {
 249                 char a[2048];
 250                 memset(a, 0, sizeof(a));
 251                 RAND_add(a, sizeof(a), sizeof(a));
 252                 return(RAND_status() <= 0);
 253         }
 254                                 ],
 255                                 [
 256                                         found_crypto=1
 257                                         break;
 258                                 ], []
 259                         )
 260
 261                         if test ! -z "$found_crypto" ; then
 262                                 break;
 263                         fi
 264                 done
 265
 266                 if test -z "$ssldir" ; then
 267                         ssldir="(system)"
 268                 fi
 269
 270                 if test ! -z "$found_crypto" ; then
 271                         ac_cv_openssldir=$ssldir
 272                 else
 273                         ac_cv_openssldir="no"
 274                 fi
 275         ])
 276         LIBS="$saved_LIBS"
 277         LDFLAGS="$saved_LDFLAGS"
 278         CFLAGS="$saved_CFLAGS"
 279
 280         if test "x$ac_cv_openssldir" != "xno" ; then
 281                 AC_DEFINE(HAVE_OPENSSL,[],[whethe we have openssl])
 282                 LIBS="-lssl -lcrypto $LIBS"
 283                 dnl Need to recover ssldir - test above runs in subshell
 284                 ssldir=$ac_cv_openssldir
 285                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 286                         # Try to use $ssldir/lib if it exists, otherwise
 287                         # $ssldir
 288                         if test -d "$ssldir/lib" ; then
 289                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 290                                 if test ! -z "$need_dash_r" ; then
 291                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 292                                 fi
 293                         else
 294                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 295                                 if test ! -z "$need_dash_r" ; then
 296                                         LDFLAGS="-R$ssldir $LDFLAGS"
 297                                 fi
 298                         fi
 299                         # Try to use $ssldir/include if it exists, otherwise
 300                         # $ssldir
 301                         if test -d "$ssldir/include" ; then
 302                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 303                         else
 304                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 305                         fi
 306                 fi
 307         fi
 308 fi
 309 dnl Checks for the SSLdir
 310 dnl this is a bit different than the rest,
 311 dnl because of the citadel used to have a keys/ subdir.
 312 AC_ARG_WITH(ssldir,
 313                     [  --with-ssldir          directory to store the ssl certificates under],
 314                         [ if test "x$withval" != "xno" ; then
 315
 316                                                   ssl_dir="$withval"
 317                           fi
 318                         AC_SUBST(MAKE_SSL_DIR)
 319                         ]
 320 )
 321 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
 322
 323
 324
 325
 326 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 327
 328 if test "$ok_nls" != "no"; then
 329         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 330         ok_nls=$ok_xgettext
 331 fi
 332
 333 if test "$ok_nls" != "no"; then
 334         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 335         ok_nls=$ok_msgmerge
 336 fi
 337
 338 if test "$ok_nls" != "no"; then
 339         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 340         ok_nls=$ok_msgfmt
 341 fi
 342
 343 if test "$ok_nls" != "no"; then
 344         AC_MSG_RESULT(WebCit will be built with national language support.)
 345         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 346         PROG_SUBDIRS="$PROG_SUBDIRS po"
 347 else
 348         AC_MSG_RESULT(WebCit will be built without national language support.)
 349 fi
 350
 351 AC_SUBST(SETUP_LIBS)
 352
 353 dnl disable backtrace if we don't want it.
 354 AC_ARG_WITH(gprof,
 355                     [  --with-gprof          enable profiling],
 356                         [ if test "x$withval" != "xno" ; then
 357                              CFLAGS="$CFLAGS  -pg "
 358                              LDFLAGS="$LDFLAGS  -pg "
 359                           fi
 360                         ]
 361 )
 362
 363 dnl disable backtrace if we don't want it.
 364 AC_ARG_WITH(backtrace,
 365                     [  --with-backtrace          enable backtrace dumps in the syslog],
 366                         [ if test "x$withval" != "xno" ; then
 367                              CFLAGS="$CFLAGS  -rdynamic "
 368                              LDFLAGS="$LDFLAGS  -rdynamic "
 369                              AC_CHECK_FUNCS(backtrace)
 370                           fi
 371                         ]
 372 )
 373
 374 if test "$prefix" = NONE; then
 375         datadir=$ac_default_prefix
 376         localedir=$ac_default_prefix
 377         wwwdir=$ac_default_prefix
 378         rundir=$ac_default_prefix
 379         editordir=$ac_default_prefix/tiny_mce
 380 else
 381         localedir=$prefix
 382         wwwdir=$prefix
 383         datadir=$prefix
 384         rundir=$prefix
 385         editordir=$prefix/tiny_mce
 386 fi
 387
 388 dnl where to put the locale files
 389 AC_ARG_WITH(localedir,
 390                     [  --with-localedir          directory to put the locale files to],
 391                         [ if test "x$withval" != "xno" ; then
 392                             localedir=$withval
 393                           fi
 394                         ]
 395 )
 396 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 397 LOCALEDIR=$localedir
 398 AC_SUBST(LOCALEDIR)
 399
 400 dnl Checks where to put our templates
 401 AC_ARG_WITH(wwwdir,
 402                     [  --with-wwwdir             directory to put our templates],
 403                         [ if test "x$withval" != "xno" ; then
 404                                 wwwdir=$withval
 405                           fi
 406                         ]
 407 )
 408 AC_DEFINE_UNQUOTED(WWWDIR, "$wwwdir", [where to find our templates and pics])
 409 WWWDIR=$wwwdir
 410 AC_SUBST(WWWDIR)
 411
 412
 413 dnl Checks for the run-dir for the sockets
 414 AC_ARG_WITH(rundir,
 415                         [  --with-rundir           directory to place runtime files (UDS) to?],
 416                         [ if test "x$withval" != "xno" ; then
 417                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 418
 419                                                 rundir=$withval
 420                                                 AC_SUBST(MAKE_RUN_DIR)
 421                           fi
 422                         ]
 423 )
 424 AC_DEFINE_UNQUOTED(RUNDIR, "$rundir", [define, where the config should go in unix style])
 425
 426 dnl Checks for the Datadir
 427 AC_ARG_WITH(datadir,
 428                     [  --with-datadir          directory to store the databases under],
 429                         [ if test "x$withval" != "xno" ; then
 430                                               datadir=$withval
 431                           fi
 432                         ]
 433 )
 434 AC_DEFINE_UNQUOTED(DATADIR, "$datadir",[define, if the user suplied a data-directory to use.])
 435
 436 dnl Checks where to put our editor
 437 AC_ARG_WITH(editordir,
 438                     [  --with-editordir             directory to put our editor],
 439                         [ if test "x$withval" != "xno" ; then
 440                                 editordir=$withval
 441                           fi
 442                         ]
 443 )
 444 AC_DEFINE_UNQUOTED(EDITORDIR, "$editordir", [where to find our mail editor])
 445
 446 ./mk_module_init.sh
 447 AC_CONFIG_HEADER(sysdep.h)
 448 AC_OUTPUT(Makefile po/Makefile )
 449
 450 echo ------------------------------------------------------------------------
 451 echo 'Character set conversion support:' $ok_iconv
 452 echo 'National language support:       ' $ok_nls
 453 echo