the_perfect_clock.ino

   1 // "The Perfect Clock"
   2
   3 // Copyright (C) 2019-2023 by Art Cancro <ajc@citadel.org>
   4
   5 // My perfect clock has no buttons and cannot be set manually.  This version uses a WWVB receiver module
   6 // attached to pin D9 of the Arduino, and sets the clock any time it receives a complete frame.  The clock
   7 // is kept without an RTC, simply using the millis() timer.  When time is set, it is displayed on
   8 // a 7-segment array connected using an HT16K33 decoder/driver (yes, an Adafruit backpack).  Our display
   9 // can also display at 15 different brightness levels, so we dim it when the room is dark to avoid
  10 // blasticating a dark room with super-bright LED display.
  11
  12 // The clock is hard coded to use US Eastern time with DST in effect whenever WWVB is announcing it.
  13
  14 // This software is made available to you conditionally upon you accepting the following terms and conditions:
  15 // 1. You agree that it is called "open source", not "free software".
  16 // 2. You agree that the Linux operating system is not called "GNU/Linux".
  17 // 3. You agree that Corey Ehmke is a scumbag, as are all social justice warriors.
  18 // 4. You promise never to vote democrat in any election.
  19 // 5. Under no circumstances may you use this program and also maintain a Facebook account.
  20 // Aside from these conditions, the program is made available to you under the terms of the GNU General Public License.
  21
  22 // On my clock, there is a green LED on 2, a yellow LED on 3, and a red LED on 4.
  23
  24 const uint8_t wwvb = 9;         // pin on which WWVB signal will be received
  25 const uint8_t last24led = 2;    // An LED attached to this pin will illuminate if the time has been set within the last 24 hours
  26 const uint8_t cleantimecodeled = LED_BUILTIN;   // An LED attached to this pin will illuminate if we are currently receiving a clean frame
  27 const uint8_t timecodeled = 3;
  28 const uint8_t photocell = A0;   // Attach a photocell with a 10K voltage divider to this pin
  29 const uint8_t addr = 0x70;      // I2C address of HT16K33 (using Adafruit backpack with digits on 0,1,3,4; dots on 2)
  30
  31 long millis_per_minute = 60000; // Nominally 60000; adjust if your board runs fast or slow
  32
  33 // This is a simple BCD-to-7-segment font.  It includes 0x0A through 0x0F even though they're not needed for a time clock.
  34 const uint8_t sevensegfont[] = { 63, 6, 91, 79, 102, 109, 125, 7, 127, 111, 119, 124, 57, 94, 121, 113 };
  35 const uint8_t firstcolfont[] = { 0, 6, 91 };    // this version of the font is for the first position
  36
  37 #include <Wire.h>               // I2C library to drive the HT16K33 display
  38
  39 int hour = 0;
  40 int minute = 0;
  41 unsigned long millisecond = 0;
  42 unsigned long previous_millis = 0;
  43 unsigned long last_sync = -86398000;
  44 uint16_t displayBuffer[8];      // Digit buffer for HT16K33
  45 int previous_minute = 61;       // What the minute was previously; we use this to detect whether an update is needed
  46 int this_pulse = 0;             // Value of the current pulse received
  47 int previous_pulse = 0;         // Value of the previous pulse received (two "mark" bits == new frame)
  48 int start_of_pulse = 0;         // The value of the millis() timer when the current pulse began
  49 uint8_t framebuf[60];           // We store the entire 60-bit frame here
  50 uint8_t framesync = 0;          // Nonzero if we've received all good pulses since the start of the frame
  51 int position_in_frame = 0;      // Where we are in the frame (1 bit per second)
  52 int previous_signal = 0;        // "high" or "low" received on the previous cycle (so we can do edge detection)
  53 int time_is_set = 0;            // nonzero when time has been set at least once
  54
  55 void setup() {
  56         int i;
  57
  58         pinMode(timecodeled, OUTPUT);   // The built-in LED will display the raw WWVB signal pulses
  59         pinMode(last24led, OUTPUT);     // This LED will illuminate if the time has been set within the last 24 hours
  60         pinMode(cleantimecodeled, OUTPUT);      // This LED will illuminate if we are currently receiving a clean frame
  61         pinMode(wwvb, INPUT);   // Input pin for WWVB receiver signal
  62         pinMode(photocell, INPUT);      // Input pin for photocell
  63
  64         Wire.begin();           // Initialize I2C
  65
  66         Wire.beginTransmission(addr);
  67         Wire.write(0x21);       // turn on oscillator
  68         Wire.endTransmission();
  69
  70         Wire.beginTransmission(addr);
  71         Wire.write(0xE1);       // brightness (max is 15)
  72         Wire.endTransmission();
  73
  74         Wire.beginTransmission(addr);
  75         Wire.write(0x81);       // no blinking or blanking
  76         Wire.endTransmission();
  77
  78         displayBuffer[0] = 0;
  79         displayBuffer[1] = 0;
  80         displayBuffer[2] = 16;
  81         displayBuffer[3] = 0;
  82         displayBuffer[4] = 0;
  83         show();
  84 }
  85
  86
  87 // Note: only write to the display when the readout needs to be updated.
  88 // Speaking I2C on every loop iteration jams the WWVB receiver.
  89 void loop() {
  90
  91   // Reading it three times and taking the average gives us some hysteresis
  92   int signal = (digitalRead(wwvb) + digitalRead(wwvb) + digitalRead(wwvb)) / 3;
  93
  94   // has the timer ticked?
  95         unsigned long m = millis();
  96         if (m != previous_millis) {
  97                 millisecond += (m - previous_millis);
  98                 if (millisecond >= millis_per_minute) {
  99                         millisecond -= millis_per_minute;
 100                         ++minute;
 101                         if (minute > 59) {
 102                                 minute = 0;
 103                                 ++hour;
 104                                 if (hour > 23) {
 105                                         hour = 0;
 106                                 }
 107                         }
 108                 }
 109   }
 110         previous_millis = m;
 111
 112         int pulse_length;
 113
 114   if (signal) {
 115     analogWrite(timecodeled, 5);       // it's too bright on my board so we dim it; change to digitalWrite() if not needed
 116   }
 117   else {
 118     digitalWrite(timecodeled, LOW);
 119   }
 120
 121         if (signal && (!previous_signal)) {                     // leading edge of pulse detected
 122                 start_of_pulse = millis();
 123         }
 124         else if ((!signal) && (previous_signal)) {              // trailing edge of pulse detected
 125                 pulse_length = millis() - start_of_pulse;
 126
 127                 if (pulse_length > 150 && pulse_length < 250) { // "0" bit ~= 200 ms (represented as "0")
 128                         this_pulse = 0;
 129                 }
 130                 else if (pulse_length > 450 && pulse_length < 550) {    // "1" bit ~= 500 ms (represented as "1")
 131                         this_pulse = 1;
 132                 }
 133                 else if (pulse_length > 750 && pulse_length < 850) {    // marker bit ~= 800 ms (represented as "2")
 134                         this_pulse = 2;
 135                 }
 136                 else {
 137                         this_pulse = 15;        // bad pulse (represented as "15")
 138                         framesync = 0;  // throw the whole frame away
 139                 }
 140
 141                 // BEGIN -- THINGS TO DO AT THE END OF A PULSE
 142
 143                 if ((this_pulse == 2) && (previous_pulse == 2)) {       // start of a new frame!
 144
 145                         if (framesync == 1) {
 146                                 set_the_time(); // We have a whole good frame.  Set the clock!
 147                         }
 148                         else if ((!framesync) && (time_is_set)) {
 149                                 snap_to_zero(); // We don't have a whole frame, but we know it's :00 seconds now.
 150                         }
 151
 152                         framesync = 1;
 153                         position_in_frame = 0;
 154                         calibrate();    // calibrate the software timer
 155                 }
 156
 157                 if (framesync) {        // yellow LED = we currently have frame sync
 158                         digitalWrite(cleantimecodeled, HIGH);   // (we run it at a low intensity)
 159                 }
 160                 else {
 161                         digitalWrite(cleantimecodeled, LOW);
 162                 }
 163
 164                 if ((framesync) && (position_in_frame < 60)) {
 165                         framebuf[position_in_frame++] = this_pulse;
 166                 }
 167
 168                 previous_pulse = this_pulse;
 169
 170                 // END -- THINGS TO DO AT THE END OF A PULSE
 171         }
 172
 173         previous_signal = signal;
 174
 175         // Update the display only if it's a new minute.
 176
 177         if (time_is_set && (minute != previous_minute)) {
 178                 previous_minute = minute;
 179                 int h12 = (hour % 12);
 180                 if (h12 == 0)
 181                         h12 = 12;
 182                 displayBuffer[0] = firstcolfont[h12 / 10];
 183                 displayBuffer[1] = sevensegfont[h12 % 10];
 184                 displayBuffer[2] = (hour < 12) ? 0x06 : 0x0a;   // AM or PM dot , colon always on
 185                 displayBuffer[3] = sevensegfont[minute / 10];
 186                 displayBuffer[4] = sevensegfont[minute % 10];
 187                 show();
 188         }
 189
 190         if ((m - last_sync) < 86400000) {       // green LED = got a good sync in the last 24 hours
 191                 digitalWrite(last24led, HIGH);
 192         }
 193         else {
 194                 digitalWrite(last24led, LOW);
 195         }
 196 }
 197
 198
 199 // Write the display buffer to the display
 200 void show() {
 201         // display the time
 202         Wire.beginTransmission(addr);
 203         Wire.write(0x00);       // start at address 0x0
 204         for (int i = 0; i < 5; i++) {
 205                 Wire.write(displayBuffer[i] & 0xFF);
 206                 Wire.write(displayBuffer[i] >> 8);
 207         }
 208         Wire.endTransmission();
 209
 210         // set the brightness
 211         int light_level = analogRead(photocell) / 64;
 212         if (light_level < 1) {
 213                 light_level = 1;
 214         }
 215         if (light_level > 15) {
 216                 light_level = 15;
 217         }
 218         Wire.beginTransmission(addr);
 219         Wire.write(0xE0 + light_level); // set the display brightness
 220         Wire.endTransmission();
 221 }
 222
 223
 224 // Set the software clock to the WWVB time currently in the buffer
 225 void set_the_time() {
 226         int i, newhour, newminute, dst;
 227
 228         // These six positions MUST contain marker bits.
 229         // If any of them do not, we are looking at a corrupt frame.
 230         int markers[] = { 0, 9, 19, 39, 49, 59 };
 231         for (i = 0; i < 6; ++i) {
 232                 if (framebuf[markers[i]] != 2) {
 233                         return;
 234                 }
 235         }
 236
 237         newhour = (framebuf[12] ? 20 : 0);
 238         newhour += (framebuf[13] ? 10 : 0);
 239         newhour += (framebuf[15] ? 8 : 0);
 240         newhour += (framebuf[16] ? 4 : 0);
 241         newhour += (framebuf[17] ? 2 : 0);
 242         newhour += (framebuf[18] ? 1 : 0);
 243         if ((newhour < 0) || (newhour > 23)) {
 244                 return;         // reject impossible hours
 245         }
 246
 247         newminute = (framebuf[1] ? 40 : 0);
 248         newminute += (framebuf[2] ? 20 : 0);
 249         newminute += (framebuf[3] ? 10 : 0);
 250         newminute += (framebuf[5] ? 8 : 0);
 251         newminute += (framebuf[6] ? 4 : 0);
 252         newminute += (framebuf[7] ? 2 : 0);
 253         newminute += (framebuf[8] ? 1 : 0);
 254         if ((newminute < 0) || (newminute > 59)) {
 255                 return;         // reject impossible minutes
 256         }
 257
 258         // advance 1 minute because WWVB gives the *previous* minute
 259         newminute += 1;
 260         if (newminute >= 60) {
 261                 newminute = newminute % 60;
 262                 newhour += 1;
 263         }
 264
 265         // US Eastern time (yes it is hard coded)
 266         newhour -= 5;
 267
 268         // DST (FIXME make this adjustable)
 269         dst = (framebuf[57] ? 2 : 0);
 270         dst += (framebuf[58] ? 1 : 0);
 271         switch (dst) {
 272         case 0:         // dst not in effect (make no adjustments)
 273                 break;
 274         case 2:         // dst begins today (adjust if local hour > 2)
 275                 if (newhour >= 2) {
 276                         ++newhour;
 277                 }
 278                 break;
 279         case 3:         // dst is in effect (always adjust)
 280                 ++newhour;
 281                 break;
 282         case 1:         // dst ends today (adjust if local hour < 2)
 283                 if (newhour < 2) {
 284                         ++newhour;
 285                 }
 286                 break;
 287         }
 288
 289         // If we went back to the previous day, adjust so that hour > 0
 290         if (newhour < 0) {
 291                 newhour += 24;
 292         }
 293
 294         // Set the software clock:
 295         // * We have decoded the hour and minute from the signal
 296         // * This function always gets called *after* the first pulse at :00, so we set the millisecond to 800
 297         hour = newhour;
 298         minute = newminute;
 299         millisecond = 800;
 300         time_is_set = 1;
 301
 302         // Let's remember the last time we synced the clock
 303         last_sync = millis();
 304 }
 305
 306
 307 // Adjust the time to :00.8 seconds at the nearest minute.
 308 void snap_to_zero() {
 309         if ((millisecond > 0) && (millisecond < 15000)) {       // If the second is from :00.0 to :15.0
 310                 millisecond = 800;      // snap back to :00.8
 311         }
 312         else if (millisecond > 45000) { // If the second is :45.0 or above
 313                 millisecond = millis_per_minute + 800;  // snap forward to :00.8 (minute will advance automatically)
 314         }
 315 }
 316
 317
 318 // By determining how many timer ticks elapsed between two minute markers, we can calibrate our software clock.
 319 // Nominally it is 60000 milliseconds, but the software clock tends to drift.
 320 // So we start with an array of all 60000 ms, and we keep ten calibrations and average them.
 321 void calibrate() {
 322
 323         static unsigned long mpm_array[10] = { 60000, 60000, 60000, 60000, 60000, 60000, 60000, 60000, 60000, 60000 };
 324         static int mpm = 0;                             // next one to update
 325
 326         static unsigned long last_calib = -86398000;
 327         unsigned long m = millis();
 328         unsigned long mm = m - last_calib;
 329         if ((mm > 50000) && (mm < 70000)) {
 330                 mpm_array[mpm++] = mm;
 331                 if (mpm >= 10) {
 332                         mpm = 0;
 333                 }
 334                 millis_per_minute = (mpm_array[0] + mpm_array[1] + mpm_array[2] + mpm_array[3]
 335                                 + mpm_array[4] + mpm_array[5] + mpm_array[6] + mpm_array[7]
 336                                 + mpm_array[8] + mpm_array[9]) / 10;
 337         }
 338         last_calib = m;
 339 }