citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_PREREQ(2.52)
   4 AC_INIT([Citadel], [7.10], [http://www.citadel.org/])
   5 AC_REVISION([$Revision: 5108 $])
   6 AC_CONFIG_SRCDIR([citserver.c])
   7 AC_PREFIX_DEFAULT(/usr/local/citadel)
   8 if test "$prefix" = NONE; then
   9         AC_DEFINE_UNQUOTED(CTDLDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  10         ssl_dir="$ac_default_prefix/keys"
  11 else
  12         AC_DEFINE_UNQUOTED(CTDLDIR, "$prefix", [define this to the Citadel home directory])
  13         ssl_dir="$prefix/keys"
  14 fi
  15
  16
  17 dnl Make sure we see all GNU and Solaris extensions.
  18 AC_GNU_SOURCE
  19
  20
  21 dnl Checks for the Datadir
  22 AC_ARG_WITH(datadir,
  23                     [  --with-datadir          directory to store the databases under],
  24                         [ if test "x$withval" != "xno" ; then
  25                                               AC_DEFINE(HAVE_DATA_DIR,[],[use alternate database location?])
  26                                               AC_DEFINE_UNQUOTED(DATA_DIR, "$withval",[define, if the user suplied a data-directory to use.])
  27                                               MAKE_DATA_DIR=$withval
  28                                               AC_SUBST(MAKE_DATA_DIR)
  29                           fi
  30                         ]
  31 )
  32
  33 dnl Checks for the Datadir
  34 AC_ARG_WITH(staticdatadir,
  35                     [  --with-staticdatadir    directory to store citadels system messages under],
  36                         [ if test "x$withval" != "xno" ; then
  37                                                   AC_DEFINE(HAVE_STATICDATA_DIR, [], [should we activate an alternate static text location?])
  38                                                   AC_DEFINE_UNQUOTED(STATICDATA_DIR, "$withval", [where do we put our static text data?])
  39                                                   MAKE_STATICDATA_DIR=$withval
  40                                                   AC_SUBST(MAKE_STATICDATA_DIR)
  41                           fi
  42                         ]
  43 )
  44
  45
  46 dnl Checks for the SSLdir
  47 dnl this is a bit different than the rest,
  48 dnl because of the citadel used to have a keys/ subdir.
  49 AC_ARG_WITH(ssldir,
  50                     [  --with-ssldir          directory to store the ssl certificates under],
  51                         [ if test "x$withval" != "xno" ; then
  52
  53                                                   ssl_dir="$withval"
  54                           fi
  55                         AC_SUBST(MAKE_SSL_DIR)
  56                         ]
  57 )
  58 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
  59
  60
  61 dnl Checks for the spooldir
  62 AC_ARG_WITH(spooldir,
  63                         [  --with-spooldir         directory to keep queues under],
  64                         [ if test "x$withval" != "xno" ; then
  65                                                 AC_DEFINE(HAVE_SPOOL_DIR, [], [enable alternate spool dir?])
  66                                                 AC_DEFINE_UNQUOTED(SPOOL_DIR,"$withval", [where do we place our spool dirs?])
  67                                                 MAKE_SPOOL_DIR=$withval
  68                                                 AC_SUBST(MAKE_SPOOL_DIR)
  69                            fi
  70                         ]
  71 )
  72
  73
  74 dnl Checks for the Configdir
  75 AC_ARG_WITH(sysconfdir,
  76                         [  --with-sysconfdir       directory to store the configs under],
  77                         [ if test "x$withval" != "xno" ; then
  78                                             AC_DEFINE(HAVE_ETC_DIR, [], [should we search our system config in an alternate place?])
  79                                                 AC_DEFINE_UNQUOTED(ETC_DIR, "$withval", [where to search our config files])
  80                                                 MAKE_ETC_DIR=$withval
  81                                                 AC_SUBST(MAKE_ETC_DIR)
  82                           fi
  83                         ]
  84 )
  85
  86 dnl Checks for where to put our utilities
  87 AC_ARG_WITH(utility-bindir,
  88                         [  --with-utility-bindir       directory where to find helper binaries],
  89                         [ if test "x$withval" != "xno" ; then
  90                                             AC_DEFINE(HAVE_UTILBIN_DIR,[],[should we put our helper binaries to another location?])
  91                                                 AC_DEFINE_UNQUOTED(UTILBIN_DIR, "$withval", [were to put our helper programs])
  92                                                 MAKE_UTILBIN_DIR=$withval
  93                                                 AC_SUBST(MAKE_UTILBIN_DIR)
  94                           fi
  95                         ]
  96 )
  97
  98
  99 dnl Checks for the run-dir for the sockets
 100 AC_ARG_WITH(rundir,
 101                         [  --with-rundir           directory to place runtime files (UDS) to?],
 102                         [ if test "x$withval" != "xno" ; then
 103                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 104                                                 AC_DEFINE_UNQUOTED(RUN_DIR, "$withval", [define, where the config should go in unix style])
 105                                                 MAKE_RUN_DIR=$withval
 106                                                 AC_SUBST(MAKE_RUN_DIR)
 107                           fi
 108                         ]
 109 )
 110
 111
 112 dnl Checks for the Pseudo Random Generator sockets TODO: this keeps being default.
 113 AC_DEFINE_UNQUOTED(EGD_POOL, "/var/run/egd-pool", [place to keep our pseudo random generator file])
 114 AC_ARG_WITH(egdpool,
 115                         [  --with-egdpool          the socket from Pseudo Random Generator, defaults to /var/run/egd-pool],
 116                         [ if test "x$withval" != "xno" ; then
 117                                                 AC_DEFINE_UNQUOTED(EGD_POOL, "$withval", [the socket from Pseudo Random Generator])
 118                           fi
 119                         ]
 120 )
 121
 122
 123 AC_ARG_WITH(docdir,
 124                         [  --with-docdir           where to install the documentation. default: /usr/local/citadel/],
 125                         [ if test "x$withval" != "xno" ; then
 126                                         MAKE_DOC_DIR=$withval
 127                                         AC_SUBST(MAKE_DOC_DIR)
 128                           fi
 129                         ]
 130 )
 131
 132
 133
 134 AC_ARG_ENABLE(chkpwd, [  --disable-chkpwd        don't build 'chkpwd'])
 135
 136 AC_ARG_ENABLE(threaded-client, [  --disable-threaded-client
 137                           disable multithreaded client])
 138
 139 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
 140
 141 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
 142 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
 143 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Sleepycat DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
 144 AC_ARG_WITH(ssl,
 145         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
 146         [
 147                 if test "x$withval" != "xno" ; then
 148                         tryssldir=$withval
 149                 fi
 150         ]
 151 )
 152 AC_ARG_WITH(ncurses, [  --without-ncurses       don't use ncurses])
 153
 154 AC_ARG_WITH(with_zlib, [  --with-zlib             use zlib compression if present])
 155 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
 156 AC_ARG_WITH(with_libical, [  --with-libical          use libical calendaring library])
 157 AC_ARG_WITH(with_libsieve, [  --with-libsieve         use libsieve mail sorting library])
 158
 159 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
 160         db_dir="$with_db"
 161         with_db=yes
 162 else
 163         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
 164           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
 165           && db_dir=/usr/local
 166
 167         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
 168         test -d /usr/local/BerkeleyDB.4.2 && db_dir=/usr/local/BerkeleyDB.4.2
 169         test -d /usr/local/BerkeleyDB.4.3 && db_dir=/usr/local/BerkeleyDB.4.3
 170 fi
 171
 172 dnl By default, we only build the client (citadel and whobbs) unless we can
 173 dnl figure out how to build with POSIX threads.
 174 TARGETS=client
 175
 176 AC_CANONICAL_HOST
 177 PTHREAD_DEFS=-D_REENTRANT
 178 AC_MSG_CHECKING([how to compile with POSIX threads])
 179 case "$host" in
 180         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
 181         dnl for dlopen(), and has a wrapper script to link with shared libs.
 182         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
 183         *-*-bsdi[123]*)
 184                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
 185                 AC_DEFINE(HAVE_NONREENTRANT_NETDB,[], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 186                 AC_MSG_RESULT([Old BSDI])
 187         ;;
 188         *-*-bsdi*)
 189                 AC_DEFINE(HAVE_NONREENTRANT_NETDB, [], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 190                 AC_MSG_RESULT([BSD/OS])
 191         ;;
 192         dnl Curses support on Mac OS X is kind of screwed at the moment.
 193         dnl TCP buffering isn't ideal under OS X. This define should also be
 194         dnl checked in other cases of OS X-Linux differences.
 195         *-*-darwin*)
 196                 AC_DEFINE(DISABLE_CURSES,[],[define this to disable use of curses])
 197                 AC_DEFINE(HAVE_DARWIN, [], [define if using OS X/Darwin])
 198                 AC_MSG_RESULT([Mac OS X])
 199         ;;
 200         dnl Digital Unix has an odd way to build for pthreads, and we can't
 201         dnl build pthreads programs with gcc due to header problems.
 202         alpha*-dec-osf*)
 203                 test -z "$CC" && CC=cc
 204                 LIBS="-lpthread -lexc $LIBS"
 205                 check_pthread=no
 206                 AC_MSG_RESULT([Tru64 or Digital UNIX])
 207         ;;
 208         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
 209         *-*-freebsd*)
 210                 if test "$with_kthread" = yes; then
 211                         LIBS="-kthread $LIBS"
 212                 else
 213                         LIBS="-pthread $LIBS"
 214                 fi
 215                 check_pthread=no
 216                 PTHREAD_DEFS=-D_THREAD_SAFE
 217                 AC_MSG_RESULT([FreeBSD])
 218         ;;
 219         *-*-openbsd*)
 220                 LIBS="-pthread $LIBS"
 221                 check_pthread=no
 222                 PTHREAD_DEFS=-pthread
 223                 AC_MSG_RESULT([OpenBSD])
 224         ;;
 225         *-*-linux*)
 226                 PTHREAD_DEFS="-D_REENTRANT -pthread"
 227                 AC_MSG_RESULT([Linux])
 228         ;;
 229         *-*-solaris*)
 230                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
 231                 AC_MSG_RESULT([Solaris])
 232         ;;
 233         *-*-cygwin*)
 234                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
 235                 AC_MSG_RESULT([Cygwin])
 236         ;;
 237         *)
 238                 AC_MSG_RESULT([default])
 239         ;;
 240 esac
 241 dnl DEFS="$DEFS $PTHREAD_DEFS"
 242
 243
 244 dnl Checks for programs.
 245 AC_PROG_CC
 246
 247 dnl Set up system-dependent compiler flags.
 248 if test "$GCC" = yes; then
 249         if test "$CC" = icc; then
 250                 CFLAGS="$CFLAGS -w1"
 251         else
 252                 case "$host" in
 253                         *-*-solaris*|alpha*-dec-osf*)
 254                                 CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts $PTHREAD_DEFS"
 255                         ;;
 256                         *)
 257                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes $PTHREAD_DEFS"
 258                         ;;
 259                 esac
 260         fi
 261 fi
 262
 263 if test "x$enable_pie" = xyes; then
 264         save_CFLAGS="$CFLAGS"
 265         save_LDFLAGS="$LDFLAGS"
 266         CFLAGS="$CFLAGS -fpie"
 267         LDFLAGS="$LDFLAGS -pie -fpie"
 268         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 269         [AC_TRY_LINK([], [],
 270         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 271         if test $ac_cv_pie_fpie = no; then
 272                 CFLAGS="$save_CFLAGS"
 273                 LDFLAGS="$save_LDFLAGS"
 274         fi
 275 fi
 276
 277 AC_PROG_INSTALL
 278 AC_PROG_YACC
 279 missing_dir=`cd $ac_aux_dir && pwd`
 280 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 281 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 282
 283 dnl Checks for system services.
 284
 285 dnl Check the size of various builtin types; see typesize.h (error)
 286 AC_CHECK_SIZEOF(char, 0)
 287 AC_CHECK_SIZEOF(short, 0)
 288 AC_CHECK_SIZEOF(int, 0)
 289 AC_CHECK_SIZEOF(long, 0)
 290 dnl AC_CHECK_SIZEOF(long long, 0)
 291
 292 dnl Checks for libraries.
 293
 294 dnl We want to test for the following in libc before checking for their
 295 dnl respective libraries, because some systems (like Irix) have both, and the
 296 dnl non-libc versions may be broken.
 297 AC_CHECK_FUNCS(crypt gethostbyname connect)
 298
 299 if test "$ac_cv_func_gethostbyname" = no; then
 300         AC_CHECK_LIB(nsl, gethostbyname)
 301 fi
 302
 303 if test "$ac_cv_func_connect" = no; then
 304         AC_CHECK_LIB(socket, connect)
 305 fi
 306
 307 dnl Check for Solaris realtime support
 308 AC_CHECK_LIB(rt, sched_yield)
 309
 310 dnl Determine the system's authentication capabilities.
 311 dnl We currently support PAM, standard getpwnam(), and getspnam()
 312 dnl (Linux shadow passwords)
 313
 314         if test "$with_pam" = yes; then
 315                 save_LIBS=$LIBS
 316                 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 317                         LIBS="-lpam $LIBS"])
 318                 AC_CHECK_FUNCS(pam_start)
 319                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 320         fi
 321         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 322                 save_LIBS=$LIBS
 323                 AC_SEARCH_LIBS(getspnam, shadow, [
 324                         if test "$ac_cv_search_getspnam" = -lshadow; then
 325                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 326                         fi])
 327                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 328                 if test "$ac_cv_func_crypt" = no; then
 329                         AC_CHECK_LIB(crypt, crypt, [
 330                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 331                                 test "$enable_chkpwd" = no && \
 332                                         LIBS="-lcrypt $LIBS"])
 333                 fi
 334         fi
 335
 336 test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 337 AC_CHECK_LIB(resolv, res_query, RESOLV="$RESOLV -lresolv")
 338
 339 if test "x$with_ncurses" != "xno"; then
 340         AC_SEARCH_LIBS(tgetent, [ncurses curses termcap])
 341         AC_SEARCH_LIBS(scrollok, [ncurses curses])
 342         AC_SEARCH_LIBS(initscr, [ncurses curses])
 343 else
 344         AC_SEARCH_LIBS(tgetent, [curses termcap])
 345         AC_SEARCH_LIBS(initscr, [curses])
 346 fi
 347 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 348
 349 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 350 dnl which the -pthread flag takes care of this.)
 351 if test "$check_pthread" != no; then
 352         AC_CHECK_LIB(pthread, pthread_create)
 353         AC_CHECK_LIB(pthreads, pthread_create)
 354 fi
 355
 356 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 357
 358 # The big search for OpenSSL
 359 if test "$with_ssl" != "no"; then
 360         saved_LIBS="$LIBS"
 361         saved_LDFLAGS="$LDFLAGS"
 362         saved_CFLAGS="$CFLAGS"
 363         if test "x$prefix" != "xNONE"; then
 364                 tryssldir="$tryssldir $prefix"
 365         fi
 366         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 367                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 368                         CFLAGS="$saved_CFLAGS"
 369                         LDFLAGS="$saved_LDFLAGS"
 370                         LIBS="$saved_LIBS -lssl -lcrypto"
 371
 372                         # Skip directories if they don't exist
 373                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 374                                 continue;
 375                         fi
 376                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 377                                 # Try to use $ssldir/lib if it exists, otherwise
 378                                 # $ssldir
 379                                 if test -d "$ssldir/lib" ; then
 380                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 381                                         if test ! -z "$need_dash_r" ; then
 382                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 383                                         fi
 384                                 else
 385                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 386                                         if test ! -z "$need_dash_r" ; then
 387                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 388                                         fi
 389                                 fi
 390                                 # Try to use $ssldir/include if it exists, otherwise
 391                                 # $ssldir
 392                                 if test -d "$ssldir/include" ; then
 393                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 394                                 else
 395                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 396                                 fi
 397                         fi
 398
 399                         # Basic test to check for compatible version and correct linking
 400                         # *does not* test for RSA - that comes later.
 401                         AC_TRY_RUN(
 402                                 [
 403         #include <string.h>
 404         #include <openssl/rand.h>
 405         int main(void)
 406         {
 407                 char a[2048];
 408                 memset(a, 0, sizeof(a));
 409                 RAND_add(a, sizeof(a), sizeof(a));
 410                 return(RAND_status() <= 0);
 411         }
 412                                 ],
 413                                 [
 414                                         found_crypto=1
 415                                         break;
 416                                 ], []
 417                         )
 418
 419                         if test ! -z "$found_crypto" ; then
 420                                 break;
 421                         fi
 422                 done
 423
 424                 if test -z "$ssldir" ; then
 425                         ssldir="(system)"
 426                 fi
 427
 428                 if test ! -z "$found_crypto" ; then
 429                         ac_cv_openssldir=$ssldir
 430                 else
 431                         ac_cv_openssldir="no"
 432                 fi
 433         ])
 434         LIBS="$saved_LIBS"
 435         LDFLAGS="$saved_LDFLAGS"
 436         CFLAGS="$saved_CFLAGS"
 437
 438         if test "x$ac_cv_openssldir" != "xno" ; then
 439                 AC_DEFINE(HAVE_OPENSSL, [], [Define if you have OpenSSL.])
 440                 LIBS="-lssl -lcrypto $LIBS"
 441                 dnl Need to recover ssldir - test above runs in subshell
 442                 ssldir=$ac_cv_openssldir
 443                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 444                         # Try to use $ssldir/lib if it exists, otherwise
 445                         # $ssldir
 446                         if test -d "$ssldir/lib" ; then
 447                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 448                                 if test ! -z "$need_dash_r" ; then
 449                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 450                                 fi
 451                         else
 452                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 453                                 if test ! -z "$need_dash_r" ; then
 454                                         LDFLAGS="-R$ssldir $LDFLAGS"
 455                                 fi
 456                         fi
 457                         # Try to use $ssldir/include if it exists, otherwise
 458                         # $ssldir
 459                         if test -d "$ssldir/include" ; then
 460                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 461                         else
 462                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 463                         fi
 464                 fi
 465         fi
 466 fi
 467
 468 if test "x$with_db" != xno; then
 469         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 470
 471         dblib=""
 472
 473         if test -d "$db_dir/include/db4"; then
 474                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 475                 dblib="db4"
 476         elif test "$db_dir"; then
 477                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 478         elif test -d /usr/include/db4; then
 479                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 480                 dblib="db4"
 481         fi
 482
 483
 484         AC_CHECK_DB([db db-4.1 db-4 db4],
 485                     [
 486                      DATABASE=database_sleepycat.c
 487                     ],
 488                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 489                                   library.  Use --with-db=PATH to specify
 490                                   the path]]))
 491
 492 fi
 493
 494 dnl Checks for the zlib compression library.
 495 if test "x$with_zlib" != xno ; then
 496         AC_CHECK_HEADERS(zlib.h,
 497                 [AC_CHECK_LIB(z, zlibVersion,
 498                         [ok_zlib=yes],,
 499         )])
 500 fi
 501
 502 if test "x$ok_zlib" = xyes ; then
 503         SERVER_LIBS="-lz $SERVER_LIBS"
 504         AC_DEFINE(HAVE_ZLIB, [], [define this if you have zlib compression available])
 505 fi
 506
 507
 508
 509
 510 dnl Checks for the OpenLDAP client library.
 511 if test "x$with_ldap" != xno ; then
 512         AC_CHECK_HEADERS(ldap.h,
 513                 [AC_CHECK_LIB(ldap, ldap_init,
 514                         [ok_ldap=yes],,
 515         )])
 516 fi
 517
 518 if test "x$ok_ldap" = xyes ; then
 519         SERVER_LIBS="-lldap $SERVER_LIBS"
 520         AC_DEFINE(HAVE_LDAP, [], [define this if you have OpenLDAP client available])
 521 fi
 522
 523
 524
 525
 526
 527 dnl Checks for the libsieve mailbox sorting library.
 528 if test "x$with_libsieve" != xno ; then
 529         AC_CHECK_HEADERS(sieve2.h,
 530                 [AC_CHECK_LIB(sieve, sieve2_license,
 531                         [ok_libsieve=yes],,
 532         )])
 533 fi
 534
 535 if test "x$ok_libsieve" = xyes ; then
 536         SERVER_LIBS="-lsieve $SERVER_LIBS"
 537         AC_DEFINE(HAVE_LIBSIEVE, [], [define this if you have the libsieve mailbox filtering library available])
 538 fi
 539
 540
 541
 542
 543 dnl Checks for the libical calendaring library.
 544 if test "x$with_libical" != xno ; then
 545         AC_CHECK_HEADERS(ical.h,
 546                 [AC_CHECK_LIB(ical, icalcomponent_new,
 547                         [ok_libical=yes],,
 548         )])
 549 fi
 550
 551 if test "x$ok_libical" = xyes ; then
 552
 553         AC_TRY_RUN(
 554                 [
 555 #include <ical.h>
 556 main() {
 557         int major, minor, v;
 558         sscanf(ICAL_VERSION, "%d.%d", &major, &minor);
 559         v = 100*major + minor;
 560         printf("libical version: %i\n", v);
 561         if (v >= 24) {
 562                 printf("This version is ok.\n");
 563                 return(0);
 564         }
 565         printf("libical 0.24 or newer required.\n");
 566         printf("Citadel will be built without calendar support.\n");
 567         return(1);
 568 }
 569                 ],
 570                 [
 571                         SERVER_LIBS="-lical $SERVER_LIBS"
 572                         AC_DEFINE(HAVE_LIBICAL, [], [define this if you have the libical calendaring library available])
 573                 ]
 574         )
 575 fi
 576
 577
 578
 579
 580 dnl Checks for header files.
 581 AC_HEADER_DIRENT
 582 AC_HEADER_STDC
 583 AC_HEADER_SYS_WAIT
 584
 585 dnl
 586 dnl TODO: for the DB header checks, we should check whether the headers
 587 dnl define db_env_create, somehow
 588 dnl
 589 AC_CHECK_HEADERS(curses.h dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/time.h sys/prctl.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h)
 590
 591 dnl
 592 dnl need to check if this is actually compilable, sometimes there are
 593 dnl conflicts with the system's headers (eg solaris xpg4 style headers)
 594 dnl
 595 if test "x$with_ncurses" != xno; then
 596         AC_CHECK_HEADERS(ncurses.h,,,[ ])
 597 fi
 598
 599 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H, [], [define this if you have the resolv.h header file.]),,
 600 [#ifdef HAVE_SYS_TYPES_H
 601 #include <sys/types.h>
 602 #endif
 603 #ifdef HAVE_NETINET_IN_H
 604 #include <netinet/in.h>
 605 #endif
 606 #ifdef HAVE_ARPA_NAMESER_H
 607 #include <arpa/nameser.h>
 608 #endif])
 609
 610
 611 dnl Checks for typedefs, structures, and compiler characteristics.
 612 AC_C_CONST
 613 AC_TYPE_PID_T
 614 AC_TYPE_SIZE_T
 615 AC_HEADER_TIME
 616
 617 dnl defined in acinclude.m4:
 618 CIT_STRUCT_TM
 619
 620 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 621 [AC_TRY_COMPILE([#include <sys/types.h>
 622 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 623 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 624 if test $ac_cv_struct_ut_type = yes; then
 625         AC_DEFINE(HAVE_UT_TYPE, [], [define this if struct utmp has an ut_type member])
 626 fi
 627
 628 AC_CACHE_CHECK(
 629         [for call semantics from getpwuid_r],
 630         ac_cv_call_getpwuid_r,
 631         [AC_TRY_COMPILE([#include <sys/types.h>
 632 #include <pwd.h>],
 633                          [
 634                                 struct passwd pw, *pwp;
 635                                 char pwbuf[64];
 636                                 uid_t uid;
 637
 638                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 639                         ],
 640                         ac_cv_call_getpwuid_r=yes,
 641                         ac_cv_call_getpwuid_r=no)
 642         ])
 643
 644 if test $ac_cv_call_getpwuid_r = no; then
 645         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 646         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 647         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 648         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 649 else
 650         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 651         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 652         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 653 fi
 654
 655 dnl AC_CHECK_FUNCS(res_query)
 656 AC_CACHE_CHECK([for the resolver calls],
 657                ac_cv_resquery_ok,
 658 [AC_TRY_COMPILE([#include <netinet/in.h>
 659 #include <arpa/nameser.h>
 660 #include <resolv.h>],
 661                 [
 662                         char *domain="www.google.com";
 663                         u_char *answer;
 664                         int len;
 665                         len = res_query( domain, C_IN, T_A, answer, PACKETSZ );
 666                 ],
 667                 ac_cv_resquery_ok=yes,
 668                 ac_cv_resquery_ok=no)
 669 ])
 670 echo "resquery: $ac_cv_resquery_ok"
 671
 672 dnl if test "$ac_cv_resquery_ok" = "no" ; then
 673 dnl    AC_DEFINE(RES_QUERY_GONE, "#error resquery not here. can't continue.")
 674 dnl fi
 675
 676
 677
 678 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 679 [AC_TRY_COMPILE([#include <sys/types.h>
 680 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 681 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 682 if test $ac_cv_struct_ut_host = yes; then
 683         AC_DEFINE(HAVE_UT_HOST, [], [define this if struct utmp has an ut_host member])
 684 fi
 685
 686 dnl Checks for library functions.
 687 AC_FUNC_GETPGRP
 688 AC_PROG_GCC_TRADITIONAL
 689 AC_TYPE_SIGNAL
 690 AC_FUNC_VPRINTF
 691 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 692
 693 dnl Now check for pthreads
 694
 695 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 696 dnl we need to include pthread.h
 697
 698 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 699 [AC_TRY_LINK([#include <pthread.h>],
 700 [       pthread_t thread;
 701
 702         /* The GNU C library defines this for functions which it implements
 703            to always fail with ENOSYS.  Some functions are actually named
 704            something starting with __ and the normal name is an alias.  */
 705 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 706         choke me
 707 #else
 708         pthread_cancel(thread);
 709 #endif],
 710 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 711 if test "$ac_cv_func_pthread_cancel" = yes; then
 712         AC_DEFINE(HAVE_PTHREAD_CANCEL, [], [define this if you have the pthread_cancel() function])
 713 fi
 714
 715 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
 716 [AC_TRY_LINK([#include <pthread.h>],
 717 [       /* The GNU C library defines this for functions which it implements
 718            to always fail with ENOSYS.  Some functions are actually named
 719            something starting with __ and the normal name is an alias.  */
 720 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 721         choke me
 722 #else
 723         pthread_create(NULL, NULL, NULL, NULL);
 724 #endif],
 725 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
 726 if test "$ac_cv_func_pthread_create" = yes; then
 727         test "$DATABASE" && TARGETS="client server utils"
 728         if test "x$enable_threaded_client" != xno; then
 729                 AC_DEFINE(THREADED_CLIENT, [], [define this if you want to enable the multithreaded client])
 730         fi
 731 fi
 732
 733 AC_REPLACE_FUNCS(snprintf getutline)
 734
 735 AC_CACHE_CHECK([the weather], ac_cv_weather, [
 736         sleep 1
 737         echo $ECHO_N "opening your window... $ECHO_C" >&6
 738         sleep 2
 739         month=`date | cut -f 2 -d ' '`
 740         case $month in
 741         Dec | Jan | Feb)
 742                 ac_cv_weather="it's cold!"
 743                 ;;
 744         Mar | Apr)
 745                 ac_cv_weather="it's wet!"
 746                 ;;
 747         Jul | Aug)
 748                 ac_cv_weather="it's hot!"
 749                 ;;
 750         Oct | Nov)
 751                 ac_cv_weather="it's cool"
 752                 ;;
 753         May | Jun | Sep | *)
 754                 ac_cv_weather="it's fine"
 755                 ;;
 756         esac
 757         ])
 758
 759
 760
 761 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
 762         number=`date | cut -c 19`
 763         case $number in
 764         7)
 765                 ac_cv_under_the_bed="lunatics and monsters found"
 766                 ;;
 767         *)
 768                 ac_cv_under_the_bed="dust bunnies found"
 769                 ;;
 770         esac
 771         ])
 772
 773 dnl Done! Now write the Makefile and sysdep.h
 774 AC_SUBST(AUTH)
 775 AC_SUBST(RESOLV)
 776 AC_SUBST(chkpwd_LIBS)
 777 AC_SUBST(TARGETS)
 778 AC_SUBST(DATABASE)
 779 AC_SUBST(SERVER_LDFLAGS)
 780 AC_SUBST(SERVER_LIBS)
 781 AC_SUBST(SETUP_LIBS)
 782 AC_CONFIG_HEADER(sysdep.h)
 783 AC_CONFIG_FILES([Makefile])
 784 AC_OUTPUT(database_cleanup.sh)
 785
 786 if test -z "$DATABASE"; then
 787         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
 788 fi
 789
 790 echo ------------------------------------------------------------------------
 791 echo 'zlib compression:                ' $ok_zlib
 792 echo 'Calendar support:                ' $ok_libical
 793 echo 'LDAP support:                    ' $ok_ldap
 794 echo 'Sieve mailbox filtering support: ' $ok_libsieve
 795 echo
 796 echo 'Note: if you are not using Linux, make sure you are using GNU make'
 797 echo '(gmake) to compile Citadel.'
 798 echo