citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.52)
   3 AC_INIT([Citadel], [7.89], [http://www.citadel.org/])
   4 AC_REVISION([$Revision: 5108 $])
   5 AC_CONFIG_SRCDIR([citserver.c])
   6 AC_CONFIG_HEADER(sysdep.h)
   7 AC_CONFIG_MACRO_DIR([m4])
   8 AC_PREFIX_DEFAULT(/usr/local/citadel)
   9 if test "$prefix" = NONE; then
  10         AC_DEFINE_UNQUOTED(CTDLDIR, "$ac_default_prefix", [define this to the Citadel home directory])
  11         ssl_dir="$ac_default_prefix/keys"
  12         localedir=$ac_default_prefix
  13 else
  14         AC_DEFINE_UNQUOTED(CTDLDIR, "$prefix", [define this to the Citadel home directory])
  15         ssl_dir="$prefix/keys"
  16         localedir=$prefix
  17 fi
  18
  19 dnl Make sure we see all GNU and Solaris extensions.
  20 AC_GNU_SOURCE
  21
  22
  23 dnl Checks for the Datadir
  24 AC_ARG_WITH(datadir,
  25                     [  --with-datadir          directory to store the databases under],
  26                         [ if test "x$withval" != "xno" ; then
  27                                               AC_DEFINE(HAVE_DATA_DIR,[],[use alternate database location?])
  28                                               AC_DEFINE_UNQUOTED(DATA_DIR, "$withval",[define, if the user suplied a data-directory to use.])
  29                                               MAKE_DATA_DIR=$withval
  30                                               AC_SUBST(MAKE_DATA_DIR)
  31                           fi
  32                         ]
  33 )
  34
  35
  36 dnl Checks for the helpDatadir
  37 AC_ARG_WITH(helpdir,
  38                     [  --with-helpdir          directory to store the helpfiles under],
  39                         [ if test "x$withval" != "xno" ; then
  40                                               AC_DEFINE(HAVE_HELP_DIR,[],[use alternate database location?])
  41                                               AC_DEFINE_UNQUOTED(HELP_DIR, "$withval",[define, if the user suplied a helpfile-directory to use.])
  42                                               MAKE_HELP_DIR=$withval
  43                                               AC_SUBST(MAKE_HELP_DIR)
  44                           fi
  45                         ]
  46 )
  47
  48 dnl Checks for the Static Datadir
  49 AC_ARG_WITH(staticdatadir,
  50                     [  --with-staticdatadir    directory to store citadels system messages under],
  51                         [ if test "x$withval" != "xno" ; then
  52                                                   AC_DEFINE(HAVE_STATICDATA_DIR, [], [should we activate an alternate static text location?])
  53                                                   AC_DEFINE_UNQUOTED(STATICDATA_DIR, "$withval", [where do we put our static text data?])
  54                                                   MAKE_STATICDATA_DIR=$withval
  55                                                   AC_SUBST(MAKE_STATICDATA_DIR)
  56                           fi
  57                         ]
  58 )
  59
  60
  61 dnl Checks for the SSLdir
  62 dnl this is a bit different than the rest,
  63 dnl because of the citadel used to have a keys/ subdir.
  64 AC_ARG_WITH(ssldir,
  65                     [  --with-ssldir           directory to store the ssl certificates under],
  66                         [ if test "x$withval" != "xno" ; then
  67
  68                                                   ssl_dir="$withval"
  69                           fi
  70                         AC_SUBST(MAKE_SSL_DIR)
  71                         ]
  72 )
  73 AC_DEFINE_UNQUOTED(SSL_DIR, "$ssl_dir", [were should we put our keys?])
  74
  75
  76 dnl Checks for the spooldir
  77 AC_ARG_WITH(spooldir,
  78                         [  --with-spooldir         directory to keep queues under],
  79                         [ if test "x$withval" != "xno" ; then
  80                                                 AC_DEFINE(HAVE_SPOOL_DIR, [], [enable alternate spool dir?])
  81                                                 AC_DEFINE_UNQUOTED(SPOOL_DIR,"$withval", [where do we place our spool dirs?])
  82                                                 MAKE_SPOOL_DIR=$withval
  83                                                 AC_SUBST(MAKE_SPOOL_DIR)
  84                            fi
  85                         ]
  86 )
  87
  88
  89 dnl Checks for the Configdir
  90 AC_ARG_WITH(sysconfdir,
  91                         [  --with-sysconfdir       directory to store the configs under],
  92                         [ if test "x$withval" != "xno" ; then
  93                                             AC_DEFINE(HAVE_ETC_DIR, [], [should we search our system config in an alternate place?])
  94                                                 AC_DEFINE_UNQUOTED(ETC_DIR, "$withval", [where to search our config files])
  95                                                 MAKE_ETC_DIR=$withval
  96                                                 AC_SUBST(MAKE_ETC_DIR)
  97                           fi
  98                         ]
  99 )
 100
 101 dnl Checks for the Configdir
 102 AC_ARG_WITH(autosysconfdir,
 103                         [  --with-autosysconfdir         directory to store the automaticaly maintained configs under],
 104                         [ if test "x$withval" != "xno" ; then
 105                                             AC_DEFINE(HAVE_AUTO_ETC_DIR, [], [should we search our automatic config in an alternate place?])
 106                                                 AC_DEFINE_UNQUOTED(AUTO_ETC_DIR, "$withval", [where to search our automatic config files])
 107                                                 MAKE_AUTO_ETC_DIR=$withval
 108                                                 AC_SUBST(MAKE_AUTO_ETC_DIR)
 109                           fi
 110                         ]
 111 )
 112
 113 dnl Checks for where to put our utilities
 114 AC_ARG_WITH(utility-bindir,
 115                         [  --with-utility-bindir   directory where to find helper binaries],
 116                         [ if test "x$withval" != "xno" ; then
 117                                             AC_DEFINE(HAVE_UTILBIN_DIR,[],[should we put our helper binaries to another location?])
 118                                                 AC_DEFINE_UNQUOTED(UTILBIN_DIR, "$withval", [were to put our helper programs])
 119                                                 MAKE_UTILBIN_DIR=$withval
 120                                                 AC_SUBST(MAKE_UTILBIN_DIR)
 121                           fi
 122                         ]
 123 )
 124
 125
 126 dnl Checks for the run-dir for the sockets
 127 AC_ARG_WITH(rundir,
 128                         [  --with-rundir           directory to place runtime files (UDS) to?],
 129                         [ if test "x$withval" != "xno" ; then
 130                                             AC_DEFINE(HAVE_RUN_DIR, [], [should we put our non volatile files elsewhere?])
 131                                                 AC_DEFINE_UNQUOTED(RUN_DIR, "$withval", [define, where the config should go in unix style])
 132                                                 MAKE_RUN_DIR=$withval
 133                                                 AC_SUBST(MAKE_RUN_DIR)
 134                           fi
 135                         ]
 136 )
 137
 138
 139 dnl Checks for the Pseudo Random Generator sockets TODO: this keeps being default.
 140 AC_DEFINE_UNQUOTED(EGD_POOL, "/var/run/egd-pool", [place to keep our pseudo random generator file])
 141 AC_ARG_WITH(egdpool,
 142                         [  --with-egdpool          the socket from Pseudo Random Generator, defaults to /var/run/egd-pool],
 143                         [ if test "x$withval" != "xno" ; then
 144                                                 AC_DEFINE_UNQUOTED(EGD_POOL, "$withval", [the socket from Pseudo Random Generator])
 145                           fi
 146                         ]
 147 )
 148
 149
 150 AC_ARG_WITH(docdir,
 151                         [  --with-docdir           where to install the documentation. default: /usr/local/citadel/],
 152                         [ if test "x$withval" != "xno" ; then
 153                                         MAKE_DOC_DIR=$withval
 154                                         AC_SUBST(MAKE_DOC_DIR)
 155                           fi
 156                         ]
 157 )
 158
 159 dnl where to put the locale files
 160 AC_ARG_WITH(localedir,
 161                     [  --with-localedir          directory to put the locale files to],
 162                         [ if test "x$withval" != "xno" ; then
 163                             localedir=$withval
 164                           fi
 165                         ]
 166 )
 167 AC_DEFINE_UNQUOTED(LOCALEDIR, "$localedir",[where to find our pot files])
 168 LOCALEDIR=$localedir
 169 AC_SUBST(LOCALEDIR)
 170
 171
 172
 173 dnl Checks for the zlib compression library.
 174 if test "x$with_zlib" != xno ; then
 175        AC_CHECK_HEADERS(zlib.h,
 176                [AC_CHECK_LIB(z, zlibVersion,
 177                        [ok_zlib=yes],,
 178        )])
 179 fi
 180
 181 if test "x$ok_zlib" = xyes ; then
 182        LDFLAGS="-lz $LDFLAGS"
 183        AC_DEFINE(HAVE_ZLIB, [], [define this if you have zlib compression available])
 184 fi
 185
 186
 187
 188
 189 dnl Here is the check for a libc integrated iconv
 190 AC_ARG_ENABLE(iconv,
 191         [  --disable-iconv         do not use iconv charset conversion],
 192         ok_iconv=no, ok_iconv=yes)
 193
 194 AC_MSG_CHECKING(Checking to see if your system supports iconv)
 195 AC_TRY_RUN([
 196         #include <iconv.h>
 197         main() {
 198                 iconv_t ic = (iconv_t)(-1) ;
 199                 ic = iconv_open("UTF-8", "us-ascii");
 200                 iconv_close(ic);
 201                 exit(0);
 202         }
 203  ],
 204                 [
 205                   ok_iconv=yes
 206                   AC_MSG_RESULT([yes])
 207                 ],
 208                 [
 209                   ok_iconv=no
 210                   AC_MSG_RESULT([no])
 211                 ]
 212 )
 213
 214 dnl Check for iconv in external libiconv
 215 if test "$ok_iconv" = no; then
 216         AC_MSG_CHECKING(Checking for an external libiconv)
 217         OLD_LDFLAGS="$LDFLAGS"
 218         LDFLAGS="$LDFLAGS -liconv"
 219         AC_TRY_RUN([
 220                         #include <iconv.h>
 221                         main() {
 222                                 iconv_t ic = (iconv_t)(-1) ;
 223                                 ic = iconv_open("UTF-8", "us-ascii");
 224                                 iconv_close(ic);
 225                         }
 226                 ],
 227                         [
 228                           ok_iconv=yes
 229                           AC_MSG_RESULT([yes])
 230                         ],
 231                         [
 232                           ok_iconv=no
 233                           LDFLAGS="$OLD_LDFLAGS"
 234                           AC_MSG_RESULT([no])
 235                         ]
 236                 )
 237 fi
 238 if test "$ok_iconv" != "no"; then
 239         AC_MSG_RESULT(Citadel will be built with character set conversion.)
 240         AC_DEFINE(HAVE_ICONV,[],[whether we have iconv for charset conversion])
 241 else
 242         AC_MSG_RESULT(Citadel will be built without character set conversion.)
 243 fi
 244
 245 AC_CHECK_LIB(intl, libintl_bindtextdomain, [LDFLAGS="$LDFLAGS -lintl"])
 246
 247
 248
 249 AC_ARG_ENABLE(threaded-client, [  --disable-threaded-client
 250                           disable multithreaded client])
 251
 252 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
 253
 254 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
 255 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
 256 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Berkeley DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
 257 AC_ARG_WITH(ssl,
 258         [  --with-ssl=PATH         Specify path to OpenSSL installation ],
 259         [
 260                 if test "x$withval" != "xno" ; then
 261                         tryssldir=$withval
 262                 fi
 263         ]
 264 )
 265 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
 266 dnl AC_ARG_WITH(with_libdspam, [  --with-libdspam         use libdspam mail spam scanning library])
 267 AC_ARG_WITH(with_gc, [  --with-gc             use the Boehm-Demers-Weiser garbage collection library])
 268
 269 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
 270         db_dir="$with_db"
 271         with_db=yes
 272 else
 273         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
 274           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
 275           && db_dir=/usr/local
 276
 277         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
 278         test -d /usr/local/BerkeleyDB.4.2 && db_dir=/usr/local/BerkeleyDB.4.2
 279         test -d /usr/local/BerkeleyDB.4.3 && db_dir=/usr/local/BerkeleyDB.4.3
 280         test -d /usr/local/BerkeleyDB.4.4 && db_dir=/usr/local/BerkeleyDB.4.4
 281         test -d /usr/local/BerkeleyDB.4.5 && db_dir=/usr/local/BerkeleyDB.4.5
 282 fi
 283
 284 dnl By default, we only build the client (citadel and whobbs) unless we can
 285 dnl figure out how to build with POSIX threads.
 286 TARGETS=client
 287
 288 AC_CANONICAL_HOST
 289 PTHREAD_DEFS=-D_REENTRANT
 290 AC_MSG_CHECKING([how to compile with POSIX threads])
 291 case "$host" in
 292         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
 293         dnl for dlopen(), and has a wrapper script to link with shared libs.
 294         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
 295         *-*-bsdi[123]*)
 296                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
 297                 AC_DEFINE(HAVE_NONREENTRANT_NETDB,[], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 298                 AC_MSG_RESULT([Old BSDI])
 299         ;;
 300         *-*-bsdi*)
 301                 AC_DEFINE(HAVE_NONREENTRANT_NETDB, [], [define this if the OS has broken non-reentrant gethostby{name,addr}() ])
 302                 AC_MSG_RESULT([BSD/OS])
 303         ;;
 304         dnl Curses support on Mac OS X is kind of screwed at the moment.
 305         dnl TCP buffering isn't ideal under OS X. This define should also be
 306         dnl checked in other cases of OS X-Linux differences.
 307         *-*-darwin*)
 308                 AC_DEFINE(HAVE_DARWIN, [], [define if using OS X/Darwin])
 309                 AC_MSG_RESULT([Mac OS X])
 310         ;;
 311         dnl Digital Unix has an odd way to build for pthreads, and we can't
 312         dnl build pthreads programs with gcc due to header problems.
 313         alpha*-dec-osf*)
 314                 test -z "$CC" && CC=cc
 315                 LIBS="-lpthread -lexc $LIBS"
 316                 check_pthread=no
 317                 AC_MSG_RESULT([Tru64 or Digital UNIX])
 318         ;;
 319         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
 320         *-*-freebsd*)
 321                 if test "$with_kthread" = yes; then
 322                         LIBS="-kthread $LIBS"
 323                 else
 324                         LIBS="-pthread $LIBS"
 325                 fi
 326                 check_pthread=no
 327                 PTHREAD_DEFS=-D_THREAD_SAFE
 328                 AC_MSG_RESULT([FreeBSD])
 329         ;;
 330         *-*-openbsd*)
 331                 LIBS="-pthread $LIBS"
 332                 check_pthread=no
 333                 PTHREAD_DEFS=-pthread
 334                 AC_MSG_RESULT([OpenBSD])
 335         ;;
 336         *-*-linux*)
 337                 PTHREAD_DEFS="-D_REENTRANT -pthread"
 338                 AC_MSG_RESULT([Linux])
 339         ;;
 340         *-*-solaris*)
 341                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
 342                 AC_MSG_RESULT([Solaris])
 343         ;;
 344         *-*-cygwin*)
 345                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
 346                 AC_MSG_RESULT([Cygwin])
 347         ;;
 348         *)
 349                 AC_MSG_RESULT([default])
 350         ;;
 351 esac
 352 dnl DEFS="$DEFS $PTHREAD_DEFS"
 353
 354
 355 dnl Checks for programs.
 356 AC_PROG_CC
 357
 358
 359
 360 dnl Set up system-dependent compiler flags.
 361 if test "$GCC" = yes; then
 362         if test "$CC" = icc; then
 363                 CFLAGS="$CFLAGS -w1"
 364         else
 365                 case "$host" in
 366                         *-*-solaris*|alpha*-dec-osf*)
 367                                 CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts $PTHREAD_DEFS"
 368                         ;;
 369                         *)
 370                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes $PTHREAD_DEFS"
 371                         ;;
 372                 esac
 373         fi
 374 fi
 375
 376 if test "x$enable_pie" = xyes; then
 377         save_CFLAGS="$CFLAGS"
 378         save_LDFLAGS="$LDFLAGS"
 379         CFLAGS="$CFLAGS -fpie"
 380         LDFLAGS="$LDFLAGS -pie -fpie"
 381         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 382         [AC_TRY_LINK([], [],
 383         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 384         if test $ac_cv_pie_fpie = no; then
 385                 CFLAGS="$save_CFLAGS"
 386                 LDFLAGS="$save_LDFLAGS"
 387         fi
 388 fi
 389
 390 AC_MSG_CHECKING([how to create dependancy checks])
 391                  if test -n "`$CC -V 2>&1 |grep Sun`"; then
 392                         DEPEND_FLAG=-xM;
 393                  else
 394                         DEPEND_FLAG=-M
 395                  fi
 396 AC_SUBST(DEPEND_FLAG)
 397
 398
 399 AC_PROG_INSTALL
 400 AC_PROG_YACC
 401 missing_dir=`cd $ac_aux_dir && pwd`
 402 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 403 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 404
 405 dnl Checks for system services.
 406
 407 dnl Check the size of various builtin types; see typesize.h (error)
 408 AC_CHECK_SIZEOF(char, 0)
 409 AC_CHECK_SIZEOF(short, 0)
 410 AC_CHECK_SIZEOF(int, 0)
 411 AC_CHECK_SIZEOF(long, 0)
 412 AC_CHECK_SIZEOF(size_t, 0)
 413 dnl AC_CHECK_SIZEOF(long long, 0)
 414
 415 dnl Checks for libraries.
 416
 417 dnl We want to test for the following in libc before checking for their
 418 dnl respective libraries, because some systems (like Irix) have both, and the
 419 dnl non-libc versions may be broken.
 420 AC_CHECK_FUNCS(crypt gethostbyname connect flock getpwnam_r getpwuid_r getloadavg)
 421
 422 AC_CHECK_FUNCS(strftime_l uselocale gettext)
 423
 424 if test "$ok_nls" != "no"; then
 425         AC_CHECK_PROG(ok_xgettext, xgettext, yes, no)
 426         ok_nls=$ok_xgettext
 427 fi
 428
 429 if test "$ok_nls" != "no"; then
 430         AC_CHECK_PROG(ok_msgmerge, msgmerge, yes, no)
 431         ok_nls=$ok_msgmerge
 432 fi
 433
 434 if test "$ok_nls" != "no"; then
 435         AC_CHECK_PROG(ok_msgfmt, msgfmt, yes, no)
 436         ok_nls=$ok_msgfmt
 437 fi
 438
 439 if test "$ok_nls" != "no"; then
 440         AC_MSG_RESULT(citadel will be built with national language support.)
 441         AC_DEFINE(ENABLE_NLS, [], [whether we have NLS support])
 442         PROG_SUBDIRS="$PROG_SUBDIRS po/citadel-setup"
 443 else
 444         AC_MSG_RESULT(citadel will be built without national language support.)
 445 fi
 446
 447 dnl disable backtrace if we don't want it.
 448 AC_ARG_WITH(backtrace,
 449                     [  --with-backtrace        enable backtrace dumps in the syslog],
 450                         [ if test "x$withval" != "xno" ; then
 451                              CFLAGS="$CFLAGS  -rdynamic "
 452                              LDFLAGS="$LDFLAGS  -rdynamic "
 453                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -rdynamic "
 454                              AC_CHECK_FUNCS(backtrace)
 455                           fi
 456                         ]
 457 )
 458
 459 dnl disable backtrace if we don't want it.
 460 AC_ARG_WITH(gprof,
 461                     [  --with-gprof            enable profiling],
 462                         [ if test "x$withval" != "xno" ; then
 463                              CFLAGS="$CFLAGS  -pg "
 464                              LDFLAGS="$LDFLAGS  -pg "
 465                              SERVER_LDFLAGS="$SERVER_LDFLAGS  -pg "
 466                           fi
 467                         ]
 468 )
 469
 470 dnl disable thread table reporting
 471 AC_ARG_WITH(threadlog,
 472                 [  --with-threadlog        enable logging of thread table],
 473                         [ if test "x$withval" != "xno" ; then
 474                                 AC_DEFINE(WITH_THREADLOG, [], [Define if you want logging of the thread tables.])
 475                           fi
 476                         ]
 477 )
 478
 479
 480 if test "$ac_cv_func_gethostbyname" = no; then
 481         AC_CHECK_LIB(nsl, gethostbyname)
 482 fi
 483
 484 if test "$ac_cv_func_connect" = no; then
 485         AC_CHECK_LIB(socket, connect)
 486 fi
 487
 488 dnl Check for Solaris realtime support
 489 AC_CHECK_LIB(rt, sched_yield)
 490
 491 dnl Determine the system's authentication capabilities.
 492 dnl We currently support PAM, standard getpwnam(), and getspnam()
 493 dnl (Linux shadow passwords)
 494
 495 save_LIBS=$LIBS
 496 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 497         LIBS="-lpam $LIBS"])
 498 AC_CHECK_FUNCS(pam_start)
 499 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 500         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 501                 save_LIBS=$LIBS
 502                 AC_SEARCH_LIBS(getspnam, shadow, [
 503                         if test "$ac_cv_search_getspnam" = -lshadow; then
 504                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 505                         fi])
 506                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 507                 if test "$ac_cv_func_crypt" = no; then
 508                         AC_CHECK_LIB(crypt, crypt, [
 509                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 510                                 test "$enable_chkpwd" = no && \
 511                                         LIBS="-lcrypt $LIBS"])
 512                 fi
 513         fi
 514
 515 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 516
 517 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 518 dnl which the -pthread flag takes care of this.)
 519 if test "$check_pthread" != no; then
 520         AC_CHECK_LIB(pthread, pthread_create)
 521         AC_CHECK_LIB(pthreads, pthread_create)
 522 fi
 523
 524 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 525
 526 dnl Checks for the libical iCalendar library.
 527 AC_CHECK_HEADER(libical/ical.h,
 528         [AC_CHECK_LIB(ical, icaltimezone_set_tzid_prefix,
 529                 [
 530                         SERVER_LIBS="-lical $SERVER_LIBS"
 531                 ],
 532                 [
 533                         AC_MSG_ERROR(libical was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 534                 ]
 535         ,
 536         )],
 537         [
 538                 AC_MSG_ERROR(libical/ical.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 539         ]
 540 )
 541
 542
 543 dnl Checks for the libsieve mailbox sorting library.
 544 AC_CHECK_HEADER(sieve2.h,
 545         [AC_CHECK_LIB(sieve, sieve2_license,
 546                 [
 547                         SERVER_LIBS="-lsieve $SERVER_LIBS"
 548                 ],
 549                 [
 550                         AC_MSG_ERROR(libsieve was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 551                 ]
 552         ,
 553         )],
 554         [
 555                 AC_MSG_ERROR(sieve2.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 556         ]
 557 )
 558
 559 saved_CFLAGS="$CFLAGS"
 560 CFLAGS="$CFLAGS $SERVER_LIBS"
 561 dnl Check for libcitadel
 562 AC_CHECK_HEADER(libcitadel.h,
 563         [AC_CHECK_LIB(citadel, libcitadel_version_string,
 564                 [
 565                         LIBS="-lcitadel $LIBS $SERVER_LIBS"
 566                         chkpwd_LIBS="-lcitadel $chkpwd_LIBS"
 567                 ],
 568                 [
 569                         AC_MSG_ERROR(libcitadel was not found or is not usable.  Please install libcitadel.)
 570                 ]
 571         ,
 572         )],
 573         [
 574                 AC_MSG_ERROR(libcitadel.h was not found or is not usable.  Please install libcitadel.)
 575         ]
 576 )
 577
 578 CFLAGS="$saved_CFLAGS"
 579
 580
 581
 582 # The big search for OpenSSL
 583 if test "$with_ssl" != "no"; then
 584         saved_LIBS="$LIBS"
 585         saved_LDFLAGS="$LDFLAGS"
 586         saved_CFLAGS="$CFLAGS"
 587         if test "x$prefix" != "xNONE"; then
 588                 tryssldir="$tryssldir $prefix"
 589         fi
 590         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 591                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 592                         CFLAGS="$saved_CFLAGS"
 593                         LDFLAGS="$saved_LDFLAGS"
 594                         LIBS="$saved_LIBS -lssl -lcrypto"
 595
 596                         # Skip directories if they don't exist
 597                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 598                                 continue;
 599                         fi
 600                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 601                                 # Try to use $ssldir/lib if it exists, otherwise
 602                                 # $ssldir
 603                                 if test -d "$ssldir/lib" ; then
 604                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 605                                         if test ! -z "$need_dash_r" ; then
 606                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 607                                         fi
 608                                 else
 609                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 610                                         if test ! -z "$need_dash_r" ; then
 611                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 612                                         fi
 613                                 fi
 614                                 # Try to use $ssldir/include if it exists, otherwise
 615                                 # $ssldir
 616                                 if test -d "$ssldir/include" ; then
 617                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 618                                 else
 619                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 620                                 fi
 621                         fi
 622
 623                         # Basic test to check for compatible version and correct linking
 624                         # *does not* test for RSA - that comes later.
 625                         AC_TRY_RUN(
 626                                 [
 627         #include <string.h>
 628         #include <openssl/rand.h>
 629         int main(void)
 630         {
 631                 char a[2048];
 632                 memset(a, 0, sizeof(a));
 633                 RAND_add(a, sizeof(a), sizeof(a));
 634                 return(RAND_status() <= 0);
 635         }
 636                                 ],
 637                                 [
 638                                         found_crypto=1
 639                                         break;
 640                                 ], []
 641                         )
 642
 643                         if test ! -z "$found_crypto" ; then
 644                                 break;
 645                         fi
 646                 done
 647
 648                 if test -z "$ssldir" ; then
 649                         ssldir="(system)"
 650                 fi
 651
 652                 if test ! -z "$found_crypto" ; then
 653                         ac_cv_openssldir=$ssldir
 654                 else
 655                         ac_cv_openssldir="no"
 656                 fi
 657         ])
 658         LIBS="$saved_LIBS"
 659         LDFLAGS="$saved_LDFLAGS"
 660         CFLAGS="$saved_CFLAGS"
 661
 662         if test "x$ac_cv_openssldir" != "xno" ; then
 663                 AC_DEFINE(HAVE_OPENSSL, [], [Define if you have OpenSSL.])
 664                 LIBS="-lssl -lcrypto $LIBS"
 665                 dnl Need to recover ssldir - test above runs in subshell
 666                 ssldir=$ac_cv_openssldir
 667                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 668                         # Try to use $ssldir/lib if it exists, otherwise
 669                         # $ssldir
 670                         if test -d "$ssldir/lib" ; then
 671                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 672                                 if test ! -z "$need_dash_r" ; then
 673                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 674                                 fi
 675                         else
 676                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 677                                 if test ! -z "$need_dash_r" ; then
 678                                         LDFLAGS="-R$ssldir $LDFLAGS"
 679                                 fi
 680                         fi
 681                         # Try to use $ssldir/include if it exists, otherwise
 682                         # $ssldir
 683                         if test -d "$ssldir/include" ; then
 684                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 685                         else
 686                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 687                         fi
 688                 fi
 689         fi
 690 fi
 691
 692 if test "x$with_db" != xno; then
 693         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 694
 695         dblib=""
 696
 697         if test -d "$db_dir/include/db4"; then
 698                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 699                 dblib="db4"
 700         elif test "$db_dir"; then
 701                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 702         elif test -d /usr/include/db4; then
 703                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 704                 dblib="db4"
 705         fi
 706
 707
 708         AC_CHECK_DB([db db-4.1 db-4 db4],
 709                     [
 710                      DATABASE=database.c
 711                     ],
 712                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 713                                   library.  Use --with-db=PATH to specify
 714                                   the path]]))
 715
 716 fi
 717
 718
 719
 720
 721 dnl Checks for the OpenLDAP client library.
 722 if test "x$with_ldap" != xno ; then
 723         AC_CHECK_HEADERS(ldap.h,
 724                 [AC_CHECK_LIB(ldap, ldap_init,
 725                         [ok_ldap=yes],,
 726         )])
 727 fi
 728
 729 if test "x$ok_ldap" = xyes ; then
 730         SERVER_LIBS="-lldap $SERVER_LIBS"
 731         AC_DEFINE(HAVE_LDAP, [], [define this if you have OpenLDAP client available])
 732 fi
 733
 734
 735
 736
 737
 738
 739 dnl Checks for the libdspam mail spam scanning library.
 740 dnl if test "x$with_libdspam" != xno ; then
 741 dnl     AC_CHECK_HEADERS(dspam/libdspam.h,
 742 dnl             [AC_CHECK_LIB(dspam, dspam_init,
 743 dnl                     [ok_libdspam=yes],,
 744 dnl     )])
 745 dnl fi
 746 dnl
 747 dnl if test "x$ok_libdspam" = xyes ; then
 748 dnl     SERVER_LIBS="-ldspam $SERVER_LIBS"
 749 dnl     AC_DEFINE(HAVE_LIBDSPAM, [], [(unfinished) define this if you have the libdspam mail spam scanning library available])
 750 dnl fi
 751
 752
 753
 754 dnl Checks for the Expat XML parser.
 755 AC_CHECK_HEADER(expat.h,
 756         [AC_CHECK_LIB(expat, XML_ParserCreateNS,
 757                 [
 758                         SERVER_LIBS="-lexpat $SERVER_LIBS"
 759                 ],
 760                 [
 761                         AC_MSG_ERROR(The Expat XML parser was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 762                 ]
 763         ,
 764         )],
 765         [
 766                 AC_MSG_ERROR(expat.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 767         ]
 768 )
 769
 770
 771
 772
 773
 774
 775
 776 dnl Checks for libcurl.
 777 AC_CHECK_HEADER(curl/curl.h,
 778         [AC_CHECK_LIB(curl, curl_version,
 779                 [
 780                         SERVER_LIBS="-lcurl $SERVER_LIBS"
 781                 ],
 782                 [
 783                         AC_MSG_ERROR(libcurl was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 784                 ]
 785         ,
 786         )],
 787         [
 788                 AC_MSG_ERROR(curl/curl.h was not found and is required.  More info: http://www.citadel.org/doku.php/installation:start)
 789         ]
 790 )
 791
 792
 793
 794
 795
 796
 797
 798
 799
 800
 801 dnl Checks for header files.
 802 AC_HEADER_DIRENT
 803 AC_HEADER_STDC
 804 AC_HEADER_SYS_WAIT
 805
 806 dnl
 807 dnl TODO: for the DB header checks, we should check whether the headers
 808 dnl define db_env_create, somehow
 809 dnl
 810 AC_CHECK_HEADERS(dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/stat.h sys/time.h sys/prctl.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h syscall.h sys/syscall.h)
 811
 812 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H, [], [define this if you have the resolv.h header file.]),,
 813 [#ifdef HAVE_SYS_TYPES_H
 814 #include <sys/types.h>
 815 #endif
 816 #ifdef HAVE_NETINET_IN_H
 817 #include <netinet/in.h>
 818 #endif
 819 #ifdef HAVE_ARPA_NAMESER_H
 820 #include <arpa/nameser.h>
 821 #endif])
 822
 823
 824 dnl Checks for typedefs, structures, and compiler characteristics.
 825 AC_C_CONST
 826 AC_TYPE_PID_T
 827 AC_TYPE_SIZE_T
 828 AC_HEADER_TIME
 829
 830 dnl defined in acinclude.m4:
 831 CIT_STRUCT_TM
 832
 833 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 834 [AC_TRY_COMPILE([#include <sys/types.h>
 835 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 836 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 837 if test $ac_cv_struct_ut_type = yes; then
 838         AC_DEFINE(HAVE_UT_TYPE, [], [define this if struct utmp has an ut_type member])
 839 fi
 840
 841 AC_CACHE_CHECK(
 842         [for call semantics from getpwuid_r],
 843         ac_cv_call_getpwuid_r,
 844         [AC_TRY_COMPILE([#include <sys/types.h>
 845 #include <pwd.h>],
 846                          [
 847                                 struct passwd pw, *pwp;
 848                                 char pwbuf[64];
 849                                 uid_t uid;
 850
 851                                 getpwuid_r(uid, &pw, pwbuf, sizeof(pwbuf), &pwp);
 852                         ],
 853                         ac_cv_call_getpwuid_r=yes,
 854                         ac_cv_call_getpwuid_r=no)
 855         ])
 856
 857 if test $ac_cv_call_getpwuid_r = no; then
 858         AC_DEFINE(SOLARIS_GETPWUID,[],[do we need to use solaris call syntax?])
 859         AC_DEFINE(F_UID_T, "%ld", [whats the matching format string for uid_t?])
 860         AC_DEFINE(F_PID_T, "%ld",  [whats the matching format string for pid_t?])
 861         AC_DEFINE(F_XPID_T, "%lx",  [whats the matching format string for xpid_t?])
 862 else
 863         AC_DEFINE(F_UID_T, "%d",  [whats the matching format string for uid_t?])
 864         AC_DEFINE(F_PID_T, "%d",  [whats the matching format string for pid_t?])
 865         AC_DEFINE(F_XPID_T, "%x",  [whats the matching format string for xpid_t?])
 866 fi
 867
 868
 869 dnl Our own happy little check for the resolver library.
 870
 871 case "`uname -a`" in
 872  OpenBSD*)
 873         echo "we don't need to check for resolv on openbsd"
 874         ;;
 875  FreeBSD*)
 876         echo "we don't need to check for resolv on freeBSD"
 877         ;;
 878  *)
 879         test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 880         AC_CHECK_LIB(resolv, res_query,
 881                 RESOLV="$RESOLV -lresolv",
 882                 [dnl Have to include resolv.h as res_query is sometimes defined as a macro
 883                         AC_MSG_CHECKING([for res_query in -lresolv (with resolv.h if present)])
 884                         saved_libs="$LIBS"
 885                         LIBS="-lresolv $LIBS"
 886                         AC_TRY_LINK([
 887                                 #ifdef HAVE_RESOLV_H
 888                                 #include <resolv.h>
 889                                 #endif],
 890                                 [res_query(0,0,0,0,0)],
 891                                 [AC_MSG_RESULT(yes)
 892                                                 have_res_query=yes],
 893                                 [AC_MSG_RESULT(no)
 894                                         AC_MSG_ERROR(libresolv was not found.  Citadel requires the resolver library.)
 895                                 ])
 896          ]
 897         )
 898         ;;
 899 esac
 900
 901
 902
 903 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 904 [AC_TRY_COMPILE([#include <sys/types.h>
 905 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 906 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 907 if test $ac_cv_struct_ut_host = yes; then
 908         AC_DEFINE(HAVE_UT_HOST, [], [define this if struct utmp has an ut_host member])
 909 fi
 910
 911 dnl Checks for library functions.
 912 AC_FUNC_GETPGRP
 913 AC_PROG_GCC_TRADITIONAL
 914 AC_TYPE_SIGNAL
 915 AC_FUNC_VPRINTF
 916 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 917
 918 dnl Now check for pthreads
 919
 920 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 921 dnl we need to include pthread.h
 922
 923 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 924 [AC_TRY_LINK([#include <pthread.h>],
 925 [       pthread_t thread;
 926
 927         /* The GNU C library defines this for functions which it implements
 928            to always fail with ENOSYS.  Some functions are actually named
 929            something starting with __ and the normal name is an alias.  */
 930 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 931         choke me
 932 #else
 933         pthread_cancel(thread);
 934 #endif],
 935 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 936 if test "$ac_cv_func_pthread_cancel" = yes; then
 937         AC_DEFINE(HAVE_PTHREAD_CANCEL, [], [define this if you have the pthread_cancel() function])
 938 fi
 939
 940 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
 941 [AC_TRY_LINK([#include <pthread.h>],
 942 [       /* The GNU C library defines this for functions which it implements
 943            to always fail with ENOSYS.  Some functions are actually named
 944            something starting with __ and the normal name is an alias.  */
 945 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 946         choke me
 947 #else
 948         pthread_create(NULL, NULL, NULL, NULL);
 949 #endif],
 950 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
 951 if test "$ac_cv_func_pthread_create" = yes; then
 952         test "$DATABASE" && TARGETS="client server utils"
 953         if test "x$enable_threaded_client" != xno; then
 954                 AC_DEFINE(THREADED_CLIENT, [], [define this if you want to enable the multithreaded client])
 955         fi
 956 fi
 957
 958 AC_REPLACE_FUNCS(snprintf getutline)
 959
 960 AC_CACHE_CHECK([the weather], ac_cv_weather, [
 961         sleep 1
 962         echo $ECHO_N "opening your window... $ECHO_C" >&6
 963         sleep 2
 964         month=`date | cut -f 2 -d ' '`
 965         case $month in
 966         Dec | Jan | Feb)
 967                 ac_cv_weather="it's cold!"
 968                 ;;
 969         Mar | Apr)
 970                 ac_cv_weather="it's wet!"
 971                 ;;
 972         Jul | Aug)
 973                 ac_cv_weather="it's hot!"
 974                 ;;
 975         Oct | Nov)
 976                 ac_cv_weather="it's cool"
 977                 ;;
 978         May | Jun | Sep | *)
 979                 ac_cv_weather="it's fine"
 980                 ;;
 981         esac
 982         ])
 983
 984
 985
 986
 987 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
 988         number=`date | cut -c 19`
 989         case $number in
 990         7)
 991                 ac_cv_under_the_bed="lunatics and monsters found"
 992                 ;;
 993         *)
 994                 ac_cv_under_the_bed="dust bunnies found"
 995                 ;;
 996         esac
 997         ])
 998
 999
1000 STRUCT_UCRED
1001
1002
1003
1004 dnl Done! Now write the Makefile and sysdep.h
1005 AC_SUBST(AUTH)
1006 AC_SUBST(RESOLV)
1007 AC_SUBST(chkpwd_LIBS)
1008 AC_SUBST(TARGETS)
1009 AC_SUBST(DATABASE)
1010 AC_SUBST(SERVER_LDFLAGS)
1011 AC_SUBST(SERVER_LIBS)
1012 AC_SUBST(SETUP_LIBS)
1013 AC_CONFIG_FILES([Makefile])
1014 AC_OUTPUT(database_cleanup.sh po/citadel-setup/Makefile)
1015
1016 if test -z "$DATABASE"; then
1017         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
1018 fi
1019
1020 abs_srcdir="`cd $srcdir && pwd`"
1021 abs_builddir="`pwd`"
1022 if test "$abs_srcdir" != "$abs_builddir"; then
1023    ln -sf $abs_srcdir/include $abs_builddir
1024    ln -sf $abs_srcdir/Make_sources $abs_builddir
1025    ln -sf $abs_srcdir/Make_modules $abs_builddir
1026    for i in $abs_srcdir/*.h ; do
1027       if test "$abs_srcdir/sysdep.h" != "$i"; then
1028          ln -sf $i $abs_builddir
1029       fi
1030    done
1031    for d in `/bin/ls $abs_srcdir/modules/`; do
1032         (mkdir -p $abs_builddir/modules/$d)
1033    done
1034    if test -d "$abs_srcdir/user_modules/"; then
1035       for d in `/bin/ls $abs_srcdir/user_modules/`; do
1036         (mkdir -p $abs_builddir/user_modules/$d)
1037         done
1038    fi
1039    mkdir -p $abs_builddir/utils
1040    mkdir -p $abs_builddir/utillib
1041    mkdir -p $abs_builddir/textclient
1042 fi
1043
1044 if test -n "$srcdir"; then
1045    export srcdir=.
1046 fi
1047
1048
1049 echo ------------------------------------------------------------------------
1050 echo 'LDAP support:                    ' $ok_ldap
1051 echo 'Character set conversion support:' $ok_iconv
1052 echo 'Boehm-Demers-Weiser support:     ' $ok_gc
1053 dnl echo 'DSpam Scanning support:          ' $ok_libdspam
1054 echo
1055 echo 'Note: if you are not using Linux, make sure you are using GNU make'
1056 echo '(gmake) to compile Citadel.'
1057 echo