webcit/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_INIT([WebCit],[m4_esyscmd_s(grep CLIENT_VERSION webcit.h | sed 's/[^0-9]*//g')],[http://uncensored.citadel.org])
   4
   5 AC_SUBST(PROG_SUBDIRS)
   6 AC_DEFINE(PROG_SUBDIRS, [], [Program dirs])
   7 AC_CANONICAL_HOST
   8 AC_PROG_INSTALL
   9 missing_dir=`cd $ac_aux_dir && pwd`
  10 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  11 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
  12
  13 dnl Make sure we see all GNU and Solaris extensions.
  14 AC_USE_SYSTEM_EXTENSIONS
  15
  16 AC_CHECK_PROG(SED, sed, sed, no)
  17 AC_PREFIX_DEFAULT(/usr/local/webcit)
  18 if test "$prefix" = NONE; then
  19         AC_DEFINE_UNQUOTED(WEBCITDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  20         ssl_dir="$ac_default_prefix/keys"
  21 else
  22         AC_DEFINE_UNQUOTED(WEBCITDIR, "$prefix", [define this to the Citadel home directory])
  23         ssl_dir="$prefix/keys"
  24 fi
  25
  26 AC_ARG_WITH(ssl,
  27         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
  28         [
  29                 if test "x$withval" != "xno" ; then
  30                         tryssldir=$withval
  31                 fi
  32         ]
  33 )
  34 dnl Set some system-specific variables which are OK to set before compiler
  35 dnl checks:
  36 PTHREAD_DEFS=-D_REENTRANT
  37 case "$host" in
  38         dnl Tru64 Unix requires we use -pthread instead of linking the threads
  39         dnl libraries directly, and we can't build threaded programs with gcc
  40         dnl due to header file problems.
  41         alpha*-dec-osf*)
  42                 test -z "$CC" && CC=cc
  43                 LIBS=-pthread
  44         ;;
  45         dnl FreeBSD is similar:
  46         *-*-freebsd*)
  47                 LIBS=-pthread
  48                 PTHREAD_DEFS=-D_THREAD_SAFE
  49         ;;
  50         *-*-solaris*)
  51                 PTHREAD_DEFS='-D_REENTRANT -D_PTHREADS'
  52         ;;
  53         *-*-darwin*)
  54                 LIBS=-lintl
  55 esac
  56 AC_SUBST(PTHREAD_DEFS)
  57
  58 dnl Checks for programs.
  59 AC_PROG_CC
  60
  61 dnl Configure compiler flags for GCC
  62 if test "$GCC" = yes; then
  63         case "$host" in
  64                 *-*-solaris*)
  65 dnl                     CFLAGS="$CFLAGS -Wall -Wno-char-subscripts --pedantic"
  66                         CFLAGS="$CFLAGS -Wall -Wno-char-subscripts"
  67                 ;;
  68                 *)
  69 dnl                     CFLAGS="$CFLAGS -Wall --pedantic"
  70                         CFLAGS="$CFLAGS -Wall"
  71                 ;;
  72         esac
  73 fi
  74
  75 # missing_dir=`cd $ac_aux_dir && pwd`
  76 # AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
  77
  78 dnl Checks for libraries.
  79 if test "$LIBS" != -pthread; then
  80         AC_CHECK_LIB(pthread, pthread_create)
  81         AC_CHECK_LIB(pthreads, pthread_create)
  82 fi
  83 AC_SEARCH_LIBS(gethostbyname, nsl)
  84 AC_SEARCH_LIBS(connect, socket)
  85
  86 dnl Checks for header files.
  87 m4_warn([obsolete],
  88 [The preprocessor macro `STDC_HEADERS' is obsolete.
  89   Except in unusual embedded environments, you can safely include all
  90   ISO C90 headers unconditionally.])dnl
  91 # Autoupdate added the next two lines to ensure that your configure
  92 # script's behavior did not change.  They are probably safe to remove.
  93 AC_CHECK_INCLUDES_DEFAULT
  94 AC_PROG_EGREP
  95
  96 dnl AC_HEADER_SYS_WAIT
  97
  98 AC_CHECK_FUNCS(crypt gethostbyname connect flock getpwnam_r getpwuid_r getloadavg)
  99 AC_CACHE_CHECK(
 100         [for call semantics from getpwuid_r],
 101         ac_cv_call_getpwuid_r,
 102         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 103 #include <pwd.h>]], [[
 104                                 struct passwd pw, *pwp;
 105                                 char pwbuf[64];
 106                                 uid_t uid;
 107
 108                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 109                         ]])],[ac_cv_call_getpwuid_r=yes],[ac_cv_call_getpwuid_r=no])
 110         ])
 111
 112 if test $ac_cv_call_getpwuid_r = no; then
 113         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 114         AC_DEFINE(SOLARIS_LOCALTIME_R,[], [do we need to use soralis call syntax?])
 115         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 116         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 117         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 118 else
 119         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 120         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 121         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 122 fi
 123
 124
 125
 126 dnl Checks for typedefs, structures, and compiler characteristics.
 127 AC_C_CONST
 128 AC_TYPE_OFF_T
 129 AC_TYPE_SIZE_T
 130 dnl Check the size of various builtin types; see typesize.h (error)
 131 AC_CHECK_SIZEOF(char, 0)
 132 AC_CHECK_SIZEOF(short, 0)
 133 AC_CHECK_SIZEOF(int, 0)
 134 AC_CHECK_SIZEOF(long, 0)
 135 AC_CHECK_SIZEOF(long unsigned int, 0)
 136 AC_CHECK_SIZEOF(size_t, 0)
 137
 138 dnl Checks for library functions.
 139 m4_warn([obsolete],
 140 [your code may safely assume C89 semantics that RETSIGTYPE is void.
 141 Remove this warning and the `AC_CACHE_CHECK' when you adjust the code.])dnl
 142 AC_CACHE_CHECK([return type of signal handlers],[ac_cv_type_signal],[AC_COMPILE_IFELSE(
 143 [AC_LANG_PROGRAM([#include <sys/types.h>
 144 #include <signal.h>
 145 ],
 146                  [return *(signal (0, 0)) (0) == 1;])],
 147                    [ac_cv_type_signal=int],
 148                    [ac_cv_type_signal=void])])
 149 AC_DEFINE_UNQUOTED([RETSIGTYPE],[$ac_cv_type_signal],[Define as the return type of signal handlers
 150                     (`int' or `void').])
 151
 152 dnl AC_FUNC_VPRINTF
 153 AC_REPLACE_FUNCS(snprintf)
 154 AC_CHECK_HEADER(CUnit/CUnit.h, [AC_DEFINE(ENABLE_TESTS, [], [whether we should compile the test-suite])])
 155
 156 AC_CHECK_HEADERS(fcntl.h limits.h unistd.h iconv.h xlocale.h)
 157
 158 dnl Checks for the zlib compression library.
 159 saved_CFLAGS="$CFLAGS"
 160 CFLAGS="$CFLAGS $SERVER_LIBS"
 161 AC_CHECK_HEADER(zlib.h,
 162         [AC_CHECK_LIB(z, zlibVersion,
 163                 [
 164                         LIBS="-lz $LIBS $SERVER_LIBS"
 165                 ],
 166                 [
 167                         AC_MSG_ERROR(zlib was not found or is not usable.  Please install zlib.)
 168                 ]
 169         ,
 170         )],
 171         [
 172                 AC_MSG_ERROR(zlib.h was not found or is not usable.  Please install zlib.)
 173         ]
 174 )
 175 CFLAGS="$saved_CFLAGS"
 176
 177 dnl Here is the check for a libc integrated iconv
 178 AC_ARG_ENABLE(iconv,
 179         [  --disable-iconv         do not use iconv charset conversion],
 180         ok_iconv=no, ok_iconv=yes)
 181
 182 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 183 AC_RUN_IFELSE([AC_LANG_SOURCE([[
 184         #include <iconv.h>
 185         main() {
 186                 iconv_t ic = (iconv_t)(-1) ;
 187                 ic = iconv_open("UTF-8", "us-ascii");
 188                 iconv_close(ic);
 189                 exit(0);
 190         }
 191  ]])],[
 192                   ok_iconv=yes
 193                   AC_MSG_RESULT([yes])
 194                 ],[
 195                   ok_iconv=no
 196                   AC_MSG_RESULT([no])
 197
 198 ],[])
 199
 200 dnl Check for iconv in external libiconv
 201 if test "$ok_iconv" = no; then
 202         AC_MSG_CHECKING(Checking for an external libiconv)
 203         OLD_LDFLAGS="$LDFLAGS"
 204         LDFLAGS="$LDFLAGS -liconv"
 205         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 206                         #include <iconv.h>
 207                         main() {
 208                                 iconv_t ic = (iconv_t)(-1) ;
 209                                 ic = iconv_open("UTF-8", "us-ascii");
 210                                 iconv_close(ic);
 211                         }
 212                 ]])],[
 213                           ok_iconv=yes
 214                           AC_MSG_RESULT([yes])
 215                         ],[
 216                           ok_iconv=no
 217                           LDFLAGS="$OLD_LDFLAGS"
 218                           AC_MSG_RESULT([no])
 219
 220                 ],[])
 221 fi
 222 if test "$ok_iconv" != "no"; then
 223         AC_MSG_RESULT(webcit will be built with character set conversion.)
 224         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 225 else
 226         AC_MSG_RESULT(webcit will be built without character set conversion.)
 227 fi
 228
 229 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 230
 231
 232 dnl Checks for the libical iCalendar library.
 233 AC_CHECK_HEADER(libical/ical.h,
 234         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 235                 [
 236                         LIBS="-lical $LIBS"
 237                 ],
 238                 [
 239                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 240                 ]
 241         ,
 242         )],
 243         [
 244                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 245         ]
 246 )
 247
 248 dnl Checks for the discount markdown library.
 249 AC_CHECK_LIB(markdown,
 250          markdown,
 251          [
 252          LIBS="$LIBS -lmarkdown"
 253          AC_DEFINE(HAVE_MARKDOWN,[],[whether we have markdown message rendering])
 254 ])
 255
 256 dnl Check for libcitadel
 257 AC_CHECK_HEADER(libcitadel.h,
 258         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 259                 [
 260                         LIBS="-lcitadel $LIBS"
 261                         SETUP_LIBS="-lcitadel $SETUP_LIBS"
 262                 ],
 263                 [
 264                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 265                 ]
 266         ,
 267         )],
 268         [
 269                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 270         ]
 271 )
 272
 273 AC_MSG_CHECKING([whether your system likes memcpy + HKEY])
 274 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 275 #define _GNU_SOURCE
 276 #include <ctype.h>
 277 #include <errno.h>
 278 #include <string.h>
 279 #include <unistd.h>
 280 #include <string.h>
 281 #include <stdio.h>
 282 #include <sys/select.h>
 283 #include <fcntl.h>
 284 #include <sys/types.h>
 285
 286 #include "lib/libcitadel.h"
 287 ]], [[
 288         char foo[22];
 289         memcpy(foo, HKEY("foo"));
 290
 291 ]])],[
 292
 293                   AC_MSG_RESULT([yes])
 294                 ],[
 295                   AC_DEFINE(UNDEF_MEMCPY, [], [whether we need to undefine memcpy])
 296                   AC_MSG_RESULT([no])
 297
 298 ])
 299
 300 dnl Checks for the Expat XML parser.
 301 AC_CHECK_HEADER(expat.h,
 302         [AC_CHECK_LIB(expat, XML_ParserCreateNS,
 303                 [
 304                         LIBS="-lexpat $LIBS"
 305                 ],
 306                 [
 307                         AC_MSG_ERROR(The Expat XML parser was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 308                 ]
 309         ,
 310         )],
 311         [
 312                 AC_MSG_ERROR(expat.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 313         ]
 314 )
 315
 316
 317
 318 found_ssl=no
 319 # The big search for OpenSSL
 320 if test "$with_ssl" != "no"; then
 321         saved_LIBS="$LIBS"
 322         saved_LDFLAGS="$LDFLAGS"
 323         saved_CFLAGS="$CFLAGS"
 324         if test "x$prefix" != "xNONE"; then
 325                 tryssldir="$tryssldir $prefix"
 326         fi
 327         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 328                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 329                         CFLAGS="$saved_CFLAGS"
 330                         LDFLAGS="$saved_LDFLAGS"
 331                         LIBS="$saved_LIBS -lssl -lcrypto"
 332
 333                         # Skip directories if they don't exist
 334                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 335                                 continue;
 336                         fi
 337                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 338                                 # Try to use $ssldir/lib if it exists, otherwise
 339                                 # $ssldir
 340                                 if test -d "$ssldir/lib" ; then
 341                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 342                                         if test ! -z "$need_dash_r" ; then
 343                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 344                                         fi
 345                                 else
 346                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 347                                         if test ! -z "$need_dash_r" ; then
 348                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 349                                         fi
 350                                 fi
 351                                 # Try to use $ssldir/include if it exists, otherwise
 352                                 # $ssldir
 353                                 if test -d "$ssldir/include" ; then
 354                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 355                                 else
 356                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 357                                 fi
 358                         fi
 359
 360                         # Basic test to check for compatible version and correct linking
 361                         # *does not* test for RSA - that comes later.
 362                         AC_RUN_IFELSE([AC_LANG_SOURCE([[
 363         #include <string.h>
 364         #include <openssl/rand.h>
 365         int main(void)
 366         {
 367                 char a[2048];
 368                 memset(a, 0, sizeof(a));
 369                 RAND_add(a, sizeof(a), sizeof(a));
 370                 return(RAND_status() <= 0);
 371         }
 372                                 ]])],[
 373                                         found_crypto=1
 374                                         break;
 375                                 ],[
 376                         ],[])
 377
 378                         if test ! -z "$found_crypto" ; then
 379                                 break;
 380                         fi
 381                 done
 382
 383                 if test -z "$ssldir" ; then
 384                         ssldir="(system)"
 385                 fi
 386
 387                 if test ! -z "$found_crypto" ; then
 388                         ac_cv_openssldir=$ssldir
 389                 else
 390                         ac_cv_openssldir="no"
 391                 fi
 392         ])
 393         LIBS="$saved_LIBS"
 394         LDFLAGS="$saved_LDFLAGS"
 395         CFLAGS="$saved_CFLAGS"
 396
 397         if test "x$ac_cv_openssldir" != "xno" ; then
 398                 AC_DEFINE(HAVE_OPENSSL,[],[whethe we have openssl])
 399                 found_ssl=yes
 400                 LIBS="-lssl -lcrypto $LIBS"
 401                 dnl Need to recover ssldir - test above runs in subshell
 402                 ssldir=$ac_cv_openssldir
 403                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 404                         # Try to use $ssldir/lib if it exists, otherwise
 405                         # $ssldir
 406                         if test -d "$ssldir/lib" ; then
 407                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 408                                 if test ! -z "$need_dash_r" ; then
 409                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 410                                 fi
 411                         else
 412                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 413                                 if test ! -z "$need_dash_r" ; then
 414                                         LDFLAGS="-R$ssldir $LDFLAGS"
 415                                 fi
 416                         fi
 417                         # Try to use $ssldir/include if it exists, otherwise
 418                         # $ssldir
 419                         if test -d "$ssldir/include" ; then
 420                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 421                         else
 422                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 423                         fi
 424                 fi
 425         fi
 426 fi
 427 dnl Checks for the SSLdir
 428 dnl this is a bit different than the rest,
 429 dnl because of the citadel used to have a keys/ subdir.
 430 AC_ARG_WITH(ssldir,
 431                     [  --with-ssldir          directory to store the ssl certificates under],
 432                         [ if test "x$withval" != "xno" ; then
 433
 434                                                   ssl_dir="$withval"
 435                                                   if test "$found_ssl" = "no"; then
 436                                                      echo "Your setup was incomplete; ssldir doesn't make sense without openssl"
 437                                                      exit
 438                                                   fi
 439                           fi
 440                         AC_SUBST(MAKE_SSL_DIR)
 441                         ]
 442 )
 443 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
 444
 445
 446
 447
 448 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 449
 450 if test "$ok_nls" != "no"; then
 451         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 452         ok_nls=$ok_xgettext
 453 fi
 454
 455 if test "$ok_nls" != "no"; then
 456         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 457         ok_nls=$ok_msgmerge
 458 fi
 459
 460 if test "$ok_nls" != "no"; then
 461         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 462         ok_nls=$ok_msgfmt
 463 fi
 464
 465 if test "$ok_nls" != "no"; then
 466         AC_MSG_RESULT(WebCit will be built with national language support.)
 467         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 468         PROG_SUBDIRS="$PROG_SUBDIRS po/webcit/"
 469 else
 470         AC_MSG_RESULT(WebCit will be built without national language support.)
 471 fi
 472
 473 AC_SUBST(SETUP_LIBS)
 474
 475 dnl disable backtrace if we don't want it.
 476 AC_ARG_WITH(gprof,
 477                     [  --with-gprof          enable profiling],
 478                         [ if test "x$withval" != "xno" ; then
 479                              CFLAGS="$CFLAGS  -pg "
 480                              LDFLAGS="$LDFLAGS  -pg "
 481                           fi
 482                         ]
 483 )
 484
 485 dnl disable backtrace if we don't want it.
 486 AC_ARG_WITH(backtrace,
 487                     [  --with-backtrace          enable backtrace dumps in the syslog],
 488                         [ if test "x$withval" != "xno" ; then
 489                              CFLAGS="$CFLAGS  -rdynamic "
 490                              LDFLAGS="$LDFLAGS  -rdynamic "
 491                              AC_CHECK_FUNCS(backtrace)
 492                           fi
 493                         ]
 494 )
 495
 496 if test "$prefix" = NONE; then
 497         datadir=$ac_default_prefix
 498         localedir=$ac_default_prefix
 499         wwwdir=$ac_default_prefix
 500         rundir=$ac_default_prefix
 501         editordir=$ac_default_prefix/tiny_mce
 502         etcdir=$ac_default_prefix
 503 else
 504         localedir=$prefix
 505         wwwdir=$prefix
 506         datadir=$prefix
 507         rundir=$prefix
 508         editordir=$prefix/tiny_mce
 509         etcdir=$prefix
 510 fi
 511
 512 dnl where to put the locale files
 513 AC_ARG_WITH(localedir,
 514                     [  --with-localedir          directory to put the locale files to],
 515                         [ if test "x$withval" != "xno" ; then
 516                             localedir=$withval
 517                           fi
 518                         ]
 519 )
 520 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 521 LOCALEDIR=$localedir
 522 AC_SUBST(LOCALEDIR)
 523
 524 dnl Checks where to put our templates
 525 AC_ARG_WITH(wwwdir,
 526                     [  --with-wwwdir             directory to put our templates],
 527                         [ if test "x$withval" != "xno" ; then
 528                                 wwwdir=$withval
 529                           fi
 530                         ]
 531 )
 532 AC_DEFINE_UNQUOTED(WWWDIR, "$wwwdir", [where to find our templates and pics])
 533 WWWDIR=$wwwdir
 534 AC_SUBST(WWWDIR)
 535
 536
 537 dnl Checks for the run-dir for the sockets
 538 AC_ARG_WITH(rundir,
 539                         [  --with-rundir           directory to place runtime files (UDS) to?],
 540                         [ if test "x$withval" != "xno" ; then
 541                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 542
 543                                                 rundir=$withval
 544                                                 AC_SUBST(MAKE_RUN_DIR)
 545                           fi
 546                         ]
 547 )
 548 AC_DEFINE_UNQUOTED(RUNDIR, "$rundir", [define, where the config should go in unix style])
 549
 550 dnl Checks for the Datadir
 551 AC_ARG_WITH(datadir,
 552                     [  --with-datadir          directory to store the databases under],
 553                         [ if test "x$withval" != "xno" ; then
 554                                               datadir=$withval
 555                           fi
 556                         ]
 557 )
 558 AC_DEFINE_UNQUOTED(DATADIR, "$datadir",[define, if the user suplied a data-directory to use.])
 559
 560 dnl Checks where to put our editor
 561 AC_ARG_WITH(editordir,
 562                     [  --with-editordir             directory to put our editor],
 563                         [ if test "x$withval" != "xno" ; then
 564                                 editordir=$withval
 565                           fi
 566                         ]
 567 )
 568
 569 dnl Checks where to find our configs
 570 AC_ARG_WITH(etcdir,
 571                     [  --with-etcdir             directory to read our configs],
 572                         [ if test "x$withval" != "xno" ; then
 573                                 etcdir=$withval
 574                           fi
 575                         ]
 576 )
 577 AC_DEFINE_UNQUOTED(ETCDIR, "$etcdir", [where to find our configs])
 578 ETCDIR=$etcdir
 579 AC_SUBST(ETCDIR)
 580
 581 abs_srcdir="`cd $srcdir && pwd`"
 582 abs_builddir="`pwd`"
 583 if test "$abs_srcdir" != "$abs_builddir"; then
 584    CFLAGS="$CFLAGS -I $abs_builddir"
 585 fi
 586 AC_CONFIG_HEADERS([sysdep.h])
 587 AC_CONFIG_FILES([Makefile po/webcit/Makefile])
 588 AC_OUTPUT
 589
 590 if test "$abs_srcdir" != "$abs_builddir"; then
 591    ln -s $abs_srcdir/static $abs_builddir
 592    ln -s $abs_srcdir/tiny_mce $abs_builddir
 593    ln -s $abs_srcdir/*.h $abs_builddir
 594    make mkdir-init
 595
 596 else
 597 dnl just run it on devel systems and if non vdir build.
 598    if test -d .svn; then
 599       ./mk_module_init.sh
 600    fi
 601 fi
 602
 603 if test -n "$srcdir"; then
 604    export srcdir=.
 605 fi
 606
 607
 608 echo ------------------------------------------------------------------------
 609 echo 'Character set conversion support:' $ok_iconv
 610 echo 'National language support:       ' $ok_nls
 611 echo