citadel/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl $Id$
   3 AC_PREREQ(2.52)
   4 AC_INIT([Citadel/UX], [6.15], [http://uncensored.citadel.org/])
   5 AC_REVISION([$Revision$])
   6 AC_CONFIG_SRCDIR([citserver.c])
   7 AC_PREFIX_DEFAULT(/usr/local/citadel)
   8 if test "$prefix" = NONE; then
   9         AC_DEFINE_UNQUOTED(BBSDIR, "$ac_default_prefix")
  10 else
  11         AC_DEFINE_UNQUOTED(BBSDIR, "$prefix")
  12 fi
  13
  14 AC_ARG_ENABLE(autologin, [  --disable-autologin     disable autologin (default is enabled if possible)])
  15 AC_ARG_ENABLE(chkpwd, [  --disable-chkpwd        don't build 'chkpwd'])
  16
  17 AC_ARG_ENABLE(threaded-client, [  --disable-threaded-client
  18                           disable multithreaded client])
  19
  20 AC_ARG_ENABLE(pie, [  --enable-pie            build position-independent executables])
  21
  22 AC_ARG_WITH(pam, [  --with-pam              use PAM if present (see PAM.txt before you try this)])
  23 AC_ARG_WITH(kthread, [  --with-kthread          use kernel threads (on FreeBSD) (not recommended yet)])
  24 AC_ARG_WITH(db, [  --with-db@<:@=DIR@:>@         use Sleepycat DB 3.x @<:@DIR=/usr/local/BerkeleyDB.3.@<:@123@:>@@:>@])
  25 AC_ARG_WITH(ssl,
  26         [  --with-ssl=PATH     Specify path to OpenSSL installation ],
  27         [
  28                 if test "x$withval" != "xno" ; then
  29                         tryssldir=$withval
  30                 fi
  31         ]
  32 )
  33 AC_ARG_WITH(ncurses, [  --without-ncurses       don't use ncurses])
  34
  35 AC_ARG_WITH(with_zlib, [  --with-zlib             use zlib compression if present])
  36 AC_ARG_WITH(with_ldap, [  --with-ldap             use OpenLDAP client library])
  37 AC_ARG_WITH(with_libical, [  --with-libical          use libical calendaring library])
  38 AC_ARG_WITH(with_newt, [  --with-newt          use newt window library])
  39
  40 if test "x$with_db" != xno -a "x$with_db" != xyes -a "$with_db"; then
  41         db_dir="$with_db"
  42         with_db=yes
  43 else
  44         test -f /usr/local/lib/libdb.a -o -f /usr/local/lib/libdb.so \
  45           -o -f /usr/local/lib/libdb4.a -o -f /usr/local/lib/libdb4.so \
  46           && db_dir=/usr/local
  47
  48         test -d /usr/local/BerkeleyDB.4.1 && db_dir=/usr/local/BerkeleyDB.4.1
  49 fi
  50
  51 dnl By default, we only build the client (citadel and whobbs) unless we can
  52 dnl figure out how to build with POSIX threads.
  53 TARGETS=client
  54
  55 AC_CANONICAL_HOST
  56 PTHREAD_DEFS=-D_REENTRANT
  57 case "$host" in
  58         dnl BSDI 3.0 wants relocatable object modules instead of shared libs
  59         dnl for dlopen(), and has a wrapper script to link with shared libs.
  60         dnl Also has stupid non-reentrant gethostbyaddr() and friends.
  61         *-*-bsdi[123]*)
  62                 test -z "$CC" -a -x /usr/bin/shlicc2 && CC=shlicc2
  63                 AC_DEFINE(HAVE_NONREENTRANT_NETDB)
  64         ;;
  65         *-*-bsdi*)
  66                 AC_DEFINE(HAVE_NONREENTRANT_NETDB)
  67         ;;
  68         dnl Curses support on Mac OS X is kind of screwed at the moment.
  69         *-*-darwin*)
  70                 AC_DEFINE(DISABLE_CURSES)
  71         ;;
  72         dnl Digital Unix has an odd way to build for pthreads, and we can't
  73         dnl build pthreads programs with gcc due to header problems.
  74         alpha*-dec-osf*)
  75                 test -z "$CC" && CC=cc
  76                 LIBS="-lpthread -lexc $LIBS"
  77                 check_pthread=no
  78         ;;
  79         dnl FreeBSD is similar to Digital UNIX with DEC C, which has a -pthread flag:
  80         *-*-freebsd*)
  81                 if test "$with_kthread" = yes; then
  82                         LIBS="-kthread $LIBS"
  83                 else
  84                         LIBS="-pthread $LIBS"
  85                 fi
  86                 check_pthread=no
  87                 PTHREAD_DEFS=-D_THREAD_SAFE
  88         ;;
  89         *-*-openbsd*)
  90                 LIBS="-pthread $LIBS"
  91                 check_pthread=no
  92                 PTHREAD_DEFS=-pthread
  93         ;;
  94         *-*-solaris*)
  95                 PTHREAD_DEFS="-D_REENTRANT -D_PTHREADS"
  96         ;;
  97         *-*-cygwin*)
  98                 SERVER_LDFLAGS="-Wl,-subsystem,windows"
  99         ;;
 100 esac
 101 DEFS="$DEFS $PTHREAD_DEFS"
 102
 103 dnl Checks for programs.
 104 AC_PROG_CC
 105
 106 dnl Set up system-dependent compiler flags.
 107 if test "$GCC" = yes; then
 108         case "$host" in
 109                 *-*-solaris*|alpha*-dec-osf*)
 110                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wno-char-subscripts"
 111                 ;;
 112                 *)
 113                         CFLAGS="$CFLAGS -Wall -Wcast-qual -Wcast-align -Wstrict-prototypes"
 114                 ;;
 115         esac
 116 fi
 117
 118 if test "x$enable_pie" = xyes; then
 119         save_CFLAGS="$CFLAGS"
 120         save_LDFLAGS="$LDFLAGS"
 121         CFLAGS="$CFLAGS -fpie"
 122         LDFLAGS="$LDFLAGS -pie -fpie"
 123         AC_CACHE_CHECK([whether compiler accepts -pie -fpie], ac_cv_pie_fpie,
 124         [AC_TRY_LINK([], [],
 125         ac_cv_pie_fpie=yes, ac_cv_pie_fpie=no)])
 126         if test $ac_cv_pie_fpie = no; then
 127                 CFLAGS="$save_CFLAGS"
 128                 LDFLAGS="$save_LDFLAGS"
 129         fi
 130 fi
 131
 132 AC_PROG_INSTALL
 133 AC_PROG_YACC
 134 missing_dir=`cd $ac_aux_dir && pwd`
 135 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
 136 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
 137
 138 dnl Checks for system services.
 139
 140 dnl Check the size of various builtin types; see typesize.h (error)
 141 AC_CHECK_SIZEOF(char, 0)
 142 AC_CHECK_SIZEOF(short, 0)
 143 AC_CHECK_SIZEOF(int, 0)
 144 AC_CHECK_SIZEOF(long, 0)
 145 dnl AC_CHECK_SIZEOF(long long, 0)
 146
 147 dnl Checks for libraries.
 148
 149 dnl We want to test for the following in libc before checking for their
 150 dnl respective libraries, because some systems (like Irix) have both, and the
 151 dnl non-libc versions may be broken.
 152 AC_CHECK_FUNCS(crypt gethostbyname connect)
 153
 154 if test "$ac_cv_func_gethostbyname" = no; then
 155         AC_CHECK_LIB(nsl, gethostbyname)
 156 fi
 157
 158 if test "$ac_cv_func_connect" = no; then
 159         AC_CHECK_LIB(socket, connect)
 160 fi
 161
 162 dnl Check for Solaris realtime support
 163 AC_CHECK_LIB(rt, sched_yield)
 164
 165 dnl Determine the system's authentication capabilities, if autologin is
 166 dnl requested. We currently support PAM, standard getpwnam(), and getspnam()
 167 dnl (Linux shadow passwords)
 168 if test "$enable_autologin" != no; then
 169         if test "$with_pam" = yes; then
 170                 save_LIBS=$LIBS
 171                 AC_CHECK_LIB(pam, pam_start, [chkpwd_LIBS="-lpam $chkpwd_LIBS"
 172                         LIBS="-lpam $LIBS"])
 173                 AC_CHECK_FUNCS(pam_start)
 174                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 175         fi
 176         if test "$ac_cv_func_pam_start" = no -o "$with_pam" != yes; then
 177                 save_LIBS=$LIBS
 178                 AC_SEARCH_LIBS(getspnam, shadow, [
 179                         if test "$ac_cv_search_getspnam" = -lshadow; then
 180                                 chkpwd_LIBS="-lshadow $chkpwd_LIBS"
 181                         fi])
 182                 test "$enable_chkpwd" != no && LIBS=$save_LIBS
 183                 if test "$ac_cv_func_crypt" = no; then
 184                         AC_CHECK_LIB(crypt, crypt, [
 185                                 chkpwd_LIBS="-lcrypt $chkpwd_LIBS"
 186                                 test "$enable_chkpwd" = no && \
 187                                         LIBS="-lcrypt $LIBS"])
 188                 fi
 189         fi
 190         if test "$ac_cv_func_crypt" = yes -o "$ac_cv_lib_crypt_crypt" = yes -o "$ac_cv_func_pam_start" = yes; then
 191                 AC_DEFINE(ENABLE_AUTOLOGIN)
 192                 if test "$enable_chkpwd" != no; then
 193                         AC_DEFINE(ENABLE_CHKPWD)
 194                         CHKPWD=chkpwd
 195                 else
 196                         AUTH=auth.lo
 197                 fi
 198         fi
 199 fi
 200
 201 test -f /usr/local/lib/libresolv.a && LDFLAGS="$LDFLAGS -L/usr/local/lib"
 202 AC_CHECK_LIB(resolv, res_query, RESOLV="$RESOLV -lresolv")
 203
 204 if test "x$with_ncurses" != "xno"; then
 205         AC_SEARCH_LIBS(tgetent, [ncurses curses termcap])
 206         AC_SEARCH_LIBS(scrollok, [ncurses curses])
 207         AC_SEARCH_LIBS(initscr, [ncurses curses])
 208 else
 209         AC_SEARCH_LIBS(tgetent, [curses termcap])
 210         AC_SEARCH_LIBS(initscr, [curses])
 211 fi
 212 AC_CHECK_FUNCS(vw_printw wcolor_set resizeterm wresize)
 213
 214 dnl Check for libpthread(s) if we're not using Digital UNIX or FreeBSD. (On
 215 dnl which the -pthread flag takes care of this.)
 216 if test "$check_pthread" != no; then
 217         AC_CHECK_LIB(pthread, pthread_create)
 218         AC_CHECK_LIB(pthreads, pthread_create)
 219 fi
 220
 221 test -d /usr/kerberos/include && CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
 222
 223 # The big search for OpenSSL
 224 if test "$with_ssl" != "no"; then
 225         saved_LIBS="$LIBS"
 226         saved_LDFLAGS="$LDFLAGS"
 227         saved_CFLAGS="$CFLAGS"
 228         if test "x$prefix" != "xNONE"; then
 229                 tryssldir="$tryssldir $prefix"
 230         fi
 231         AC_CACHE_CHECK([for OpenSSL], ac_cv_openssldir, [
 232                 for ssldir in $tryssldir "" /usr /usr/local/openssl /usr/lib/openssl /usr/local/ssl /usr/lib/ssl /usr/local /usr/pkg /opt /opt/openssl ; do
 233                         CFLAGS="$saved_CFLAGS"
 234                         LDFLAGS="$saved_LDFLAGS"
 235                         LIBS="$saved_LIBS -lssl -lcrypto"
 236
 237                         # Skip directories if they don't exist
 238                         if test ! -z "$ssldir" -a ! -d "$ssldir" ; then
 239                                 continue;
 240                         fi
 241                         if test ! -z "$ssldir" -a "x$ssldir" != "x/usr"; then
 242                                 # Try to use $ssldir/lib if it exists, otherwise
 243                                 # $ssldir
 244                                 if test -d "$ssldir/lib" ; then
 245                                         LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 246                                         if test ! -z "$need_dash_r" ; then
 247                                                 LDFLAGS="-R$ssldir/lib $LDFLAGS"
 248                                         fi
 249                                 else
 250                                         LDFLAGS="-L$ssldir $saved_LDFLAGS"
 251                                         if test ! -z "$need_dash_r" ; then
 252                                                 LDFLAGS="-R$ssldir $LDFLAGS"
 253                                         fi
 254                                 fi
 255                                 # Try to use $ssldir/include if it exists, otherwise
 256                                 # $ssldir
 257                                 if test -d "$ssldir/include" ; then
 258                                         CFLAGS="-I$ssldir/include $saved_CFLAGS"
 259                                 else
 260                                         CFLAGS="-I$ssldir $saved_CFLAGS"
 261                                 fi
 262                         fi
 263
 264                         # Basic test to check for compatible version and correct linking
 265                         # *does not* test for RSA - that comes later.
 266                         AC_TRY_RUN(
 267                                 [
 268         #include <string.h>
 269         #include <openssl/rand.h>
 270         int main(void)
 271         {
 272                 char a[2048];
 273                 memset(a, 0, sizeof(a));
 274                 RAND_add(a, sizeof(a), sizeof(a));
 275                 return(RAND_status() <= 0);
 276         }
 277                                 ],
 278                                 [
 279                                         found_crypto=1
 280                                         break;
 281                                 ], []
 282                         )
 283
 284                         if test ! -z "$found_crypto" ; then
 285                                 break;
 286                         fi
 287                 done
 288
 289                 if test -z "$ssldir" ; then
 290                         ssldir="(system)"
 291                 fi
 292
 293                 if test ! -z "$found_crypto" ; then
 294                         ac_cv_openssldir=$ssldir
 295                 else
 296                         ac_cv_openssldir="no"
 297                 fi
 298         ])
 299         LIBS="$saved_LIBS"
 300         LDFLAGS="$saved_LDFLAGS"
 301         CFLAGS="$saved_CFLAGS"
 302
 303         if test "x$ac_cv_openssldir" != "xno" ; then
 304                 AC_DEFINE(HAVE_OPENSSL)
 305                 LIBS="-lssl -lcrypto $LIBS"
 306                 dnl Need to recover ssldir - test above runs in subshell
 307                 ssldir=$ac_cv_openssldir
 308                 if test ! -z "$ssldir" -a "x$ssldir" != "x/usr" -a "x$ssldir" != "x(system)"; then
 309                         # Try to use $ssldir/lib if it exists, otherwise
 310                         # $ssldir
 311                         if test -d "$ssldir/lib" ; then
 312                                 LDFLAGS="-L$ssldir/lib $saved_LDFLAGS"
 313                                 if test ! -z "$need_dash_r" ; then
 314                                         LDFLAGS="-R$ssldir/lib $LDFLAGS"
 315                                 fi
 316                         else
 317                                 LDFLAGS="-L$ssldir $saved_LDFLAGS"
 318                                 if test ! -z "$need_dash_r" ; then
 319                                         LDFLAGS="-R$ssldir $LDFLAGS"
 320                                 fi
 321                         fi
 322                         # Try to use $ssldir/include if it exists, otherwise
 323                         # $ssldir
 324                         if test -d "$ssldir/include" ; then
 325                                 CFLAGS="-I$ssldir/include $saved_CFLAGS"
 326                         else
 327                                 CFLAGS="-I$ssldir $saved_CFLAGS"
 328                         fi
 329                 fi
 330         fi
 331 fi
 332
 333 if test "x$with_db" != xno; then
 334         test "$db_dir" && LDFLAGS="$LDFLAGS -L$db_dir/lib"
 335
 336         dblib=""
 337
 338         if test -d "$db_dir/include/db4"; then
 339                 CPPFLAGS="$CPPFLAGS -I$db_dir/include/db4"
 340                 dblib="db4"
 341         elif test "$db_dir"; then
 342                 CPPFLAGS="$CPPFLAGS -I$db_dir/include"
 343         elif test -d /usr/include/db4; then
 344                 CPPFLAGS="$CPPFLAGS -I/usr/include/db4"
 345                 dblib="db4"
 346         fi
 347
 348
 349         AC_CHECK_DB([db db-4.1 db-4 db4],
 350                     [
 351                      DATABASE=database_sleepycat.c
 352                     ],
 353                     AC_MSG_ERROR([[Can not locate a suitable Berkeley DB
 354                                   library.  Use --with-db=PATH to specify
 355                                   the path]]))
 356
 357 fi
 358
 359
 360 dnl Checks for the zlib compression library.
 361 if test "x$with_zlib" != xno ; then
 362         AC_CHECK_HEADERS(zlib.h,
 363                 [AC_CHECK_LIB(z, zlibVersion,
 364                         [ok_zlib=yes],,
 365         )])
 366 fi
 367
 368 if test "x$ok_zlib" = xyes ; then
 369         SERVER_LIBS="-lz $SERVER_LIBS"
 370         AC_DEFINE(HAVE_ZLIB)
 371 fi
 372
 373
 374
 375
 376 dnl Checks for the OpenLDAP client library.
 377 if test "x$with_ldap" != xno ; then
 378         AC_CHECK_HEADERS(ldap.h,
 379                 [AC_CHECK_LIB(ldap, ldap_init,
 380                         [ok_ldap=yes],,
 381         )])
 382 fi
 383
 384 if test "x$ok_ldap" = xyes ; then
 385         SERVER_LIBS="-lldap $SERVER_LIBS"
 386         AC_DEFINE(HAVE_LDAP)
 387 fi
 388
 389
 390
 391
 392 dnl Checks for the newt window library.
 393 if test "x$with_newt" != xno ; then
 394         AC_CHECK_HEADERS(newt.h,
 395                 [AC_CHECK_LIB(newt, newtInit,
 396                         [ok_newt=yes],,
 397         )])
 398 fi
 399
 400 if test "x$ok_newt" = xyes ; then
 401         SETUP_LIBS="-lnewt $SETUP_LIBS"
 402         AC_DEFINE(HAVE_NEWT)
 403 fi
 404
 405
 406
 407
 408
 409
 410 dnl Checks for the libical calendaring library.
 411 if test "x$with_libical" != xno ; then
 412         AC_CHECK_HEADERS(ical.h,
 413                 [AC_CHECK_LIB(ical, icalcomponent_new,
 414                         [ok_libical=yes],,
 415         )])
 416 fi
 417
 418 if test "x$ok_libical" = xyes ; then
 419
 420         AC_TRY_RUN(
 421                 [
 422 #include <ical.h>
 423 main() {
 424         float v;
 425         int i;
 426         sscanf(ICAL_VERSION, "%f", &v);
 427         printf("libical version: %0.2f\n", v);
 428         v = v * 100.0;
 429         i = (int) v;
 430         if (i >= 24) {
 431                 printf("This version is ok.\n");
 432                 return(0);
 433         }
 434         printf("libical 0.24 or newer required.\n");
 435         printf("Citadel will be built without calendar support.\n");
 436         return(1);
 437 }
 438                 ],
 439                 [
 440                         SERVER_LIBS="-lical $SERVER_LIBS"
 441                         AC_DEFINE(HAVE_LIBICAL)
 442                 ]
 443         )
 444 fi
 445
 446
 447
 448
 449 dnl Checks for header files.
 450 AC_HEADER_DIRENT
 451 AC_HEADER_STDC
 452 AC_HEADER_SYS_WAIT
 453
 454 dnl
 455 dnl TODO: for the DB header checks, we should check whether the headers
 456 dnl define db_env_create, somehow
 457 dnl
 458 AC_CHECK_HEADERS(curses.h dl.h fcntl.h limits.h malloc.h termios.h sys/ioctl.h sys/select.h sys/time.h syslog.h unistd.h utmp.h utmpx.h paths.h db.h db4/db.h pthread.h netinet/in.h arpa/nameser.h arpa/nameser_compat.h)
 459
 460 dnl
 461 dnl need to check if this is actually compilable, sometimes there are
 462 dnl conflicts with the system's headers (eg solaris xpg4 style headers)
 463 dnl
 464 if test "x$with_ncurses" != xno; then
 465         AC_CHECK_HEADERS(ncurses.h,,,[ ])
 466 fi
 467
 468 AC_CHECK_HEADER(resolv.h,AC_DEFINE(HAVE_RESOLV_H),,
 469 [#ifdef HAVE_SYS_TYPES_H
 470 #include <sys/types.h>
 471 #endif
 472 #ifdef HAVE_NETINET_IN_H
 473 #include <netinet/in.h>
 474 #endif
 475 #ifdef HAVE_ARPA_NAMESER_H
 476 #include <arpa/nameser.h>
 477 #endif])
 478
 479
 480 dnl Checks for typedefs, structures, and compiler characteristics.
 481 AC_C_CONST
 482 AC_TYPE_PID_T
 483 AC_TYPE_SIZE_T
 484 AC_HEADER_TIME
 485
 486 dnl defined in acinclude.m4:
 487 CIT_STRUCT_TM
 488
 489 AC_CACHE_CHECK([for ut_type in struct utmp], ac_cv_struct_ut_type,
 490 [AC_TRY_COMPILE([#include <sys/types.h>
 491 #include <utmp.h>], [struct utmp ut; ut.ut_type;],
 492 ac_cv_struct_ut_type=yes, ac_cv_struct_ut_type=no)])
 493 if test $ac_cv_struct_ut_type = yes; then
 494         AC_DEFINE(HAVE_UT_TYPE)
 495 fi
 496
 497 AC_CACHE_CHECK([for ut_host in struct utmp], ac_cv_struct_ut_host,
 498 [AC_TRY_COMPILE([#include <sys/types.h>
 499 #include <utmp.h>], [struct utmp ut; ut.ut_host;],
 500 ac_cv_struct_ut_host=yes, ac_cv_struct_ut_host=no)])
 501 if test $ac_cv_struct_ut_host = yes; then
 502         AC_DEFINE(HAVE_UT_HOST)
 503 fi
 504
 505 dnl Checks for library functions.
 506 AC_FUNC_GETPGRP
 507 AC_PROG_GCC_TRADITIONAL
 508 AC_TYPE_SIGNAL
 509 AC_FUNC_VPRINTF
 510 AC_CHECK_FUNCS(getspnam getutxline mkdir mkfifo mktime rmdir select socket strerror strcasecmp strncasecmp)
 511
 512 dnl Now check for pthreads
 513
 514 dnl On some platforms, AC_CHECK_FUNC[S] doesn't work for pthreads programs;
 515 dnl we need to include pthread.h
 516
 517 AC_CACHE_CHECK([for pthread_cancel], ac_cv_func_pthread_cancel,
 518 [AC_TRY_LINK([#include <pthread.h>],
 519 [       pthread_t thread;
 520
 521         /* The GNU C library defines this for functions which it implements
 522            to always fail with ENOSYS.  Some functions are actually named
 523            something starting with __ and the normal name is an alias.  */
 524 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 525         choke me
 526 #else
 527         pthread_cancel(thread);
 528 #endif],
 529 ac_cv_func_pthread_cancel=yes, ac_cv_func_pthread_cancel=no)])
 530 if test "$ac_cv_func_pthread_cancel" = yes; then
 531         AC_DEFINE(HAVE_PTHREAD_CANCEL)
 532 fi
 533
 534 AC_CACHE_CHECK([for pthread_create], ac_cv_func_pthread_create,
 535 [AC_TRY_LINK([#include <pthread.h>],
 536 [       /* The GNU C library defines this for functions which it implements
 537            to always fail with ENOSYS.  Some functions are actually named
 538            something starting with __ and the normal name is an alias.  */
 539 #if defined (__stub_pthread_cancel) || defined (__stub___pthread_cancel)
 540         choke me
 541 #else
 542         pthread_create(NULL, NULL, NULL, NULL);
 543 #endif],
 544 ac_cv_func_pthread_create=yes, ac_cv_func_pthread_create=no)])
 545 if test "$ac_cv_func_pthread_create" = yes; then
 546         test "$DATABASE" && TARGETS="client server utils"
 547         if test "x$enable_threaded_client" != xno; then
 548                 AC_DEFINE(THREADED_CLIENT)
 549         fi
 550 fi
 551
 552 AC_REPLACE_FUNCS(snprintf getutline)
 553
 554 # AC_CACHE_CHECK([the weather], ac_cv_weather, [
 555 #       sleep 1
 556 #       echo $ECHO_N "opening your window... $ECHO_C" >&6
 557 #       sleep 2
 558 #       month=`date | cut -f 2 -d ' '`
 559 #       case $month in
 560 #       Dec | Jan | Feb)
 561 #               ac_cv_weather="it's cold!"
 562 #               ;;
 563 #       Mar | Apr)
 564 #               ac_cv_weather="it's wet!"
 565 #               ;;
 566 #       Jul | Aug)
 567 #               ac_cv_weather="it's hot!"
 568 #               ;;
 569 #       Oct | Nov)
 570 #               ac_cv_weather="it's cool"
 571 #               ;;
 572 #       May | Jun | Sep | *)
 573 #               ac_cv_weather="it's fine"
 574 #               ;;
 575 #       esac
 576 #       ])
 577
 578 AC_CACHE_CHECK([under the bed], ac_cv_under_the_bed, [
 579         number=`date | cut -c 19`
 580         case $number in
 581         7)
 582                 ac_cv_under_the_bed="lunatics and monsters found"
 583                 ;;
 584         *)
 585                 ac_cv_under_the_bed="dust bunnies found"
 586                 ;;
 587         esac
 588         ])
 589
 590 dnl Done! Now write the Makefile and sysdep.h
 591 AC_SUBST(AUTH)
 592 AC_SUBST(CHKPWD)
 593 AC_SUBST(RESOLV)
 594 AC_SUBST(chkpwd_LIBS)
 595 AC_SUBST(TARGETS)
 596 AC_SUBST(DATABASE)
 597 AC_SUBST(SERVER_LDFLAGS)
 598 AC_SUBST(SERVER_LIBS)
 599 AC_SUBST(SETUP_LIBS)
 600 AC_CONFIG_HEADER(sysdep.h)
 601 AC_CONFIG_FILES([Makefile])
 602 AC_OUTPUT
 603
 604 if test -z "$DATABASE"; then
 605         AC_MSG_WARN([No database driver was found. Please install Berkeley DB.])
 606 fi
 607
 608 echo ...
 609 echo ...
 610 echo "... On many operating systems, you must use GNU make (gmake) to compile"
 611 echo ... Citadel.
 612 echo ...
 613 echo ...